-
Notifications
You must be signed in to change notification settings - Fork 5
/
CMakeLists.txt
461 lines (384 loc) · 15.7 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
# Copyright Maarten L. Hekkelman, 2023
# Distributed under the Boost Software License, Version 1.0.
# (See accompanying file LICENSE_1_0.txt or copy at
# http://www.boost.org/LICENSE_1_0.txt)
cmake_minimum_required(VERSION 3.22)
project(libzeep VERSION 6.0.14 LANGUAGES CXX)
list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
include(GNUInstallDirs)
include(CheckFunctionExists)
include(CheckIncludeFiles)
include(FindFilesystem)
include(CheckLibraryExists)
include(CMakePackageConfigHelpers)
include(GenerateExportHeader)
include(VersionString)
include(CTest)
include(CMakeDependentOption)
option(ZEEP_BUILD_LIBRARY "Build the library from source code, should be off when configuring on ReadTheDocs" ON)
option(ZEEP_BUILD_DOCUMENTATION "Build documentation" OFF)
option(ZEEP_USE_BOOST_ASIO "Use the asio library from Boost instead of the non-boost version" ON)
option(ZEEP_ALLOW_FETCH_CONTENT "Use cmake's FetchContent to retrieve missing packages" ON)
cmake_dependent_option(ZEEP_BUILD_EXAMPLES "Build the example applications" ON "ZEEP_BUILD_LIBRARY" OFF)
if(ZEEP_BUILD_LIBRARY)
set(CXX_EXTENSIONS OFF)
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
# When building with ninja-multiconfig, build both debug and release by default
if(CMAKE_GENERATOR STREQUAL "Ninja Multi-Config")
set(CMAKE_CROSS_CONFIGS "Debug;Release")
set(CMAKE_DEFAULT_CONFIGS "Debug;Release")
endif()
find_package(Filesystem REQUIRED)
if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra")
elseif(MSVC)
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
endif()
# Build shared libraries by default (not my cup of tea, but hey)
option(BUILD_SHARED_LIBS "Build a shared library instead of a static one" OFF)
set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS ON)
if(WIN32)
if(${CMAKE_SYSTEM_VERSION} GREATER_EQUAL 10) # Windows 10
add_definitions(-D _WIN32_WINNT=0x0A00)
elseif(${CMAKE_SYSTEM_VERSION} EQUAL 6.3) # Windows 8.1
add_definitions(-D _WIN32_WINNT=0x0603)
elseif(${CMAKE_SYSTEM_VERSION} EQUAL 6.2) # Windows 8
add_definitions(-D _WIN32_WINNT=0x0602)
elseif(${CMAKE_SYSTEM_VERSION} EQUAL 6.1) # Windows 7
add_definitions(-D _WIN32_WINNT=0x0601)
elseif(${CMAKE_SYSTEM_VERSION} EQUAL 6.0) # Windows Vista
add_definitions(-D _WIN32_WINNT=0x0600)
else() # Windows XP (5.1)
add_definitions(-D _WIN32_WINNT=0x0501)
endif()
add_definitions(-DNOMINMAX)
endif()
if(MSVC)
# make msvc standards compliant...
add_compile_options(/permissive-)
endif()
# Optionally use mrc to create resources
if(WIN32 AND BUILD_SHARED_LIBS)
message("Not using resources when building shared libraries for Windows")
else()
find_package(Mrc QUIET)
if(MRC_FOUND)
option(USE_RSRC "Use mrc to create resources" ON)
if(USE_RSRC)
message("Using resources compiled with ${MRC_EXECUTABLE} version ${MRC_VERSION_STRING}")
set(WEBAPP_USES_RESOURCES 1)
endif()
else()
message(STATUS "Not using resources since mrc was not found")
endif()
endif()
set(CMAKE_THREAD_PREFER_PTHREAD)
set(THREADS_PREFER_PTHREAD_FLAG)
find_package(Threads REQUIRED)
if(ZEEP_USE_BOOST_ASIO)
find_package(Boost 1.74 REQUIRED)
message(STATUS "Using asio from boost")
configure_file(${PROJECT_SOURCE_DIR}/cmake/asio-boost.hpp.in ${PROJECT_SOURCE_DIR}/include/zeep/http/asio.hpp @ONLY)
set(FIND_DEPENDENCY_BOOST "find_dependency(Boost REQUIRED)")
else()
find_path(ASIO_INCLUDE_DIR asio.hpp REQUIRED)
message(STATUS "Using standalone asio")
configure_file(${PROJECT_SOURCE_DIR}/cmake/asio.hpp.in ${PROJECT_SOURCE_DIR}/include/zeep/http/asio.hpp @ONLY)
endif()
if(NOT (TARGET date OR date_FOUND))
find_package(date 3.0.1 QUIET NAMES date libhowardhinnant-date)
if(NOT date_FOUND)
if(ZEEP_ALLOW_FETCH_CONTENT)
include(FetchContent)
FetchContent_Declare(date GIT_REPOSITORY https://github.com/HowardHinnant/date.git GIT_TAG v3.0.1)
FetchContent_MakeAvailable(date)
else()
message(FATAL_ERROR "The date package was not found, please install https://github.com/HowardHinnant/date and try again")
endif()
endif()
endif()
if(UNIX)
find_file(HAVE_SYS_WAIT_H "sys/wait.h")
if(HAVE_SYS_WAIT_H)
set(HTTP_SERVER_HAS_PREFORK 1)
endif()
endif()
# Generate the revision.hpp file
write_version_header("${PROJECT_SOURCE_DIR}/lib-xml/src" LIB_NAME "libzeep")
list(APPEND ZEEP_HEADERS
${PROJECT_SOURCE_DIR}/include/zeep/crypto.hpp
${PROJECT_SOURCE_DIR}/include/zeep/streambuf.hpp
${PROJECT_SOURCE_DIR}/include/zeep/value-serializer.hpp
${PROJECT_SOURCE_DIR}/include/zeep/config.hpp
${PROJECT_SOURCE_DIR}/include/zeep/xml/document.hpp
${PROJECT_SOURCE_DIR}/include/zeep/xml/parser.hpp
${PROJECT_SOURCE_DIR}/include/zeep/xml/xpath.hpp
${PROJECT_SOURCE_DIR}/include/zeep/xml/node.hpp
${PROJECT_SOURCE_DIR}/include/zeep/xml/character-classification.hpp
${PROJECT_SOURCE_DIR}/include/zeep/xml/serialize.hpp
${PROJECT_SOURCE_DIR}/include/zeep/xml/doctype.hpp
${PROJECT_SOURCE_DIR}/include/zeep/type-traits.hpp
${PROJECT_SOURCE_DIR}/include/zeep/json/to_element.hpp
${PROJECT_SOURCE_DIR}/include/zeep/json/element.hpp
${PROJECT_SOURCE_DIR}/include/zeep/json/factory.hpp
${PROJECT_SOURCE_DIR}/include/zeep/json/serializer.hpp
${PROJECT_SOURCE_DIR}/include/zeep/json/parser.hpp
${PROJECT_SOURCE_DIR}/include/zeep/json/type_traits.hpp
${PROJECT_SOURCE_DIR}/include/zeep/json/from_element.hpp
${PROJECT_SOURCE_DIR}/include/zeep/json/element_fwd.hpp
${PROJECT_SOURCE_DIR}/include/zeep/json/iterator.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/asio.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/access-control.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/controller.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/message-parser.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/tag-processor.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/connection.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/server.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/daemon.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/error-handler.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/reply.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/template-processor.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/header.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/request.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/rest-controller.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/soap-controller.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/html-controller.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/security.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/uri.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/el-processing.hpp
${PROJECT_SOURCE_DIR}/include/zeep/http/login-controller.hpp
${PROJECT_SOURCE_DIR}/include/zeep/unicode-support.hpp
${PROJECT_SOURCE_DIR}/include/zeep/nvp.hpp
${PROJECT_SOURCE_DIR}/include/zeep/exception.hpp
)
list(APPEND ZEEP_SRC
${PROJECT_SOURCE_DIR}/lib-http/src/access-control.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/connection.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/controller.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/crypto.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/daemon.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/el-processing.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/error-handler.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/format.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/glob.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/html-controller.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/login-controller.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/message-parser.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/reply.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/request.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/rest-controller.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/security.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/server.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/uri.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/soap-controller.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/tag-processor-v2.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/tag-processor.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/template-processor.cpp
${PROJECT_SOURCE_DIR}/lib-http/src/signals.cpp
${PROJECT_SOURCE_DIR}/lib-json/src/element.cpp
${PROJECT_SOURCE_DIR}/lib-json/src/json-parser.cpp
${PROJECT_SOURCE_DIR}/lib-xml/src/character-classification.cpp
${PROJECT_SOURCE_DIR}/lib-xml/src/doctype.cpp
${PROJECT_SOURCE_DIR}/lib-xml/src/document.cpp
${PROJECT_SOURCE_DIR}/lib-xml/src/html-named-characters.hpp
${PROJECT_SOURCE_DIR}/lib-xml/src/html-named-characters.cpp
${PROJECT_SOURCE_DIR}/lib-xml/src/node.cpp
${PROJECT_SOURCE_DIR}/lib-xml/src/xml-parser.cpp
${PROJECT_SOURCE_DIR}/lib-xml/src/xpath.cpp
)
if(USE_RSRC)
list(APPEND ZEEP_SRC
${PROJECT_SOURCE_DIR}/lib-http/src/controller-rsrc.cpp)
endif()
if(HTTP_SERVER_HAS_PREFORK)
list(APPEND ZEEP_HEADERS ${PROJECT_SOURCE_DIR}/include/zeep/http/preforked-server.hpp)
list(APPEND ZEEP_SRC ${PROJECT_SOURCE_DIR}/lib-http/src/preforked-server.cpp)
endif()
add_library(zeep ${ZEEP_SRC} ${ZEEP_HEADERS})
add_library(zeep::zeep ALIAS zeep)
set_target_properties(zeep PROPERTIES POSITION_INDEPENDENT_CODE ON)
target_include_directories(zeep
PUBLIC
"$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>"
"$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
)
target_link_libraries(zeep PUBLIC Threads::Threads date::date ${STDCPPFS_LIBRARY})
if(ZEEP_USE_BOOST_ASIO)
target_link_libraries(zeep PUBLIC Boost::boost)
endif()
if(CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang")
target_link_options(zeep PRIVATE -undefined dynamic_lookup)
endif()
# # Build debug library with d postfix
# set(CMAKE_DEBUG_POSTFIX d)
# set_target_properties(zeep PROPERTIES DEBUG_POSTFIX "d")
# Install rules
install(TARGETS zeep
EXPORT zeep-targets
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
install(EXPORT zeep-targets
NAMESPACE zeep::
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/zeep
)
install(
DIRECTORY include/zeep
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
COMPONENT Devel
PATTERN "config.hpp.in" EXCLUDE
)
configure_package_config_file(${PROJECT_SOURCE_DIR}/cmake/zeep-config.cmake.in
${CMAKE_CURRENT_BINARY_DIR}/zeep/zeep-config.cmake
INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/zeep
)
write_basic_package_version_file(
"${CMAKE_CURRENT_BINARY_DIR}/zeep/zeep-config-version.cmake"
COMPATIBILITY AnyNewerVersion
)
file(GLOB OLD_CONFIG_FILES
${CMAKE_INSTALL_FULL_LIBDIR}/cmake/zeep/zeepConfig*.cmake
${CMAKE_INSTALL_FULL_LIBDIR}/cmake/zeep/zeepTargets*.cmake)
if(OLD_CONFIG_FILES)
message(STATUS "Installation will remove old config files: ${OLD_CONFIG_FILES}")
install(CODE "file(REMOVE ${OLD_CONFIG_FILES})")
endif()
install(FILES
"${CMAKE_CURRENT_BINARY_DIR}/zeep/zeep-config.cmake"
"${CMAKE_CURRENT_BINARY_DIR}/zeep/zeep-config-version.cmake"
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/zeep
COMPONENT Devel
)
set(zeep_MAJOR_VERSION ${PROJECT_VERSION_MAJOR})
set_target_properties(zeep PROPERTIES
VERSION ${PROJECT_VERSION}
SOVERSION ${PROJECT_VERSION_MAJOR}
INTERFACE_zeep_MAJOR_VERSION ${PROJECT_VERSION_MAJOR}
COMPATIBLE_INTERFACE_STRING zeep_MAJOR_VERSION
)
# Config file
set(LIBZEEP_VERSION ${PROJECT_VERSION})
set(LIBZEEP_VERSION_MAJOR ${PROJECT_VERSION_MAJOR})
set(LIBZEEP_VERSION_MINOR ${PROJECT_VERSION_MINOR})
set(LIBZEEP_VERSION_PATCH ${PROJECT_VERSION_PATCH})
configure_file("${PROJECT_SOURCE_DIR}/include/zeep/config.hpp.in" "${PROJECT_SOURCE_DIR}/include/zeep/config.hpp" @ONLY)
endif(ZEEP_BUILD_LIBRARY)
# Documentation
if(ZEEP_BUILD_DOCUMENTATION)
add_subdirectory(docs)
endif()
# Examples
if(ZEEP_BUILD_EXAMPLES)
add_subdirectory(examples)
endif()
# Test applications, but only if we're not included as a subproject
get_directory_property(HAS_PARENT PARENT_DIRECTORY)
if(BUILD_TESTING AND NOT HAS_PARENT)
find_package(Boost REQUIRED)
if(NOT (libmcfp_FOUND OR TARGET libmcfp))
find_package(libmcfp QUIET)
if(NOT libmcfp_FOUND)
if(ZEEP_ALLOW_FETCH_CONTENT)
include(FetchContent)
FetchContent_Declare(libmcfp GIT_REPOSITORY https://github.com/mhekkel/libmcfp GIT_TAG v1.2.4)
FetchContent_MakeAvailable(libmcfp)
elseif(EXISTS libmcfp/CMakeLists.txt)
add_subdirectory(libmcfp EXCLUDE_FROM_ALL)
else()
message(FATAL_ERROR "The libmcfp package was not found, please install https://github.com/mhekkel/libmcfp and try again")
endif()
endif()
endif()
# data files for the parser test
add_library(client_test OBJECT ${PROJECT_SOURCE_DIR}/lib-http/test/client-test-code.cpp)
target_include_directories(client_test PRIVATE
${CMAKE_CURRENT_SOURCE_DIR}/include
${CMAKE_CURRENT_BINARY_DIR} # for config.h
${PROJECT_SOURCE_DIR}/include
)
if(ZEEP_USE_BOOST_ASIO)
target_link_libraries(client_test PRIVATE Boost::boost)
endif()
# data files for the parser test
set(XML_CONF_TAR ${PROJECT_SOURCE_DIR}/lib-xml/test/XML-Test-Suite.tbz)
set(XML_CONF_FILE ${PROJECT_SOURCE_DIR}/lib-xml/test/XML-Test-Suite/xmlconf/xmlconf.xml)
if(NOT EXISTS ${XML_CONF_FILE})
if(${CMAKE_VERSION} VERSION_LESS "3.18.0")
find_program(TAR tar)
if(TAR)
add_custom_command(OUTPUT ${XML_CONF_FILE}
COMMAND ${TAR} xf ${XML_CONF_TAR}
WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/lib-xml/test/)
else()
message(FATAL_ERROR "Please extract the archive ${XML_CONF_TAR} manually or update your cmake version to at least 3.18")
endif()
else()
file(ARCHIVE_EXTRACT INPUT ${XML_CONF_TAR}
DESTINATION ${PROJECT_SOURCE_DIR}/lib-xml/test/)
endif()
endif()
add_custom_target(XML_CONF ALL DEPENDS ${XML_CONF_FILE})
# unit parser serializer xpath json crypto http processor webapp soap rest security uri
list(APPEND zeep_tests
xml/unit
xml/parser
xml/serializer
xml/xpath
json/json
http/crypto
http/http
http/processor
http/webapp
http/soap
http/rest
http/security
http/uri)
if(USE_RSRC)
list(APPEND zeep_tests http/rsrc_webapp)
endif()
foreach(TEST IN LISTS zeep_tests)
string(REGEX MATCH "^[^/]+" ZEEP_TEST_DIR ${TEST})
string(REGEX MATCH "[^/]+$" ZEEP_TEST ${TEST})
set(ZEEP_TEST "${ZEEP_TEST}-test")
set(ZEEP_TEST_SOURCE "${CMAKE_CURRENT_SOURCE_DIR}/lib-${ZEEP_TEST_DIR}/test/${ZEEP_TEST}.cpp")
add_executable(${ZEEP_TEST} ${ZEEP_TEST_SOURCE} $<TARGET_OBJECTS:client_test> ${ZEEP_TEST_RESOURCE})
if("${TEST}" STREQUAL "http/processor")
target_compile_definitions(${ZEEP_TEST} PUBLIC DOCROOT=".")
endif()
if(USE_RSRC AND("${TEST}" STREQUAL "http/processor" OR "${TEST}" STREQUAL "http/rsrc_webapp"))
mrc_target_resources(${ZEEP_TEST} ${PROJECT_SOURCE_DIR}/lib-http/test/fragment-file.xhtml)
endif()
target_include_directories(${ZEEP_TEST} PRIVATE
${CMAKE_CURRENT_SOURCE_DIR}/include
${CMAKE_CURRENT_BINARY_DIR} # for config.h
${PROJECT_SOURCE_DIR}/include
)
target_link_libraries(${ZEEP_TEST} PRIVATE zeep ${STDCPPFS_LIBRARY} libmcfp::libmcfp)
if(MSVC)
# Specify unwind semantics so that MSVC knowns how to handle exceptions
target_compile_options(${ZEEP_TEST} PRIVATE /EHsc)
endif()
add_custom_target("run-${ZEEP_TEST}" DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/Run${ZEEP_TEST}.touch ${ZEEP_TEST})
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/Run${ZEEP_TEST}.touch
COMMAND ${CMAKE_CURRENT_BINARY_DIR}/${ZEEP_TEST}
)
if("${TEST}" STREQUAL "xml/parser")
# Some tests should be skipped
list(APPEND ZEEP_TEST_ARGS
ibm-valid-P28-ibm28v02.xml ibm-valid-P29-ibm29v01.xml ibm-valid-P29-ibm29v02.xml
ibm-1-1-valid-P03-ibm03v09.xml rmt-e2e-34 rmt-e2e-55 rmt-054 rmt-ns10-006 rmt-e3e-13)
list(TRANSFORM ZEEP_TEST_ARGS PREPEND "--questionable=")
list(PREPEND ZEEP_TEST_ARGS ${XML_CONF_FILE} "--print-ids")
add_dependencies(${ZEEP_TEST} XML_CONF)
else()
set(ZEEP_TEST_ARGS "")
endif()
add_test(NAME ${ZEEP_TEST}
COMMAND $<TARGET_FILE:${ZEEP_TEST}> ${ZEEP_TEST_ARGS}
WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/lib-${ZEEP_TEST_DIR}/test)
endforeach()
endif()
# add_subdirectory(examples)