-
-
Notifications
You must be signed in to change notification settings - Fork 1
/
SlidableView.mc
277 lines (240 loc) · 8.45 KB
/
SlidableView.mc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
using Toybox.WatchUi as Ui;
using Toybox.Graphics as Gfx;
using UniTimer;
class SlidableView extends Ui.Drawable {
// Slideable drawables
private var prevDrawable as Drawable = null;
private var currentDrawable as Drawable = null;
// General positioning values
private var centerX;
private var centerY;
private var currentDrawablePositionY;
private var drawableHeight;
// General color scheme
private var primaryValueColor = Gfx.COLOR_WHITE;
private var altValueColor = Gfx.COLOR_WHITE;
// Animation-related values
private var animationTimer;
private var slideAnimator;
private var shakeAnimator;
private var applyAltColor = false;
function initialize(identifier, centerX, centerY) {
Drawable.initialize({:identifier => identifier});
me.centerX = centerX;
me.centerY = centerY;
animationTimer = UniTimer.getTimer();
slideAnimator = new SlideAnimator(animationTimer, method(:onFinishSlideAnimation));
shakeAnimator = new ShakeAnimator(animationTimer);
}
function draw(dc) {
if (currentDrawable != null) {
drawCurrentDrawable(dc);
}
if (prevDrawable != null) {
drawPrevDrawable(dc);
}
}
private function drawCurrentDrawable(dc) {
dc.setClip(0, currentDrawablePositionY, dc.getWidth(), currentDrawable.height);
var positionY = currentDrawablePositionY;
var offsetY = slideAnimator.getDrawablePositionOffsetY();
switch (slideAnimator.getAnimation()) {
case SLIDE_UP:
positionY += offsetY;
break;
case SLIDE_DOWN:
positionY -= offsetY;
break;
}
currentDrawable.setLocation(centerX + shakeAnimator.getShakeOffsetX(), positionY);
currentDrawable.draw(dc);
dc.clearClip();
}
private function drawPrevDrawable(dc) {
var positionY = currentDrawablePositionY;
var offsetY = prevDrawable.height - slideAnimator.getDrawablePositionOffsetY();
switch (slideAnimator.getAnimation()) {
case SLIDE_UP:
positionY -= offsetY;
break;
case SLIDE_DOWN:
positionY += offsetY;
break;
default:
return;
}
dc.setClip(0, currentDrawablePositionY, dc.getWidth(), prevDrawable.height);
prevDrawable.setLocation(centerX, positionY);
prevDrawable.draw(dc);
dc.clearClip();
}
private function getCurrentDrawableColor() {
if (applyAltColor) {
return altValueColor;
} else {
return primaryValueColor;
}
}
function onFinishSlideAnimation() {
applyAltColor = false;
if (currentDrawable != null) {
currentDrawable.setColor(getCurrentDrawableColor());
}
}
function pushDrawable(newDrawable, animation as PushAnimation) {
var prevDrawableBuffer = currentDrawable;
currentDrawable = newDrawable;
if (newDrawable != null) {
drawableHeight = currentDrawable.height;
}
if (!slideAnimator.isAnimationActive() && drawableHeight != null) {
prevDrawable = prevDrawableBuffer;
if (prevDrawable != null) {
prevDrawable.setColor(primaryValueColor);
}
currentDrawablePositionY = centerY - (drawableHeight / 2);
if (animation != SLIDE_NONE) {
slideAnimator.start(animation, drawableHeight);
} else {
slideAnimator.reset();
}
} else {
applyAltColor = true;
}
if (currentDrawable != null) {
currentDrawable.setColor(getCurrentDrawableColor());
}
}
function setPrimaryColor(color as Graphics.ColorType) {
primaryValueColor = color;
if (currentDrawable != null && !applyAltColor) {
currentDrawable.setColor(color);
}
if (prevDrawable != null) {
prevDrawable.setColor(color);
}
}
function setAltColor(color as Graphics.ColorType) {
altValueColor = color;
if (currentDrawable != null && applyAltColor) {
currentDrawable.setColor(color);
}
}
function shake() {
if (!slideAnimator.isAnimationActive()) {
shakeAnimator.start();
}
}
static enum PushAnimation {
SLIDE_NONE, SLIDE_DOWN, SLIDE_UP
}
class SlideAnimator {
private const ANIMATION_DURATION_MILLIS = 170;
private const ANIMATION_FREQUENCY = 50;
private var timerKey = "sliadable_animation_slide_" + hashCode();
private var topTranslateTheshold;
private var drawablePositionOffsetY;
private var frameStep = null;
private var animation as PushAnimation;
private var animationActive = false;
private var animationTimer;
private var drawableHeight;
private var finishCallback as Method();
function initialize(animationTimer, finishCallback as Method()) {
me.animationTimer = animationTimer;
me.finishCallback = finishCallback;
}
function getAnimation() as PushAnimation {
return animation;
}
function getDrawablePositionOffsetY() {
return drawablePositionOffsetY;
}
private function evaluateSlideFrameStep() {
if (frameStep == null || frameStep == 0) {
var transitionLength = drawableHeight;
frameStep = (transitionLength / (ANIMATION_DURATION_MILLIS / ANIMATION_FREQUENCY))
.toNumber();
}
}
function requestSlideFrameUpdate() {
evaluateSlideFrameStep();
if (drawablePositionOffsetY <= 0) {
finishSlideAnimation();
} else {
drawablePositionOffsetY = drawablePositionOffsetY - frameStep;
if (drawablePositionOffsetY <= 0) {
drawablePositionOffsetY = 0;
finishSlideAnimation();
}
}
Ui.requestUpdate();
}
private function finishSlideAnimation() {
animationTimer.stop(timerKey);
animationActive = false;
if (finishCallback != null) {
finishCallback.invoke();
}
}
function isAnimationActive() as Boolean {
return animationActive;
}
function start(animation, drawableHeight) {
me.drawableHeight = drawableHeight;
me.animation = animation;
drawablePositionOffsetY = drawableHeight;
animationTimer.start(
timerKey,
method(:requestSlideFrameUpdate),
ANIMATION_FREQUENCY,
true
);
animationActive = true;
}
function reset() {
animation = SLIDE_NONE;
drawablePositionOffsetY = 0;
Ui.requestUpdate();
}
}
class ShakeAnimator {
private const ANIMATION_DURATION_MILLIS = 170;
private const ANIMATION_FREQUENCY = 50;
private const ANIMATION_SHAKE_ITERATIONS = 4;
private const ANIMATION_SHAKE_TRANSLATE = 9;
private var timerKey = "sliadable_animation_shake_" + hashCode();
private var shakeOffsetX = 0;
private var shakeIteration = 0;
private var animationTimer;
function initialize(animationTimer) {
me.animationTimer = animationTimer;
}
function getShakeOffsetX() {
return shakeOffsetX;
}
function requestShakeFrameUpdate() {
if (shakeIteration >= ANIMATION_SHAKE_ITERATIONS) {
animationTimer.stop(timerKey);
shakeOffsetX = 0;
shakeIteration = 0;
} else {
shakeIteration++;
if (shakeOffsetX < 0) {
shakeOffsetX = ANIMATION_SHAKE_TRANSLATE;
} else {
shakeOffsetX = ANIMATION_SHAKE_TRANSLATE * -1;
}
}
Ui.requestUpdate();
}
function start() {
animationTimer.start(
timerKey,
method(:requestShakeFrameUpdate),
ANIMATION_FREQUENCY,
true
);
}
}
}