Added: QTE Framework

addons/main/config.cpp

@@ -31,7 +31,8 @@ class CfgPatches {
             "cba_ui",
             "cba_versioning",
             "cba_optics",
-            "cba_disposable"
+            "cba_disposable",
+            "cba_quicktime"
         };
         author = "$STR_CBA_Author";
         authors[] = {};

addons/quicktime/$PBOPREFIX$

@@ -0,0 +1 @@
+x\cba\addons\quicktime

addons/quicktime/CfgEventHandlers.hpp

@@ -0,0 +1,12 @@
+class Extended_PreStart_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_SCRIPT(XEH_preStart));
+    };
+};
+
+class Extended_PreInit_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_SCRIPT(XEH_preInit));
+    };
+};
+

addons/quicktime/CfgFunctions.hpp

@@ -0,0 +1,10 @@
+class CfgFunctions {
+    class CBA {
+        class QuickTimeEvent {
+            PATHTO_FNC(generateQTESequence);
+            PATHTO_FNC(getFormattedQTESequence);
+            PATHTO_FNC(runQTE);
+            PATHTO_FNC(keyPressedQTE);
+        };
+    };
+};

addons/quicktime/XEH_preInit.sqf

@@ -0,0 +1,24 @@
+#include "script_component.hpp"
+#include "\a3\ui_f\hpp\defineDIKCodes.inc"
+
+SCRIPT(XEH_preInit);
+
+ADDON = false;
+
+[LSTRING(QTEKeybindGroup), QGVAR(qteUpKey), ["↑", LSTRING(QTEKeybindUpTooltip)], {
+    ["↑"] call CBA_fnc_keyPressedQTE // return
+}, {}, [DIK_UP, [false, true, false]]] call CBA_fnc_addKeybind;
+
+[LSTRING(QTEKeybindGroup), QGVAR(qteDownKey), ["↓", LSTRING(QTEKeybindDownTooltip)], {
+    ["↓"] call CBA_fnc_keyPressedQTE // return
+}, {}, [DIK_DOWN, [false, true, false]]] call CBA_fnc_addKeybind;
+
+[LSTRING(QTEKeybindGroup), QGVAR(qteLeftKey), ["←", LSTRING(QTEKeybindLeftTooltip)], {
+    ["←"] call CBA_fnc_keyPressedQTE // return
+}, {}, [DIK_LEFT, [false, true, false]]] call CBA_fnc_addKeybind;
+
+[LSTRING(QTEKeybindGroup), QGVAR(qteRightKey), ["→", LSTRING(QTEKeybindRightTooltip)], {
+    ["→"] call CBA_fnc_keyPressedQTE // return
+}, {}, [DIK_RIGHT, [false, true, false]]] call CBA_fnc_addKeybind;
+
+ADDON = true;

addons/quicktime/XEH_preStart.sqf

@@ -0,0 +1 @@
+#include "script_component.hpp"

addons/quicktime/config.cpp

@@ -0,0 +1,18 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+    class ADDON {
+        name = CSTRING(component);
+        units[] = {};
+        weapons[] = {};
+        requiredVersion = REQUIRED_VERSION;
+        requiredAddons[] = {"cba_common","cba_events"};
+        author = "$STR_CBA_Author";
+        authors[] = {"john681611"};
+        url = "$STR_CBA_URL";
+        VERSION_CONFIG;
+    };
+};
+
+#include "CfgFunctions.hpp"
+#include "CfgEventHandlers.hpp"

addons/quicktime/fnc_generateQTESequence.sqf

@@ -0,0 +1,31 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_generateQTESequence
+
+Description:
+    Generate a Quick-Time sequence of a given length.
+
+Parameters:
+    _length - Length of QTE sequence <NUMBER>
+
+Example:
+    [5] call CBA_fnc_generateQTESequence;
+
+Returns:
+    Quick-Time sequence of requested length made up of ["↑", "↓", "→", "←"] <ARRAY>
+
+Author:
+    john681611
+---------------------------------------------------------------------------- */
+
+params [["_length", 0, [0]]];
+
+if (_length <= 0) exitWith {[]};
+
+private _code = [];
+
+for "_i" from 0 to _length do {
+    _code pushBack (selectRandom ["↑", "↓", "→", "←"]);
+};
+
+_code

