forgot to add the new files locations in the previous commit, fixing #8

src/tablecloth/time/validatable.clj

@@ -0,0 +1,27 @@
+(ns tablecloth.time.validatable)
+
+(defn add-validatable
+  "Add metadata derived from a few columns,
+  validatable by checking if these columns
+  are identical to their values when it was created."
+  [ds column-names name metadata]
+  (-> ds
+      (vary-meta assoc-in
+                 [:validatable name]
+                 {:column-names column-names
+                  :columns      (select-keys ds column-names)
+                  :metadata         metadata})))
+
+(defn valid?
+  "Check if metadata derived from a few columns is still valid
+  (that is, if the columns have not changed)."
+  [ds name]
+  (let [{:keys [columns column-names]} (-> ds
+                                           meta
+                                           :validatable
+                                           (get name))]
+    (->> column-names
+         (every? (fn [column-name]
+                   (identical? (ds column-name)
+                               (columns column-name)))))))
+

test/tablecloth/time/validatable_test.clj

@@ -0,0 +1,25 @@
+(ns tablecloth.time.validatable-test
+  (:require [clojure.test :refer [deftest is]]
+            [tablecloth.api :as tablecloth]
+            [tablecloth.time.validatable :as validatable]))
+
+(deftest validatable-test
+  (let [ds (tablecloth/dataset {:x [1 2 3]
+                                :y [4 5 6]})
+        ds-with-validatable (validatable/add-validatable ds
+                                             [:x]
+                                             :id1
+                                             9999)]
+    (is (-> ds-with-validatable
+            (tablecloth/select-rows [0 2])
+            (validatable/valid? :id1)
+            not))
+    (is (-> ds-with-validatable
+            (tablecloth/add-or-replace-column :x 9)
+            (validatable/valid? :id1)
+            not))
+    (is (-> ds-with-validatable
+            (tablecloth/add-or-replace-column :z 9)
+            (validatable/valid? :id1)))))
+
+