Tmux-navigator Plugins Installation Error

[workadev]

Hi, apologies in advance for beginner's question.
I've been trying to configure my nixvim and so far with few bumps managed to get them working, thanks!
I have Tmux installed globally in my nix darwin configuration.nix and also it's working.
But when I tried to install the plugins.tmux-navigator.enable it says

error: In module `<unknown-file>', you're trying to define a value of type `bool'
       rather than an attribute set for the option
       `home-manager.users.workambp1.programs.nixvim.plugins.tmux-navigator'!

       This usually happens if `home-manager.users.workambp1.programs.nixvim.plugins.tmux-navigator' has option
       definitions inside that are not matched. Please check how to properly define
       this option

The documentation stated

[plugins.tmux-navigator.enable](https://nix-community.github.io/nixvim/plugins/tmux-navigator/index.html#pluginstmux-navigatorenable)

Whether to enable vim-tmux-navigator.

Type: boolean

Default: false

Example: true

Below is a snippet of my home.nix

  # Nixvim
  programs.nixvim = {
    enable = true;
    defaultEditor = true;
    viAlias = true;
    vimAlias = true;
    vimdiffAlias = true;

    globals.mapleader = " ";

    keymaps = [
      {
        # Nvim
        action = "<CR>gg<S-v>G<CR>";
	key = "<C-a>";
	mode = "n";
	options = {
	  desc = "Select all";
        };
      }
      {
        # NvimTree Toggle
        action = "<cmd>NvimTreeToggle<CR>";
	key = "<leader>ee";
	mode = "n";
	options = {
	  desc = "Toggle Nvim Tree";
        };
      }
      {
        # NvimTree Focus 
        action = "<cmd>NvimTreeFocus<CR>";
	key = "<leader>er";
	mode = "n";
	options = {
	  desc = "Switch focus to Nvim Tree";
        };
      }
      {
        # NvimTree Find File 
        action = "<cmd>NvimTreeFindFile<CR>";
	key = "<leader>ef";
	mode = "n";
	options = {
	  desc = "Nvim Tree Find File";
        };
      }
      {
        # Telescope Find File 
        action = "<cmd>Telescope find_files<CR>";
	key = "<leader>ff";
	mode = "n";
	options = {
	  desc = "Telescope Find Files";
        };
      }
    ];
    
    opts = {
      number = true;
      relativenumber = true;
      shiftwidth = 2;
      ignorecase = true;
      smartcase = true;
    };

    colorschemes.catppuccin.enable = true;

    plugins = {
      lualine.enable = true;
      lspkind.enable = true;
      web-devicons.enable = true;
      which-key.enable = true;
      nvim-autopairs.enable = true;
      nvim-tree.enable = true;
      telescope.enable = true;
      tmux-navigator = true;
      
      treesitter = {
        enable = true;
        settings = {
	  auto_install = true;
          highlight = {
            enable = true;
          };
        };
        grammarPackages = with pkgs.vimPlugins.nvim-treesitter.builtGrammars; [
          bash
          json
          lua
          make
          markdown
          nix
          regex
          toml
          vim
          vimdoc
          xml
          yaml
	  javascript
	  typescript
	  css
	  gitignore
	  http
	  scss
	  sql
        ];
      };

      # LSP, Snippets - Part of plugins
      lsp = {
        enable = true;
        servers = {
	  html.enable = true;
          nil_ls.enable = true;
          ts_ls.enable = true;
	  lua_ls.enable = true;
	  eslint.enable = true;
	  jsonls.enable = true;
          rust_analyzer.installCargo = true;
          rust_analyzer.installRustc = true;
          rust_analyzer.enable = true;
	  };
	};

      luasnip = {
	enable = true;
	settings = {
	  enable_autosnippets = true;
	  store_selection_keys = "<Tab>";
        };
      };

      # Completion engines
      cmp-nvim-lsp.enable = true;
      cmp_luasnip.enable = true;
      cmp-nvim-lua.enable = true;
      cmp-path.enable = true;
      cmp-calc.enable = true;
      cmp-buffer.enable = true;


      cmp = {
        enable = true;
	autoEnableSources = true;
	settings = {
	  mapping = {
	    "<C-d>" = "cmp.mapping.scroll_docs(-4)";
	    "<C-f>" = "cmp.mapping.scroll_docs(4)";

	    # Manually trigger a completion from nvim-cmp
	    "<C-Space>" = "cmp.mapping.complete()";
	    "<C-e>" = "cmp.mapping.close()";
	    "<C-n>" = "cmp.mapping.select_next_item()";
	    "<C-p>" = "cmp.mapping.select_prev_item()";
	    "<CR>" = "cmp.mapping.confirm({ select = true })";
	  };
	  sources = [
	    {name = "nvim_lsp";}
	    {name = "luasnip";}
	    {name = "nvim_lua";}
	    #{name = "nvim_lsp_signature_help";}
	    {name = "path";}
	    {name = "calc";}
	    {name = "buffer";}
	  ];
	  snippet.expand = ''function(args) require('luasnip').lsp_expand(args.body) end'';
	};
      };

      friendly-snippets.enable = true;

      indent-blankline = {
        enable = true;
          settings = {
            indent = {
              char = "│";
                tab_char = "";
                #trail = "-";
                #nbsp = "+";
            };
          };
      };

    };
  };

Can someone help?

[MattSturgeon]

You've configured tmux-navigator = true instead of tmux-navigator.enable = true.

This is what the error means by "plugins.tmux-navigator: found a bool, expected an attribute set".

[MattSturgeon]

Looks like I chose to use the tmux-naviagtor plugin. The relevant lines in my config are:

programs.tmux.enable = true;
programs.tmux.plugins = [
  pkgs.tmuxPlugins.vim-tmux-navigator
];

As an alternative, you could also manually set up the keybinds:
(as documented here)

programs.tmux.enable = true;
programs.tmux.extraConfig = ''
  # Smart pane switching with awareness of vim splits.
  # See: https://github.com/christoomey/vim-tmux-navigator
  is_vim="ps -o state= -o comm= -t '#{pane_tty}' \
    | grep -iqE '^[^TXZ ]+ +(\\S+\\/)?g?(view|l?n?vim?x?|fzf)(diff)?$'"

  bind-key -n 'C-h' if-shell "$is_vim" 'send-keys C-h'  'select-pane -L'
  bind-key -n 'C-j' if-shell "$is_vim" 'send-keys C-j'  'select-pane -D'
  bind-key -n 'C-k' if-shell "$is_vim" 'send-keys C-k'  'select-pane -U'
  bind-key -n 'C-l' if-shell "$is_vim" 'send-keys C-l'  'select-pane -R'

  # Forwarding <C-\\> needs different syntax, depending on tmux version
  tmux_version='$(tmux -V | sed -En "s/^tmux ([0-9]+(.[0-9]+)?).*/\1/p")'
  if-shell -b '[ "$(echo "$tmux_version < 3.0" | bc)" = 1 ]' \
    "bind-key -n 'C-\\' if-shell \"$is_vim\" 'send-keys C-\\'  'select-pane -l'"
  if-shell -b '[ "$(echo "$tmux_version >= 3.0" | bc)" = 1 ]' \
    "bind-key -n 'C-\\' if-shell \"$is_vim\" 'send-keys C-\\\\'  'select-pane -l'"

  bind-key -T copy-mode-vi 'C-h' select-pane -L
  bind-key -T copy-mode-vi 'C-j' select-pane -D
  bind-key -T copy-mode-vi 'C-k' select-pane -U
  bind-key -T copy-mode-vi 'C-l' select-pane -R
  bind-key -T copy-mode-vi 'C-\' select-pane -l
'';

[workadev]

Yes, that is what I got so far. Got it to work, can navigate between tmux and nixvim using Ctrl hjkl.
But then my tmux using the wrong shell?

tmux

I am still curious on how to add the tmuxPlugins.vim-tmux-navigator plugin to my global configuration.nix file where I declared tmux there...

[MattSturgeon]

I am still curious on how to add the tmuxPlugins.vim-tmux-navigator plugin to my global configuration.nix file where I declared tmux there...

Looking at the nixos option search, nixos has a similar programs.tmux module to the home-manager programs.tmux module I'm using.

You should also be able to use programs.tmux.plugins = [ pkgs.tmuxPlugins.vim-tmux-navigator ] in either a nixos configuration or a home-manager configuration, because both have this option.

Regarding zsh, the home-manager module has a shell option that you should just be able to set to lib.getExe pkgs.zsh. But nixos doesn't have a shell option in its tmux module...

If you're using nixos you may need to do this via extraConfig instead:

plugins.tmux.extraConfig = ''
  set -g default-shell ${lib.getExe pkgs.zsh}
''

[MattSturgeon]

Ah, looking at those screenshots from your edit it seems the shell may be set correctly, but perhaps you need to enable tmux's colour mode?

In my config that is programs.tmux.terminal = "screen-256color", which is also available for the nixos module.

[workadev]

Thank you for the pointers!

Now it is working with an extraConfig set -g default-shell "$SHELL"

  # Tmux
  programs.tmux = {
    enable = true;

    plugins = with pkgs; [
      tmuxPlugins.vim-tmux-navigator
    ];

    extraConfig = ''
      set -gu default-command
      set -g mouse on
      set -g @catppuccin_flavour 'mocha'
      set -g default-shell "$SHELL"
    '';
  };

Although there is a bit funny part with the white block in my prompt, but that is something I think I can live with - think of it as tmux indicator lol.

I'll study more regarding the nix configuration.
Again, thank you.