addons/quicktime/fnc_getFormattedQTESequence.sqf

@@ -0,0 +1,24 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_getFormattedQTESequence
+
+Description:
+    Formats Quick-Time sequence into a displayable string.
+
+Parameters:
+    _code - Quick-Time sequence <ARRAY>
+
+
+Example:
+    [["↑", "↓", "→", "←"]] call CBA_fnc_getFormattedQTESequence;
+
+Returns:
+    Formatted Quick-Time sequence <STRING>
+
+Author:
+    john681611
+---------------------------------------------------------------------------- */
+
+params ["_code"];
+
+_code joinString "     " // Arma doesn't know how to space ↑ so we need loads of spaces between

addons/quicktime/fnc_keyPressedQTE.sqf

@@ -0,0 +1,60 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_keyPressedQTE
+
+Description:
+    Process Quick-Time Key Press
+
+Parameters:
+    _eventQTE - Character to test against Quick-Time Event <STRING>
+
+Example:
+    ["↑"] call CBA_fnc_keyPressedQTE;
+
+Returns:
+    True if QTE is running <BOOLEAN>
+
+Author:
+    john681611
+---------------------------------------------------------------------------- */
+
+
+params ["_eventQTE"];
+
+if !(missionNamespace getVariable [QGVAR(QTERunning), false]) exitWith {
+    false
+};
+
+
+private _args = GVAR(QTEArgs) get "args";
+private _qteSequence = GVAR(QTEArgs) get "qteSeqence";
+private _elapsedTime = CBA_missionTime - (GVAR(QTEArgs) get "startTime");
+
+GVAR(QTEHistory) pushBack _eventQTE;
+
+
+if (GVAR(QTEHistory) isEqualTo _qteSequence) exitWith {
+    GVAR(QTEHistory) = [];
+    GVAR(QTERunning) = false;
+    TRACE_1("QTE Completed",_elapsedTime);
+    private _onFinish = GVAR(QTEArgs) get "onFinish";
+    if (_onFinish isEqualType "") then {
+        [_onFinish, [_args, _elapsedTime]] call CBA_fnc_localEvent;
+    } else {
+        [_args, _elapsedTime] call _onFinish;
+    };
+    true
+};
+
+if (GVAR(QTEHistory) isNotEqualTo (_qteSequence select [0, count GVAR(QTEHistory)])) then {
+    GVAR(QTEHistory) = [];
+};
+
+private _onDisplay = GVAR(QTEArgs) get "onDisplay";
+if (_onDisplay isEqualType "") then {
+    [_onDisplay, [_args, _qteSequence, GVAR(QTEHistory)]] call CBA_fnc_localEvent;
+} else {
+    [_args, _qteSequence, GVAR(QTEHistory)] call _onDisplay;
+};
+
+true

addons/quicktime/fnc_runQTE.sqf

