Add SWISE token

.forge-snapshots/SwiseToken_burn.snap

@@ -0,0 +1 @@
+51418

.forge-snapshots/SwiseToken_mint.snap

@@ -0,0 +1 @@
+92566

.forge-snapshots/SwiseToken_permit.snap

@@ -0,0 +1 @@
+96845

.forge-snapshots/SwiseToken_setController.snap

@@ -0,0 +1 @@
+69655

script/DeployOsToken.s.sol

@@ -3,7 +3,7 @@
 pragma solidity ^0.8.22;
 
 import {Script, console2} from "forge-std/Script.sol";
-import {OsToken} from "../src/OsToken.sol";
+import {OsToken} from "../src/tokens/OsToken.sol";
 
 contract DeployOsToken is Script {
     function run() external {

script/DeploySwiseToken.s.sol

@@ -0,0 +1,22 @@
+// SPDX-License-Identifier: BUSL-1.1
+
+pragma solidity ^0.8.22;
+
+import {Script, console2} from "forge-std/Script.sol";
+import {SwiseToken} from "../src/tokens/SwiseToken.sol";
+
+contract DeploySwiseToken is Script {
+    function run() external {
+        vm.startBroadcast();
+        console2.log("Deploying from: ", msg.sender);
+
+        // Deploy SwiseToken.
+        SwiseToken swiseToken = new SwiseToken(msg.sender, "StakeWise", "SWISE");
+        console2.log("SwiseToken deployed at: ", address(swiseToken));
+
+        vm.stopBroadcast();
+    }
+
+    // excludes this contract from coverage report
+    function test() public {}
+}

src/tokens/SwiseToken.sol

@@ -0,0 +1,70 @@
+// SPDX-License-Identifier: BUSL-1.1
+
+pragma solidity ^0.8.22;
+
+import {Ownable2Step, Ownable} from "@openzeppelin/contracts/access/Ownable2Step.sol";
+import {ERC20Permit, ERC20} from "@openzeppelin/contracts/token/ERC20/extensions/ERC20Permit.sol";
+import {Errors} from "@stakewise-core/libraries/Errors.sol";
+
+/**
+ * @title SwiseToken
+ * @author StakeWise
+ * @notice SwiseToken is an ERC20 token with permit and minting functionality
+ */
+contract SwiseToken is Ownable2Step, ERC20Permit {
+    /**
+     * @notice Emitted when the controller is updated
+     * @param newController The address of the new controller
+     */
+    event ControllerUpdated(address newController);
+
+    address public controller;
+
+    /**
+     * @dev Constructor
+     * @param _owner The address of the contract owner
+     * @param _name The name of the ERC20 token
+     * @param _symbol The symbol of the ERC20 token
+     */
+    constructor(address _owner, string memory _name, string memory _symbol)
+        ERC20(_name, _symbol)
+        ERC20Permit(_name)
+        Ownable(_owner)
+    {}
+
+    /**
+     * @dev Throws if called by any account other than the controller.
+     */
+    modifier onlyController() {
+        if (msg.sender != controller) revert Errors.AccessDenied();
+        _;
+    }
+
+    /**
+     * @notice Mint SwiseToken. Can only be called by the controller.
+     * @param account The address of the account to mint SwiseToken for
+     * @param value The amount of SwiseToken to mint
+     */
+    function mint(address account, uint256 value) external onlyController {
+        _mint(account, value);
+    }
+
+    /**
+     * @notice Burn SwiseToken. Can only be called by the controller.
+     * @param account The address of the account to burn SwiseToken for
+     * @param value The amount of SwiseToken to burn
+     */
+    function burn(address account, uint256 value) external onlyController {
+        _burn(account, value);
+    }
+
+    /**
+     * @notice Set the controller address. Can only be called by the owner.
+     * @param newController The address of the new controller
+     */
+    function setController(address newController) external onlyOwner {
+        if (newController == address(0)) revert Errors.ZeroAddress();
+        controller = newController;
+        emit ControllerUpdated(newController);
+    }
+}

test/OsToken.t.sol → test/tokens/OsToken.t.sol

@@ -7,8 +7,8 @@ import {Errors} from "@stakewise-core/libraries/Errors.sol";
 import {GasSnapshot} from "forge-gas-snapshot/GasSnapshot.sol";
 import {Test} from "forge-std/Test.sol";
 import {Vm} from "forge-std/Vm.sol";
-import {OsToken, IOsToken} from "../src/OsToken.sol";
-import {SigUtils} from "./helpers/SigUtils.sol";
+import {OsToken, IOsToken} from "../../src/tokens/OsToken.sol";
+import {SigUtils} from "../helpers/SigUtils.sol";
 
 contract OsTokenTest is Test, GasSnapshot {
     OsToken osToken;

test/tokens/SwiseToken.t.sol

@@ -0,0 +1,87 @@
+// SPDX-License-Identifier: BUSL-1.1
+
+pragma solidity ^0.8.22;
+
+import {Ownable} from "@openzeppelin/contracts/access/Ownable2Step.sol";
+import {Errors} from "@stakewise-core/libraries/Errors.sol";
+import {GasSnapshot} from "forge-gas-snapshot/GasSnapshot.sol";
+import {Test} from "forge-std/Test.sol";
+import {Vm} from "forge-std/Vm.sol";
+import {SwiseToken} from "../../src/tokens/SwiseToken.sol";
+import {SigUtils} from "../helpers/SigUtils.sol";
+
+contract SwiseTokenTest is Test, GasSnapshot {
+    SwiseToken swiseToken;
+
+    function setUp() public {
+        swiseToken = new SwiseToken(address(this), "test", "test");
+    }
+
+    function test_setController() public {
+        vm.expectRevert(abi.encodeWithSelector(Ownable.OwnableUnauthorizedAccount.selector, address(1)));
+        vm.prank(address(1));
+        swiseToken.setController(address(1));
+
+        vm.expectRevert(abi.encodeWithSelector(Errors.ZeroAddress.selector));
+        swiseToken.setController(address(0));
+
+        vm.expectEmit(false, false, false, true);
+        emit SwiseToken.ControllerUpdated(address(1));
+
+        snapStart("SwiseToken_setController");
+        swiseToken.setController(address(1));
+        snapEnd();
+
+        assertEq(swiseToken.controller(), address(1));
+    }
+
+    function test_mint() public {
+        vm.expectRevert(Errors.AccessDenied.selector);
+        vm.prank(address(1));
+        swiseToken.mint(address(1), 1);
+
+        swiseToken.setController(address(this));
+
+        snapStart("SwiseToken_mint");
+        swiseToken.mint(address(1), 1);
+        snapEnd();
+
+        assertEq(swiseToken.balanceOf(address(1)), 1);
+    }
+
+    function test_burn() public {
+        vm.expectRevert(Errors.AccessDenied.selector);
+        vm.prank(address(1));
+        swiseToken.burn(address(1), 1);
+
+        swiseToken.setController(address(this));
+        swiseToken.mint(address(1), 1);
+
+        snapStart("SwiseToken_burn");
+        swiseToken.burn(address(1), 1);
+        snapEnd();
+
+        assertEq(swiseToken.balanceOf(address(1)), 0);
+    }
+
+    function test_Permit() public {
+        uint256 ownerPrivateKey = 0xA11CE;
+        address owner = vm.addr(ownerPrivateKey);
+        address spender = address(1);
+
+        SigUtils sigUtils = new SigUtils(swiseToken.DOMAIN_SEPARATOR());
+        SigUtils.Permit memory permit =
+            SigUtils.Permit({owner: owner, spender: spender, value: 1e18, nonce: 0, deadline: 1 days});
+
+        bytes32 digest = sigUtils.getTypedDataHash(permit);
+
+        (uint8 v, bytes32 r, bytes32 s) = vm.sign(ownerPrivateKey, digest);
+
+        snapStart("SwiseToken_permit");
+        swiseToken.permit(permit.owner, permit.spender, permit.value, permit.deadline, v, r, s);
+        snapEnd();
+
+        assertEq(swiseToken.allowance(owner, spender), 1e18);
+        assertEq(swiseToken.nonces(owner), 1);
+    }
+}