-
Notifications
You must be signed in to change notification settings - Fork 7
/
BitmapPixels.pas
1535 lines (1428 loc) · 41.8 KB
/
BitmapPixels.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// -----------------------------------------------------------------------------
// *** BitmapPixels ***
// version 1.1, last update 13.12.2021
// -----------------------------------------------------------------------------
// Module for direct access to pixels at TBitmap
// Tested on Windows(WinApi), Linux(Gtk2, Qt5), OSX(Cocoa)
// -----------------------------------------------------------------------------
//
// Latest verion of this unit aviable here:
// https://github.com/crazzzypeter/BitmapPixels/
//
// GitHub: https://github.com/crazzzypeter/
// Twitch: https://www.twitch.tv/crazzzypeter/
// YouTube: https://www.youtube.com/c/crazzzypeter/
// YouTube?: https://www.youtube.com/channel/UCPQmDZGb5mZJ27ev9-t3bGQ/
// Telegram: @crazzzypeter
//
// -----------------------------------------------------------------------------
// MIT LICENSE
//
// Copyright (c) 2021-2021 CrazzzyPeter
//
// Permission is hereby granted, free of charge, to any person obtaining a copy
// of this software and associated documentation files (the "Software"), to deal
// in the Software without restriction, including without limitation the rights
// to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
// copies of the Software, and to permit persons to whom the Software is
// furnished to do so, subject to the following conditions:
//
// The above copyright notice and this permission notice shall be included in
// all copies or substantial portions of the Software.
//
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
// IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
// FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
// AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
// LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
// OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
// SOFTWARE.
// -----------------------------------------------------------------------------
{$REGION 'Examples'}
{
Examples of use:
--- 1 ---
procedure InvertColors(const Bitmap: TBitmap);
var
Data: TBitmapData;
X, Y: Integer;
Pixel: TPixelRec;
begin
Data.Map(Bitmap, TAccessMode.ReadWrite, False);// RGB access
try
for Y := 0 to Data.Height - 1 do
begin
for X := 0 to Data.Width - 1 do
begin
Pixel := Data.GetPixel(X, Y);
Pixel.R := 255 - Pixel.R;
Pixel.G := 255 - Pixel.G;
Pixel.B := 255 - Pixel.B;
Data.SetPixel(X, Y, Pixel);
end;
end;
finally
Data.Unmap();
end;
end;
--- 2 ---
procedure HalfAlpha(const Bitmap: TBitmap);
var
Data: TBitmapData;
X, Y: Integer;
Pixel: TPixelRec;
begin
Data.Map(Bitmap, TAccessMode.ReadWrite, True);// ARGB access
try
for Y := 0 to Data.Height - 1 do
begin
for X := 0 to Data.Width - 1 do
begin
Pixel := Data.GetPixel(X, Y);
Pixel.A := Pixel.A div 2;
Data.SetPixel(X, Y, Pixel);
end;
end;
finally
Data.Unmap();
end;
end;
--- 3 ---
function MakePlasm(): TBitmap;
var
Data: TBitmapData;
X, Y: Integer;
Pixel: TPixelRec;
begin
Result := TBitmap.Create();
Result.SetSize(300, 300);
Data.Map(Result, TAccessMode.Write, False);
try
for Y := 0 to Data.Height - 1 do
begin
for X := 0 to Data.Width - 1 do
begin
Pixel.R := Byte(Trunc(
100 + 100 * (Sin(X * Cos(Y * 0.049) * 0.01) + Cos(X * 0.0123 - Y * 0.09))));
Pixel.G := 0;
Pixel.B := Byte(Trunc(
Pixel.R + 100 * (Sin(X * Cos(X * 0.039) * 0.022) + Sin(X * 0.01 - Y * 0.029))));
Data.SetPixel(X, Y, Pixel);
end;
end;
finally
Data.Unmap();
end;
end;
--- 4 ---
function Mix(const A, B: TBitmap): TBitmap;
function Min(A, B: Integer): Integer;
begin
if A < B then Exit(A) else Exit(B);
end;
var
DataA, DataB, DataResult: TBitmapData;
X, Y: Integer;
PixelA, PixelB, PixelResult: TPixelRec;
begin
Result := TBitmap.Create();
Result.SetSize(Min(A.Width, B.Width), Min(A.Height, B.Height));
// this needed for correct Unmap() on exception
DataA.Init();
DataB.Init();
DataResult.Init();
try
DataA.Map(A, TAccessMode.Read, False);
DataB.Map(B, TAccessMode.Read, False);
DataResult.Map(Result, TAccessMode.Write, False);
for Y := 0 to DataResult.Height - 1 do
begin
for X := 0 to DataResult.Width - 1 do
begin
PixelA := DataA.Pixels[X, Y];
PixelB := DataB.Pixels[X, Y];
PixelResult.R := (PixelA.R + PixelB.R) div 2;
PixelResult.G := (PixelA.G + PixelB.G) div 2;
PixelResult.B := (PixelA.B + PixelB.B) div 2;
DataResult[X, Y] := PixelResult;
end;
end;
finally
DataA.Unmap();
DataB.Unmap();
DataResult.Unmap();
end;
end;
}
{$ENDREGION}
unit BitmapPixels;
{$IFDEF FPC}{$MODE DELPHI}{$ENDIF}
{$SCOPEDENUMS ON}
{$POINTERMATH ON}
interface
uses
{$IFNDEF FPC}Windows,{$ENDIF} Classes, SysUtils, Graphics{$IFDEF FPC}, FPImage{$ENDIF};
type
// $AARRGGBB
TPixel = Cardinal;
PPixel = ^TPixel;
TPixelArray = array [0..High(Integer) div SizeOf(TPixel) - 1] of TPixel;
PPixelArray = ^TPixelArray;
TAccessMode = (Read, Write, ReadWrite);
{ TBitmapData }
TBitmapData = record
private
FData: PPixelArray;
FBitmap: TBitmap;
FWidth: Integer;
FHeight: Integer;
FAccessMode: TAccessMode;
FHasAlpha: Boolean;
FDataArray: array of TPixel;// do not use this
public
procedure Init();
procedure Map(const Bitmap: TBitmap; const Mode: TAccessMode; const UseAlpha: Boolean;
const Background: TColor = clNone);
procedure Unmap();
function GetPixel(X, Y: Integer): TPixel; inline;
procedure SetPixel(X, Y: Integer; AValue: TPixel); inline;
function GetPixelUnsafe(X, Y: Integer): TPixel; inline;
procedure SetPixelUnsafe(X, Y: Integer; AValue: TPixel); inline;
property Data: PPixelArray read FData;
property HasAlpha: Boolean read FHasAlpha;
property Width: Integer read FWidth;
property Height: Integer read FHeight;
property Pixels[X, Y: Integer]: TPixel read GetPixel write SetPixel; default;
end;
{ TPixelRec }
TPixelRec = packed record
constructor Create(const R, G, B: Byte; const A: Byte = 255);
class operator Implicit(Pixel: TPixel): TPixelRec; inline;
class operator Implicit(Pixel: TPixelRec): TPixel; inline;
case Byte of
0: (B, G, R, A: Byte);
1: (Color: TPixel);
end;
TPixelColors = record
{$REGION 'HTML Colors'}
const
AliceBlue = $FFF0F8FF;
AntiqueWhite = $FFFAEBD7;
Aqua = $FF00FFFF;
Aquamarine = $FF7FFFD4;
Azure = $FFF0FFFF;
Beige = $FFF5F5DC;
Bisque = $FFFFE4C4;
Black = $FF000000;
BlanchedAlmond = $FFFFEBCD;
Blue = $FF0000FF;
BlueViolet = $FF8A2BE2;
Brown = $FFA52A2A;
BurlyWood = $FFDEB887;
CadetBlue = $FF5F9EA0;
Chartreuse = $FF7FFF00;
Chocolate = $FFD2691E;
Coral = $FFFF7F50;
CornflowerBlue = $FF6495ED;
Cornsilk = $FFFFF8DC;
Crimson = $FFDC143C;
Cyan = $FF00FFFF;
DarkBlue = $FF00008B;
DarkCyan = $FF008B8B;
DarkGoldenrod = $FFB8860B;
DarkGray = $FFA9A9A9;
DarkGreen = $FF006400;
DarkKhaki = $FFBDB76B;
DarkMagenta = $FF8B008B;
DarkOliveGreen = $FF556B2F;
DarkOrange = $FFFF8C00;
DarkOrchid = $FF9932CC;
DarkRed = $FF8B0000;
DarkSalmon = $FFE9967A;
DarkSeaGreen = $FF8FBC8F;
DarkSlateBlue = $FF483D8B;
DarkSlateGray = $FF2F4F4F;
DarkTurquoise = $FF00CED1;
DarkViolet = $FF9400D3;
DeepPink = $FFFF1493;
DeepSkyBlue = $FF00BFFF;
DimGray = $FF696969;
DodgerBlue = $FF1E90FF;
FireBrick = $FFB22222;
FloralWhite = $FFFFFAF0;
ForestGreen = $FF228B22;
Fuchsia = $FFFF00FF;
Gainsboro = $FFDCDCDC;
GhostWhite = $FFF8F8FF;
Gold = $FFFFD700;
Goldenrod = $FFDAA520;
Gray = $FF808080;
Green = $FF008000;
GreenYellow = $FFADFF2F;
Honeydew = $FFF0FFF0;
HotPink = $FFFF69B4;
IndianRed = $FFCD5C5C;
Indigo = $FF4B0082;
Ivory = $FFFFFFF0;
Khaki = $FFF0E68C;
Lavender = $FFE6E6FA;
LavenderBlush = $FFFFF0F5;
LawnGreen = $FF7CFC00;
LemonChiffon = $FFFFFACD;
LightBlue = $FFADD8E6;
LightCoral = $FFF08080;
LightCyan = $FFE0FFFF;
LightGoldenrodYellow = $FFFAFAD2;
LightGreen = $FF90EE90;
LightGrey = $FFD3D3D3;
LightPink = $FFFFB6C1;
LightSalmon = $FFFFA07A;
LightSeaGreen = $FF20B2AA;
LightSkyBlue = $FF87CEFA;
LightSlateGray = $FF778899;
LightSteelBlue = $FFB0C4DE;
LightYellow = $FFFFFFE0;
Lime = $FF00FF00;
LimeGreen = $FF32CD32;
Linen = $FFFAF0E6;
Magenta = $FFFF00FF;
Maroon = $FF800000;
MediumAquamarine = $FF66CDAA;
MediumBlue = $FF0000CD;
MediumOrchid = $FFBA55D3;
MediumPurple = $FF9370DB;
MediumSeaGreen = $FF3CB371;
MediumSlateBlue = $FF7B68EE;
MediumSpringGreen = $FF00FA9A;
MediumTurquoise = $FF48D1CC;
MediumVioletRed = $FFC71585;
MidnightBlue = $FF191970;
MintCream = $FFF5FFFA;
MistyRose = $FFFFE4E1;
Moccasin = $FFFFE4B5;
NavajoWhite = $FFFFDEAD;
Navy = $FF000080;
OldLace = $FFFDF5E6;
Olive = $FF808000;
OliveDrab = $FF6B8E23;
Orange = $FFFFA500;
OrangeRed = $FFFF4500;
Orchid = $FFDA70D6;
PaleGoldenrod = $FFEEE8AA;
PaleGreen = $FF98FB98;
PaleTurquoise = $FFAFEEEE;
PaleVioletRed = $FFDB7093;
PapayaWhip = $FFFFEFD5;
PeachPuff = $FFFFDAB9;
Peru = $FFCD853F;
Pink = $FFFFC0CB;
Plum = $FFDDA0DD;
PowderBlue = $FFB0E0E6;
Purple = $FF800080;
Red = $FFFF0000;
RosyBrown = $FFBC8F8F;
RoyalBlue = $FF4169E1;
SaddleBrown = $FF8B4513;
Salmon = $FFFA8072;
SandyBrown = $FFF4A460;
SeaGreen = $FF2E8B57;
Seashell = $FFFFF5EE;
Sienna = $FFA0522D;
Silver = $FFC0C0C0;
SkyBlue = $FF87CEEB;
SlateBlue = $FF6A5ACD;
SlateGray = $FF708090;
Snow = $FFFFFAFA;
SpringGreen = $FF00FF7F;
SteelBlue = $FF4682B4;
Tan = $FFD2B48C;
Teal = $FF008080;
Thistle = $FFD8BFD8;
Tomato = $FFFF6347;
Turquoise = $FF40E0D0;
Violet = $FFEE82EE;
Wheat = $FFF5DEB3;
White = $FFFFFFFF;
WhiteSmoke = $FFF5F5F5;
Yellow = $FFFFFF00;
YellowGreen = $FF9ACD32;
{$ENDREGION}
end;
function MakePixel(const R, G, B: Byte; const A: Byte = 255): TPixel; inline;
function PixelGetA(const Pixel: TPixel): Byte; inline;
function PixelGetR(const Pixel: TPixel): Byte; inline;
function PixelGetG(const Pixel: TPixel): Byte; inline;
function PixelGetB(const Pixel: TPixel): Byte; inline;
{$IFDEF FPC}
function FPColorToPixel(const FPColor: TFPColor): TPixel; inline;
function PixelToFPColor(const Pixel: TPixel): TFPColor; inline;
{$ENDIF}
function ColorToPixel(const Color: TColor): TPixel; inline;
function PixelToColor(const Pixel: TPixel): TColor; inline;
implementation
{$IFDEF FPC}
uses
IntfGraphics, GraphType, LCLType, LCLIntf;
{$ENDIF}
function MakePixel(const R, G, B: Byte; const A: Byte): TPixel; inline;
begin
Result := B or (G shl 8) or (R shl 16) or (A shl 24);
end;
function PixelGetA(const Pixel: TPixel): Byte; inline;
begin
Result := (Pixel shr 24) and $FF;
end;
function PixelGetR(const Pixel: TPixel): Byte; inline;
begin
Result := (Pixel shr 16) and $FF;
end;
function PixelGetG(const Pixel: TPixel): Byte; inline;
begin
Result := (Pixel shr 8) and $FF;
end;
function PixelGetB(const Pixel: TPixel): Byte; inline;
begin
Result := Pixel and $FF;
end;
{$IFDEF FPC}
function FPColorToPixel(const FPColor: TFPColor): TPixel; inline;
begin
Result:=
((FPColor.Blue shr 8) and $ff) or
(FPColor.Green and $ff00) or
((FPColor.Red shl 8) and $ff0000) or
((FPColor.Alpha shl 16) and $ff000000);
end;
function PixelToFPColor(const Pixel: TPixel): TFPColor; inline;
begin
Result.Red := (Pixel and $ff0000) shr 8;
Result.Red := Result.Red + (Result.Red shr 8);
Result.Green := (Pixel and $ff00);
Result.Green := Result.Green + (Result.Green shr 8);
Result.Blue := (Pixel and $ff);
Result.Blue := Result.Blue + (Result.Blue shl 8);
Result.Alpha := (Pixel and $ff000000) shr 16;
Result.Alpha := Result.Alpha + (Result.Alpha shr 8);
end;
{$ENDIF}
function ColorToPixel(const Color: TColor): TPixel; inline;
begin
Result:=
(Color and $0000FF00) or
((Color shr 16) and $000000FF) or
((Color shl 16) and $00FF0000) or
$FF000000;
end;
function PixelToColor(const Pixel: TPixel): TColor; inline;
begin
Result:=
(Pixel and $0000FF00) or
((Pixel shr 16) and $000000FF) or
((Pixel shl 16) and $00FF0000);
end;
function SwapRedBlueChanel(const Pixel: TPixel): TPixel; inline;
begin
Result:=
(Pixel and $FF00FF00) or
((Pixel shr 16) and $000000FF) or
((Pixel shl 16) and $00FF0000);
end;
procedure BlendData(var BitmapData: TBitmapData; const Background: TColor);
var
I: Integer;
R, G, B, A: Byte;
DestR, DestG, DestB: Byte;
C: TPixel;
begin
DestR := Background and $FF;
DestG := (Background shr 8) and $FF;
DestB := (Background shr 16) and $FF;
for I := 0 to BitmapData.FWidth * BitmapData.FHeight - 1 do
begin
C := BitmapData.FData[I];
// read
B := C and $FF;
G := (C shr 8) and $FF;
R := (C shr 16) and $FF;
A := (C shr 24) and $FF;
// blend
B := ((B * A) + (DestB * (255 - A))) div 255;
G := ((G * A) + (DestG * (255 - A))) div 255;
R := ((R * A) + (DestR * (255 - A))) div 255;
// write
BitmapData.FData[I] := B or ((G shl 8) and $0000FF00) or ((R shl 16) and $00FF0000);
end;
end;
{$IFDEF FPC}
// FPC ACCESS
procedure ReadData(var BitmapData: TBitmapData);
var
IntfImage: TLazIntfImage;
X, Y, Position: Integer;
begin
IntfImage := BitmapData.FBitmap.CreateIntfImage();
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
for X := 0 to BitmapData.FWidth - 1 do
begin
BitmapData.FData[Position] := FPColorToPixel(IntfImage.Colors[X, Y]);
Inc(Position, 1);
end;
end;
finally
IntfImage.Free();
end;
end;
{function MakeNativeGtk2RawImageDescription(const Width, Height: Integer): TRawImageDescription;
begin
Result.Init;
Result.Format := ricfRGBA;
Result.Width := Width;
Result.Height := Height;
Result.Depth := 32;
Result.BitOrder := riboBitsInOrder;
Result.ByteOrder := riboLSBFirst;
Result.LineOrder := riloTopToBottom;
Result.LineEnd := rileDWordBoundary;
Result.BitsPerPixel := 32;
Result.RedPrec := 8;
Result.RedShift := 0;
Result.GreenPrec := 8;
Result.GreenShift := 8;
Result.BluePrec := 8;
Result.BlueShift := 16;
Result.AlphaPrec := 8;
Result.AlphaShift := 24;
Result.MaskBitsPerPixel := 0;
Result.MaskShift := 0;
Result.MaskLineEnd := rileByteBoundary;
Result.MaskBitOrder := riboBitsInOrder;
Result.PaletteColorCount := 0;
Result.PaletteBitsPerIndex := 0;
Result.PaletteShift := 0;
Result.PaletteLineEnd := rileTight;
Result.PaletteBitOrder := riboBitsInOrder;
Result.PaletteByteOrder := riboLSBFirst;
end;}
{$IF DEFINED(LCLGTK2) OR DEFINED(WINDOWS)}
procedure WriteData(var BitmapData: TBitmapData);
var
Position: Integer;
RawImage: TRawImage;
begin
if BitmapData.FHasAlpha then
begin
RawImage.Init();
RawImage.Description.Init_BPP32_B8G8R8A8_BIO_TTB(BitmapData.FWidth, BitmapData.FHeight);
RawImage.Data := PByte(@(BitmapData.FData[0]));
RawImage.DataSize := BitmapData.FWidth * BitmapData.FHeight * SizeOf(TPixel);
BitmapData.FBitmap.LoadFromRawImage(RawImage, False);
end else
begin
RawImage.Init();
RawImage.Description.Init_BPP32_B8G8R8_BIO_TTB(BitmapData.FWidth, BitmapData.FHeight);
RawImage.DataSize := BitmapData.FWidth * BitmapData.FHeight * SizeOf(TPixel);
RawImage.CreateData(False);
try
for Position := 0 to BitmapData.FWidth * BitmapData.FHeight - 1 do
begin
PPixel(RawImage.Data)[Position] := BitmapData.Data[Position] and $00FFFFFF;
end;
BitmapData.FBitmap.LoadFromRawImage(RawImage, False);
finally
RawImage.FreeData();
end;
end;
end;
{$ELSE}
procedure WriteData(var BitmapData: TBitmapData);
var
IntfImage: TLazIntfImage;
X, Y, Position: Integer;
//RawImage: TRawImage;
begin
if BitmapData.FHasAlpha then
IntfImage := TLazIntfImage.Create(BitmapData.FWidth, BitmapData.FHeight, [riqfRGB, riqfAlpha])
else
IntfImage := TLazIntfImage.Create(BitmapData.FWidth, BitmapData.FHeight, [riqfRGB]);
try
IntfImage.CreateData();
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
for X := 0 to BitmapData.FWidth - 1 do
begin
IntfImage.Colors[X, Y] := PixelToFPColor(BitmapData.FData[Position]);
Inc(Position, 1);
end;
end;
BitmapData.FBitmap.LoadFromIntfImage(IntfImage);
// IntfImage.GetRawImage(RawImage, True);
// BitmapData.FBitmap.LoadFromRawImage(RawImage, True);
finally
IntfImage.Free();
end;
end;
{$ENDIF}
procedure ReadDataRGB(var BitmapData: TBitmapData);
var
pSrc: PByte;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
pSrc := PByte(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
BitmapData.FData[Position] := (pSrc[0] shl 16) or (pSrc[1] shl 8) or pSrc[2];
Inc(Position, 1);
Inc(pSrc, 3);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure ReadDataRGBOpaque(var BitmapData: TBitmapData);
var
pSrc: PByte;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
pSrc := PByte(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
BitmapData.FData[Position] := (pSrc[0] shl 16) or (pSrc[1] shl 8) or pSrc[2] or $FF000000;
Inc(Position, 1);
Inc(pSrc, 3);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure ReadDataBGR(var BitmapData: TBitmapData);
var
pSrc: PByte;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
pSrc := PByte(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
BitmapData.FData[Position] := pSrc[0] or (pSrc[1] shl 8) or (pSrc[2] shl 16);
Inc(Position, 1);
Inc(pSrc, 3);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure ReadDataBGROpaque(var BitmapData: TBitmapData);
var
pSrc: PByte;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
pSrc := PByte(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
BitmapData.FData[Position] := pSrc[0] or (pSrc[1] shl 8) or (pSrc[2] shl 16) or $FF000000;
Inc(Position, 1);
Inc(pSrc, 3);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure ReadDataBGRA(var BitmapData: TBitmapData);// fast
var
Y: Integer;
pSrc, pDst: PPixel;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
for Y := 0 to BitmapData.FHeight - 1 do
begin
pSrc := PPixel(BitmapData.FBitmap.RawImage.GetLineStart(Y));
pDst := @(BitmapData.FData[BitmapData.FWidth * Y]);
Move(pSrc^, pDst^, BitmapData.FWidth * SizeOf(TPixel));
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure ReadDataBGRN(var BitmapData: TBitmapData);
var
Scanline: PPixel;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
Scanline := PPixel(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
BitmapData.FData[Position] := Scanline[X];
Inc(Position, 1);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure ReadDataBGRNOpaque(var BitmapData: TBitmapData);
var
Scanline: PPixel;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
Scanline := PPixel(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
BitmapData.FData[Position] := Scanline[X] or $FF000000;
Inc(Position, 1);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure ReadDataRGBA(var BitmapData: TBitmapData);
var
Scanline: PPixel;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
Scanline := PPixel(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
BitmapData.FData[Position] := SwapRedBlueChanel(Scanline[X]);
Inc(Position, 1);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure ReadDataRGBN(var BitmapData: TBitmapData);
var
Scanline: PPixel;
Pixel: TPixel;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
Scanline := PPixel(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
Pixel := Scanline[X];
BitmapData.FData[Position] :=
((Pixel shr 16) and $000000FF) or
(Pixel and $0000FF00) or
((Pixel shl 16) and $00FF0000);
Inc(Position, 1);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure ReadDataRGBNOpaque(var BitmapData: TBitmapData);
var
Scanline: PPixel;
Pixel: TPixel;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
Scanline := PPixel(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
Pixel := Scanline[X];
BitmapData.FData[Position] :=
((Pixel shr 16) and $000000FF) or
(Pixel and $0000FF00) or
((Pixel shl 16) and $00FF0000) or
$FF000000;
Inc(Position, 1);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure WriteDataRGB(var BitmapData: TBitmapData);
var
pSrc: PByte;
C: TPixel;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
pSrc := PByte(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
C := BitmapData.FData[Position];
pSrc[0] := (C shr 16) and $FF;
pSrc[1] := (C shr 8) and $FF;
pSrc[2] := C and $FF;
Inc(Position, 1);
Inc(pSrc, 3);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure WriteDataBGR(var BitmapData: TBitmapData);
var
pSrc: PByte;
C: TPixel;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
pSrc := PByte(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
C := BitmapData.FData[Position];
pSrc[0] := C and $FF;
pSrc[1] := (C shr 8) and $FF;
pSrc[2] := (C shr 16) and $FF;
Inc(Position, 1);
Inc(pSrc, 3);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure WriteDataBGRA(var BitmapData: TBitmapData);// fast
var
Y: Integer;
pSrc, pDst: PPixel;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
for Y := 0 to BitmapData.FHeight - 1 do
begin
pDst := PPixel(BitmapData.FBitmap.RawImage.GetLineStart(Y));
pSrc := @(BitmapData.FData[BitmapData.FWidth * Y]);
Move(pSrc^, pDst^, BitmapData.FWidth * SizeOf(TPixel));
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure WriteDataRGBA(var BitmapData: TBitmapData);
var
Scanline: PPixel;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
Scanline := PPixel(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
Scanline[X] := SwapRedBlueChanel(BitmapData.FData[Position]);
Inc(Position, 1);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure WriteDataRGBN(var BitmapData: TBitmapData);
var
Scanline: PPixel;
Pixel: TPixel;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
Scanline := PPixel(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
Pixel := BitmapData.FData[Position];
Scanline[X] :=
((Pixel shr 16) and $000000FF) or
(Pixel and $0000FF00) or
((Pixel shl 16) and $00FF0000);
Inc(Position, 1);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
procedure WriteDataBGRN(var BitmapData: TBitmapData);
var
Scanline: PPixel;
X, Y, Position: Integer;
begin
BitmapData.FBitmap.BeginUpdate(False);
try
Position := 0;
for Y := 0 to BitmapData.FHeight - 1 do
begin
Scanline := PPixel(BitmapData.FBitmap.RawImage.GetLineStart(Y));
for X := 0 to BitmapData.FWidth - 1 do
begin
Scanline[X] := BitmapData.FData[Position] and $00FFFFFF;
Inc(Position, 1);
end;
end;
finally
BitmapData.FBitmap.EndUpdate(False);
end;
end;
type
TDescriptionType = (DeskBGR, DeskRGB, DeskBGRA, DeskRGBA, DeskBGRN, DeskRGBN, DeskOther);
function CalcDescriptionType(const Description: TRawImageDescription; const IsReadOnly: Boolean = False): TDescriptionType;
begin
Result := TDescriptionType.DeskOther;
if Description.Format <> ricfRGBA then Exit;
if Description.ByteOrder <> riboLSBFirst then Exit;
if Description.PaletteColorCount <> 0 then Exit;
// if Description.BitOrder <> riboBitsInOrder then Exit; // it doesn't matter without a mask
// ??? I think it makes no difference to us whether there is a mask or not
{$IFDEF LCLGTK2}
// LCLGTK2 image width workaround
// ex: width = 16 - ok, width = 15 bug
if (not IsReadOnly) and (Description.MaskBitsPerPixel <> 0) then
if Description.MaskLineEnd = rileByteBoundary then Exit;
{$ENDIF}
if Description.BitsPerPixel = 32 then
begin
if Description.Depth = 32 then