@@ -0,0 +1,94 @@
+#include "script_component.hpp"
+/* ----------------------------------------------------------------------------
+Function: CBA_fnc_runQTE
+
+Description:
+    Runs a Quick-Time Event.
+
+Parameters:
+    _object - <OBJECT>
+    _args - Extra arguments passed to the _on... functions<ARRAY>
+    _onDisplay - Code callback on displayable event passed [_args, _qteSequence, _qteHistory]. <CODE, STRING>
+    _onFinish - Code callback on Quick-Time Event completed passed [_args, _elapsedTime]. <CODE, STRING>
+    _onFinish - Code callback on Quick-Time Event timeout/outranged passed [_args, _elapsedTime]. <CODE, STRING>
+    _qteSequence - Quick-Time sequence made up of ["↑", "↓", "→", "←"] <ARRAY>
+    _maxDistance - max interaction distance from attached object <NUMBER> (default: 10) 
+    _timeout - ingame timeout <NUMBER> (default: 30)
+
+Example:
+    [car,
+    [], 
+    { 
+        hint format [
+            "%1 \n %2",
+            [_this select 1] call CBA_fnc_getFormattedQTESequence,
+            [_this select 2] call CBA_fnc_getFormattedQTESequence
+        ]
+    }, 
+    { 
+        hint "Finished!"; 
+    },
+    { 
+        hint "Failure!"; 
+    },
+    ["↑", "↓", "→", "←"]] call CBA_fnc_runQTE
+
+Returns:
+    True if the QTE was started, false if it was already running <BOOELAN>
+
+Author:
+    john681611
+---------------------------------------------------------------------------- */
+
+
+params ["_object", "_args", "_onDisplay", "_onFinish", "_onFail", "_qteSequence", ["_maxDistance", 10], ["_timeout", 30]];
+if (GVAR(QTERunning)) exitWith {
+    false
+};
+
+GVAR(QTEHistory) = [];
+GVAR(QTERunning) = true;
+private _startTime = CBA_missionTime;
+private _qteArgsArray = [
+    ["object", _object],
+    ["args", _args],
+    ["onDisplay", _onDisplay],
+    ["onFinish", _onFinish],
+    ["onFail", _onFail],
+    ["maxDistance", _maxDistance],
+    ["qteSeqence", _qteSequence],
+    ["startTime", _startTime],
+    ["timeout", _timeout]
+];
+GVAR(QTEArgs) = createHashMapFromArray _qteArgsArray;
+
+// Setup 
+[{
+    private _timeout = GVAR(QTEArgs) get "timeout";
+    private _object = GVAR(QTEArgs) get "object";
+    private _maxDistance = GVAR(QTEArgs) get "maxDistance";
+    private _elapsedTime = CBA_missionTime - (GVAR(QTEArgs) get "startTime");
+
+    !GVAR(QTERunning) || player distance _object > _maxDistance || _elapsedTime > _timeout;
+}, {
+    TRACE_1("QTE ended",GVAR(QTERunning));
+    if(!GVAR(QTERunning)) exitWith {};
+    GVAR(QTERunning) = false;
+    GVAR(QTEHistory) = [];
+    private _onFail = (GVAR(QTEArgs) get "onFail");
+    private _args = (GVAR(QTEArgs) get "args");
+    TRACE_1("QTE Failed",_args);
+    if (_onFail isEqualType "") then {
+        [_onFail, [_args, _elapsedTime]] call CBA_fnc_localEvent;
+    } else {
+        [_args, _elapsedTime] call _onFail;
+    };
+}, []] call CBA_fnc_waitUntilAndExecute;
+
+if (_onDisplay isEqualType "") then {
+    [_onDisplay, [_args, _qteSequence, []]] call CBA_fnc_localEvent;
+} else {
+    [_args, _qteSequence, []] call _onDisplay;
+};
+
+true

addons/quicktime/script_component.hpp

@@ -0,0 +1,20 @@
+#define COMPONENT quicktime
+#include "\x\cba\addons\main\script_mod.hpp"
+
+//#define DEBUG_MODE_FULL
+//#define DISABLE_COMPILE_CACHE
+//#define DEBUG_ENABLED_quicktime
+
+#ifdef DEBUG_ENABLED_QUICKTIME
+    #define DEBUG_MODE_FULL
+#endif
+
+#ifdef DEBUG_SETTINGS_QUICKTIME
+    #define DEBUG_SETTINGS DEBUG_SETTINGS_QUICKTIME
+#endif
+
+#define DEBUG_SYNCHRONOUS
+#include "\x\cba\addons\main\script_macros.hpp"
+
+#include "\a3\ui_f\hpp\defineResincl.inc"
+

addons/quicktime/stringtable.xml

@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="utf-8"?>
+<Project name="CBA_A3">
+    <Package name="Quicktime">
+        <Key ID="STR_cba_quicktime_QTEKeybindGroup">
+            <English>CBA Quick-Time Events</English>  
+        </Key>
+        <Key ID="STR_cba_quicktime_QTEKeybindUpTooltip">
+            <English>Up key used in Quick-Time Events.</English>  
+        </Key>
+        <Key ID="STR_cba_quicktime_QTEKeybindDownTooltip">
+            <English>Down key used in Quick-Time Events.</English>  
+        </Key>
+        <Key ID="STR_cba_quicktime_QTEKeybindLeftTooltip">
+            <English>Left key used in Quick-Time Events.</English>  
+        </Key>
+        <Key ID="STR_cba_quicktime_QTEKeybindRightTooltip">
+            <English>Right key used in Quick-Time Events.</English>  
+        </Key>
+    </Package>
+</Project>