build.gradle

//file:noinspection GradlePackageVersionRange
plugins {
    id 'fabric-loom' version '1.4-SNAPSHOT'
    id 'maven-publish'
}

version = "${project.mod_version}+${project.minecraft_base_version}"
group = project.maven_group

repositories {
    maven   { url = "https://maven.terraformersmc.com/" }
    maven   { url = "https://maven.ladysnake.org/releases" }
    maven   { url = "https://maven.shedaniel.me/" }
    maven   { url = "https://maven.wispforest.io/" }
    maven   { url = "https://api.modrinth.com/maven/" }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    modImplementation include("dev.onyxstudios.cardinal-components-api:cardinal-components-base:${project.cca_version}")
    modImplementation include("dev.onyxstudios.cardinal-components-api:cardinal-components-entity:${project.cca_version}")

    // REI
    modCompileOnly "me.shedaniel:RoughlyEnoughItems-api-fabric:${project.rei_version}"
    modLocalRuntime "me.shedaniel:RoughlyEnoughItems-fabric:${project.rei_version}"
    modLocalRuntime "dev.architectury:architectury-fabric:8.1.73"

    // Stacc
    modLocalRuntime include("maven.modrinth:stacc-api:${project.stacc_version}")

    // ModMenu
    modImplementation "com.terraformersmc:modmenu:${project.modmenu_version}"

    // oωo
    modImplementation annotationProcessor("io.wispforest:owo-lib:${project.owo_version}")
    modCompileOnly include("io.wispforest:owo-sentinel:${project.owo_version}")
}

base {
    archivesName = project.archives_base_name
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    // Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
    it.options.release = 17
}

java {
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

jar {
    from("LICENSE") {
        rename { "${it}_${base.archivesName.get()}"}
    }
}