build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

apply from: 'versions.gradle'
apply from: 'publish.gradle'

buildscript {
    repositories {
        jcenter()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.1'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:1.5'
        classpath 'com.google.gms:google-services:3.0.0'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        jcenter()
    }

    apply plugin: 'checkstyle'

    //add checkstyle to each module
    task checkstyle(type: Checkstyle) {
        configFile = new File(rootDir, "config/checkstyle/checkstyle.xml")
        //use same config file for each module
        source 'src/'
        include '**/*.java'
        exclude '**/gen/**'
        classpath = files()
        reports {
            xml {
                destination "build/outputs/reports/checkstyle-results.xml"
            }
        }
    }

    task checkstyleReport(dependsOn: 'checkstyle') {
        doLast {
            if (file("build/outputs/reports/checkstyle-results.xml").exists()) {
                ant.xslt(in: "build/outputs/reports/checkstyle-results.xml",
                        style: "${rootDir}/config/checkstyle/checkstyle.xsl",
                        out: "build/outputs/reports/checkstyle-results.html"
                )
            }
        }
    }
}

subprojects {
    afterEvaluate { project ->
        if (project.hasProperty('android')) {
            def config = android.defaultConfig
            def ext = rootProject.ext
            if (android.compileSdkVersion == null)
                android.compileSdkVersion ext.compileSdkVersion
            if (config.minSdkVersion == null)
                config.minSdkVersion ext.minSdkVersion
            if (config.targetSdkVersion == null)
                config.targetSdkVersion ext.targetSdkVersion
            if (config.versionCode == null)
                config.versionCode ext.versionCode
            if (config.versionName == null)
                config.versionName ext.versionName
            if (config.testInstrumentationRunner == null)
                config.testInstrumentationRunner ext.testInstrumentationRunner
        }
    }
}

ext {
    testInstrumentationRunner = 'android.support.test.runner.AndroidJUnitRunner'
}

task clean(type: Delete) {
    delete project.buildDir
}