Use a group of multiple paired files as input

[zihhuafang]

Hi, I am new to Nextflow and trying to understand how to work with complex inputs.

I have a process that I would like to ingest multiple paired-end fqs from the same sample.
Example csv below:

sample_id,fq1,fq2
sample1,fqs/sample1_22F3KCLT4_5_R1.fq.gz,fqs/sample1_22F3KCLT4_5_R2.fq.gz
sample1,fqs/sample1_22F3KCLT4_6_R1.fq.gz,fqs/sample1_22F3KCLT4_6_R2.fq.gz
sample1,fqs/sample1_22F52VLT4_2_R1.fq.gz,fqs/sample1_22F52VLT4_2_R2.fq.gz
sample1,fqs/sample1_22GCWHLT4_5_R1.fq.gz,fqs/sample1_22GCWHLT4_5_R2.fq.gz
sample1,fqs/sample1_22GF53LT4_5_R1.fq.gz,fqs/sample1_22GF53LT4_5_R2.fq.gz

I thought the input channel could be constructed as below:

sample_meta = Channel.fromPath( params.sample_csv )
                    .splitCsv( header: true, sep: ',' )
                  | map { row ->
                      meta = [id: row.sample_id]
                      [meta, [file(row.fq1), file(row.fq2)]]
                  }
                  | groupTuple
                  | map { meta, reads->
                          tuple( groupKey(meta, reads.size()), reads)
                  }

process input as

    input:
    tuple val(meta), path(reads)

so I can define my inputs as:
def in_fq_command = reads.collect{ "--in-fq $it" }.join(" ")

The idea is to get the following command:
--in-fq fqs/sample1_22F3KCLT4_5_R1.fq.gz fqs/sample1_22F3KCLT4_5_R2.fq.gz --in-fq fqs/sample1_22F3KCLT4_6_R1.fq.gz fqs/sample1_22F3KCLT4_6_R2.fq.gz --in-fq fqs/sample1_22F52VLT4_2_R1.fq.gz fqs/sample1_22F52VLT4_2_R2.fq.gz --in-fq fqs/sample1_22GCWHLT4_5_R1.fq.gz fqs/sample1_22GCWHLT4_5_R2.fq.gz --in-fq fqs/sample1_22GF53LT4_5_R1.fq.gz fqs/sample1_22GF53LT4_5_R2.fq.gz

I got the error:
error [nextflow.exception.ProcessUnrecoverableException]: Not a valid path value type: java.util.ArrayList ([fqs/sample1_22F3KCLT4_5_R1.fq.gz, fqs/sample1_22F3KCLT4_5_R2.fq.gz])

So I guessed array list cannot be passed as input, but I don't know how to construct the input channel in this case.
Since the number of the paired files per sample is dynamic, I can't really hard code the inputs like
tuple val(meta), path(pair_1), path(pair_2)

Wonder if anyone can advice on this?

[bentsherman]

When you do the groupTuple, it is creating a list of lists for the reads. So you need to flatten the reads after the groupTuple:

    Channel.fromPath(params.sample_csv)
        .splitCsv(header: true, sep: ',')
        .map { row ->
            def meta = [id: row.sample_id]
            [meta, [file(row.fq1), file(row.fq2)]]
        }
        .groupTuple()
        .map { meta, reads -> [ meta, reads.flatten() ] }
        .view()

[zihhuafang]

Thanks a lot! Fixed my problem of the input channel.