-
Notifications
You must be signed in to change notification settings - Fork 2
/
_cimport.sas
331 lines (247 loc) · 10.1 KB
/
_cimport.sas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
%put NOTE: You have called the macro _CIMPORT, 2022-06-30.;
%put NOTE: Copyright (c) 2004-2022 Rodney Sparapani;
%put;
/*
Author: Rodney Sparapani <[email protected]>
Created: 2004-00-00
This file is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2, or (at your option)
any later version.
This file is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this file; see the file COPYING. If not, write to
the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
*/
/* _CIMPORT Documentation
Import a CSV/Stata file into a SAS Dataset. This macro assumes
that the first line contains variable names. The following
characters in variable names are converted to underscore:
_.-[]()@ and space. All other non-alphanumeric characters are
removed. Don't forget to turn off file-locking when necessary:
-filelocks none DIRECTORY-NAME.
REQUIRED Parameters
INFILE= CSV file to read
OUT= SAS dataset created
Specific OPTIONAL Parameters
ATTRIB= ATTRIB statement;
see the SAS manual with respect to the
ATTRIB statement for more details
DAY0='01JAN1960'D set to the date which represents 0
in the file which you are importing;
see also the NUMDATES= option;
the default is valid for SAS and Stata;
for Excel, try DAY0='30DEC1899'D
however, Excel dates prior to 01MAR1900
are uncertain since the non-existant
leap year date of 29FEB1900 is a valid
choice for day 60 in Excel, whereas other
Excel-compatible spreadsheet applications
may have no leap year in 1900 and define
day 60 as 28FEB1900 so that 01MAR1900, and
beyond, agree
DLM=2C default comma delimiter (in HEX) besides
carriage return (0D) which is automatic
since it is needed for DOS line-endings:
for TAB delimited DLM=09
EOL=0D default end of line
FILE=INFILE alias
FIRSTOBS=2 the line on which data starts
HEADER=1 the line on which headings can be found
INFORMAT= INFORMAT statement; for formatted data,
such as dates, list the variables followed
by their informat
Ex. INFORMAT=birthd date7.
see the SAS manual with respect to the
INFORMAT statement for more details
LENGTH=200 default maximum length of character variables
actual length is determined from all records
but it will be no longer than LENGTH
LINESIZE=32767 default line length
LS=LINESIZE alias
NVARS= to skip blank columns, specify the
number of variables to be expected
NUMDATES= list of numeric dates containing
optional formats (rather than
character dates, for those see
INFORMAT= above); supply these
for a DAY0= correction
CHECK=MAX defaults to using all observations
to determine which fields are
character vs. numeric
however, with a large file this
can be very time-consuming
therefore, if it is not sparse,
you may want to try CHECK=100
LOWCASE=/UPCASE= list of variables to lower/upper case
Common OPTIONAL Parameters
LOG=/dev/null set to blank to turn on .log
BY=
DROP=
IF=
KEEP=
OBS=
SORT=
RENAME=
WHERE=
RASMACRO Dependencies
_COUNT
_LIST
_NULL
_PRINTTO
_REQUIRE
_SORT
*/
%macro _cimport(file=REQUIRED, infile=&file, out=REQUIRED, attrib=, by=,
check=max, day0='01JAN1960'd, dlm=2C, eol=0d, drop=, informat=,
length=200, linesize=32767, ls=&linesize, lowcase=, numdates=,
firstobs=2, header=1, obs=max, nvars=, if=, index=, keep=, rename=,
sort=, upcase=, where=, log=%_null);
%_require(&infile &out);
%let infile=%scan(&infile, 1, ''"");
%if %_exist(&infile) %then %do;
%if %length(&log) %then %_printto(log=&log);
%local i j %_list(var0-var256); %* BEWARE: more than 256 variables is trouble!;
%if "%upcase(&obs)"^="MAX" %then %let obs=%eval(&obs+&header);
%if "%_datatyp(&header)"="NUMERIC" %then %do;
%if &firstobs<&header %then %let firstobs=%eval(&header+1);
data _null_;
infile "&infile" dsd firstobs=&header obs=&header ls=&ls dlm="&eol.&dlm"x
%if %length(&nvars)=0 %then missover;;
length var $ 64;
i=0;
j=0;
do until( %if %length(&nvars) %then (i-j)=&nvars; %else var=' '; );
i=i+1;
input var @;
if var>' ' then do;
var=compress(var, '=\`;'',/!#$%^&*+|~:"?{}');
if substr(var, 1, 1) in ('0', '1', '2', '3', '4', '5', '6', '7', '8', '9') then
var='_'||var;
if length(var)>32 then var=substr(var, 1, 32);
var=translate(trim(var), '________', ' -.[]()@');
var=tranwrd(var, '__', '_');
call symput('var'||left(i), var);
call symput('var0', trim(left(i)));
end;
%if %length(&nvars) %then %do;
else do;
j=j+1;
var='_drop_'||left(j);
call symput('var'||left(i), var);
call symput('var0', trim(left(i)));
end;
put i= var=;
%end;
end;
run;
%end;
%else %do;
%local var0;
%let header=%_list(&header);
%let var0=%_count(&header);
%do i=1 %to &var0;
%local var&i;
%let var&i=%scan(&header, &i, %str( ));
%end;
%end;
%do i=1 %to &var0;
%local type&i len&i;
%do j=1 %to &i-1;
%if "%upcase(&&var&i)"="%upcase(&&var&j)" %then %let var&i=_&&var&i;
%end;
data _null_;
attrib &attrib;
informat &informat;
infile "&infile" dsd firstobs=&firstobs obs=&check ls=&ls dlm="&eol.&dlm"x
%if %length(&nvars)=0 %then missover;;
input %do j=1 %to &i; &&var&j &&type&j %end;;
if _error_ then do;
%*_error_=0;
call symput("type&i", "$");
stop;
end;
run;
%end;
data &out;
%do i=1 %to &var0;
%if "&&type&i"="$" %then %do;
length &&var&i &&type&i &length;
%end;
%end;
attrib &attrib;
informat &informat;
infile "&infile" dsd firstobs=&firstobs obs=&obs ls=&ls dlm="&eol.&dlm"x end=_last_
%if %length(&nvars)=0 %then missover;;
input %do i=1 %to &var0; &&var&i &&type&i %end;;
%if %length(&numdates) %then %do;
%let numdates=%_list(&numdates);
%do i=1 %to %_count(&numdates);
%local num&i;
%let num&i=%scan(&numdates, &i, %str( ));
%if %index(&&num&i,.)=0 %then &&num&i=&&num&i+&day0;;
%end;
%end;
%do i=1 %to &var0;
%if "&&type&i"="$" %then %do;
drop _len&i;
retain _len&i 1;
_len&i=max(_len&i, length(&&var&i));
if _last_ then call symput("len&i", trim(left(_len&i)));
%end;
%end;
if %do i=1 %to &var0;
%if "&&type&i"="$" %then &&var&i='';
%else nmiss(&&var&i);
&
%end; 1 then delete;
run;
%if %length(&log) %then %_printto;
data &out;
length %do i=1 %to &var0;
%if "&&type&i"="$" %then %do;
&&var&i &&type&i &&len&i
%if &&len&i=&length %then
%put WARNING: maximum character length, &length, possibly exceeded for &&var&i;
%end;
%end;;
set &out;
/*
by &by;
%if %length(&drop) %then drop &drop;;
rename &rename;
where &where;
%if %length(&if) %then if &if;;
*/
%if %length(&nvars) %then %do;
%if &var0>&nvars %then drop _drop_:;;
%end;
%if %length(&lowcase) %then %do;
%let lowcase=%_list(&lowcase);
%do j=1 %to %_count(&lowcase);
%scan(&lowcase, &j, %str( ))=lowcase(%scan(&lowcase, &j, %str( )));
%end;
%end;
%if %length(&upcase) %then %do;
%let upcase=%_list(&upcase);
%do j=1 %to %_count(&upcase);
%scan(&upcase, &j, %str( ))=upcase(%scan(&upcase, &j, %str( )));
%end;
%end;
run;
%_sort(data=&out, out=&out, by=&by, drop=&drop, if=&if, index=&index,
keep=&keep, rename=&rename, sort=&sort, where=&where);
%end;
%else %do;
data &out;
set _null_;
run;
%put ERROR: "&infile" does not exist.;
%end;
%mend _cimport;
%*VALIDATION TEST STREAM;
/* un-comment to re-validate
*/