build.gradle

plugins {
    id 'java-gradle-plugin'
    id 'maven-publish'
    id 'groovy'
    id 'java'
    id "com.gradle.plugin-publish" version "0.15.0"
}


dependencies {
    implementation 'org.ajoberstar.grgit:grgit-core:5.0.0'
    testImplementation 'junit:junit:4.12'
    testImplementation 'com.github.stefanbirkner:system-rules:1.19.0'
    testImplementation 'com.github.stefanbirkner:system-lambda:1.1.1'
}

repositories {
    maven {
        url = 'https://frcmaven.wpi.edu/artifactory/ex-mvn'
    }
}

version = '2024.0.0'
group = 'edu.wpi.first.wpilib.versioning'

pluginBundle {
    website = 'https://github.com/wpilibsuite/wpilib-version-plugin'
    vcsUrl = 'https://github.com/wpilibsuite/wpilib-version-plugin'
    description = 'This plugin provides maven remote settings and versioning for the WPILib Suite FRC projects.'
    tags = ['groovy', 'version', 'maven', 'frc', 'wpilib']

    plugins {
        wpilibVersionPlugin {
            id = 'edu.wpi.first.wpilib.versioning.WPILibVersioningPlugin'
            displayName = 'WPILib Version Plugin'
        }
    }
}

gradlePlugin {
    plugins {
        wpilibVersionPlugin {
            id = 'edu.wpi.first.wpilib.versioning.WPILibVersioningPlugin'
            implementationClass = 'edu.wpi.first.wpilib.versioning.WPILibVersioningPlugin'
        }
    }
}

tasks.withType(Test).configureEach {
    jvmArgs(["--add-opens=java.base/java.lang=ALL-UNNAMED",
             "--add-opens=java.base/java.util=ALL-UNNAMED"])
}

tasks.withType(Javadoc) {
    options.addBooleanOption('Xdoclint:all,-missing', true)
}

tasks.withType(JavaCompile) {
    options.compilerArgs << '-Xlint:unchecked'
    options.deprecation = true
}

wrapper {
    gradleVersion = '7.5.1'
}