build.gradle

plugins {
    id "com.exactpro.th2.gradle.base" version "0.1.3"
    id "com.exactpro.th2.gradle.component" version "0.1.3" apply false
}

ext {
    commonVersion = '5.14.0-dev'
    cradleVersion = '5.4.3-dev'
}

dependencyCheck {
    suppressionFile = "suppressions.xml"
}

subprojects {
    apply plugin: 'java'

    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
    compileJava.options.debugOptions.debugLevel = 'source,lines,vars' // Include debug information

    group = 'com.exactpro.th2'
    version = release_version

    repositories {
        mavenCentral()
        maven {
            name 'Sonatype_snapshots'
            url 'https://s01.oss.sonatype.org/content/repositories/snapshots/'
        }
        maven {
            name 'Sonatype_releases'
            url 'https://s01.oss.sonatype.org/content/repositories/releases/'
        }
        configurations.configureEach {
            resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
            resolutionStrategy.cacheDynamicVersionsFor 0, 'seconds'
        }
    }

    dependencies {
        implementation "org.slf4j:slf4j-api"

        testImplementation 'com.exactpro.th2:junit-jupiter-integration:0.0.1'

        testImplementation 'org.mockito:mockito-core:5.14.1'
        testImplementation 'org.mockito:mockito-junit-jupiter:5.14.1'
        testImplementation 'org.junit.jupiter:junit-jupiter:5.11.4'

        testRuntimeOnly('org.junit.platform:junit-platform-launcher') {
            because 'This artifact will not be added automatically since gradle 9.0. You can read more information here:' +
                    'https://docs.gradle.org/8.3/userguide/upgrading_version_8.html#test_framework_implementation_dependencies'
        }
    }

    test {
        useJUnitPlatform {
            excludeTags('integration')
        }
    }

    tasks.register('integrationTest', Test) {
        group = 'verification'
        useJUnitPlatform {
            includeTags('integration')
        }
        testLogging {
            showStandardStreams = true
        }
    }
}