Liquidsoap playing a fragment of the last song at the end of Live

[unudelaradio]

Greetings,

I am using Azuracast & Liquidsoap and have been encountering this issue for quite some time:

@Moonbase59 wrote about it here: AzuraCast/AzuraCast#6933

After playing a live DJ, a seemingly "buffered" rest of the song before the live show still plays before the "real" next song starts.

I was wondering if there's some workaround, maybe a custom crossfade code, to make AutoDJ fade out at the start of Live, and somehow skip this song played before live. So when the live ends, the AutoDJ to have a clean start, without previous song "fragment".

I currently use this custom crossfade code, placed in the 3rd Liquidsoap Configuration Box (maybe this can be adjusted to get the desired effect):

def clean_transition(old, new) =

  def safe_float_of_string(str) =
    try
      float_of_string(str)
    catch _ do
      0.
    end
  end

  cross_duration = safe_float_of_string(old.metadata["liq_cross_duration"])
  fade_out = safe_float_of_string(old.metadata["liq_fade_out"])
  fade_in = safe_float_of_string(new.metadata["liq_fade_in"])
  log_label = "clean_transition"
    
  let fade.out = fun (s) -> fade.out(type="exp", duration=fade_out, s)
  let fade.in = fun (s) -> fade.in(type="log", duration=fade_in, s)

  add = fun (a, b) -> add(normalize=false, [b, a])
  sequence = fun (a, b) -> (sequence([a, b]) : source)

  if cross_duration > 0. then
    log(label= log_label,"Crossfade. Duration: #{cross_duration}. Fade out: #{fade_out}. Fade in: #{fade_in}.")
    if fade_out > 0. and fade_in > 0. then 
      add(fade.out(old.source), fade.in(new.source))
    elsif fade_out > 0. and fade_in <= 0. then 
      add(fade.out(old.source), new.source)
    elsif fade_out <= 0. and fade_in > 0. then 
      add(old.source, fade.in(new.source))
    else
      add(old.source, new.source)
    end
  else
    log(label= log_label,"Sequence. Fade out: #{fade_out}. Fade in: #{fade_in}.")
    if fade_out > 0. and fade_in > 0. then 
      sequence(fade.out(old.source), fade.in(new.source))
    elsif fade_out > 0. and fade_in <= 0. then 
      sequence(fade.out(old.source), new.source)
    elsif fade_out <= 0. and fade_in > 0. then 
      sequence(old.source, fade.in(new.source))
    else
      sequence(old.source, new.source)
    end
  end

end

radio = cross(clean_transition,radio)

[nowster]

One way to do this is to schedule a skip of the non-live source when the live one becomes active, to cause the playlist to move on to its next track:

def do_skip() =
  log("Sending skip to backup")
  backup.skip()
end

def to_live(a, b)
  log("Transition to live")
  thread.run(delay=3., do_skip)
  add(normalize=false, [fade.out(duration=1., a),
                        fade.in(duration=1., b)])
end

def to_backup(a, b)
  log("Transition to backup")
  add(normalize=false, [fade.out(duration=1., a),
                        fade.in(duration=1., b)])
end

radio = fallback(track_sensitive=false, transition_length=2.,
                 transitions=[to_live, to_backup], [live, backup])

[unudelaradio]

Hello! Where should i paste this script? Should i replace mine, with this new one? Because i want to keep my existing crossfade settings.

[unudelaradio]

LE: I tried to place the script in Azuracast, but unfortunately i get an error and station goes offline.

[nowster]

It's just an example of how you'd do it. As you've only posted the crossfade part, not the switching logic, I can't comment on where you'd put it. The trick is to split the to/from transitions, and add a delayed skip to the non-live source which uses a playlist on the playlist→live transition.

[nowster]

If there are only two sources, perhaps use radio = fallback.skip(live, fallback=backup) instead of where the original script has radio = fallback([live, backup]. (Changing live and backup to match what the original script has.)

See https://www.liquidsoap.info/doc-2.2.4/reference-extras.html#fallback.skip