Adding support for ga403

asus/zephyrus/ga403/default.nix

@@ -0,0 +1,93 @@
+{ config,
+  pkgs,
+  lib,
+  ...
+}:
+
+let
+  inherit (lib) mkDefault mkEnableOption mkIf mkMerge mkForce version versionAtLeast versionOlder;
+in {
+
+  imports = [
+    ../../../common/cpu/amd
+    ../../../common/cpu/amd/pstate.nix
+    ../../../common/gpu/amd
+    ../../../common/pc/laptop
+    ../../../common/pc/laptop/acpi_call.nix
+    ../../../common/pc/ssd
+    ../../../common/gpu/nvidia/prime.nix
+    ../../../common/gpu/nvidia/ada-lovelace
+  ];
+
+  config = mkMerge [
+    {
+      # Configure basic system settings:
+      boot = {
+        kernelPackages = mkDefault pkgs.linuxPackages_latest;
+        kernelModules = [ "kvm-amd" ];
+        kernelParams = [
+          "mem_sleep_default=deep"
+          "pcie_aspm.policy=powersupersave"
+        ];
+      };
+
+      services = {
+        asusd = {
+          enable = mkDefault true;
+          enableUserService = mkDefault true;
+        };
+
+        supergfxd.enable = mkDefault true;
+      };
+
+      # Enable the Nvidia card, as well as Prime and Offload: NVIDIA GeForce RTX 4060 Mobile
+      boot.blacklistedKernelModules = [ "nouveau" ];
+
+      services.xserver.videoDrivers = mkForce [ "amdgpu" "nvidia" ];
+
+      hardware = {
+        amdgpu.initrd.enable = mkDefault true;
+
+        nvidia = {
+          modesetting.enable = true;
+          nvidiaSettings = mkDefault true;
+
+          prime = {
+            offload = {
+              enable = mkDefault true;
+              enableOffloadCmd = mkDefault true;
+            };
+            amdgpuBusId = "PCI:101:0:0";
+            nvidiaBusId = "PCI:1:0:0";
+          };
+
+          powerManagement = {
+            enable = true;
+            finegrained = true;
+          };
+        };
+      };
+    }
+
+    (mkIf (versionOlder version "23.11") {
+      # See https://asus-linux.org/wiki/nixos/ for info about some problems
+      # detecting the dGPU:
+      systemd.services.supergfxd.path = [ pkgs.pciutils ];
+    })
+
+    (mkIf (config.networking.wireless.iwd.enable && config.networking.wireless.scanOnLowSignal) {
+      # Meditek doesn't seem to be quite sensitive enough on the default roaming settings:
+      #   https://wiki.archlinux.org/title/Wpa_supplicant#Roaming
+      #   https://wiki.archlinux.org/title/Iwd#iwd_keeps_roaming
+      #
+      # But NixOS doesn't have the tweaks for IWD, yet.
+      networking.wireless.iwd.settings = {
+        General = {
+          RoamThreshold = -75;
+          RoamThreshold5G = -80;
+          RoamRetryInterval = 20;
+        };
+      };
+    })
+  ];
+}

common/gpu/nvidia/ada-lovelace/default.nix

@@ -7,4 +7,22 @@ in
 
   # enable the open source drivers if the package supports it
   hardware.nvidia.open = lib.mkOverride 990 (nvidiaPackage ? open && nvidiaPackage ? firmware);
+
+  # nvidia's hibernate, suspend, and resume services are not normally triggered on suspend-then-hibernate and hybrid-hibernate
+  systemd.services = {
+    nvidia-hibernate = {
+      before = [ "systemd-suspend-then-hibernate.service" ];
+      wantedBy = [ "suspend-then-hibernate.target" ];
+    };
+
+    nvidia-suspend = {
+      before = [ "systemd-hybrid-sleep.service" ];
+      wantedBy = [ "hybrid-sleep.target" ];
+    };
+
+    nvidia-resume = {
+      after = [ "systemd-suspend-then-hibernate.service" "systemd-hybrid-sleep.service" ];
+      wantedBy = [ "post-resume.target" ];
+    };
+  };
 }

flake.nix

@@ -45,6 +45,7 @@
         asus-zephyrus-ga402x = import ./asus/zephyrus/ga402x;
         asus-zephyrus-ga402x-amdgpu = import ./asus/zephyrus/ga402x/amdgpu;
         asus-zephyrus-ga402x-nvidia = import ./asus/zephyrus/ga402x/nvidia;
+        asus-zephyrus-ga403 = import ./asus/zephyrus/ga403;
         asus-zephyrus-ga502 = import ./asus/zephyrus/ga502;
         asus-zephyrus-ga503 = import ./asus/zephyrus/ga503;
         asus-zephyrus-gu603h = import ./asus/zephyrus/gu603h;