Mail.applescript

-- Mail.applescript
-- iCal
-- !!! Note that this script is not compiled by iCal.xcodeproj, which uses a compiled version instead
-- !!! so changes to this file will not be reflected in iCal behavior unless manually recompiled.
-- (Not compiled because of <rdar://problem/3675416> osacompile fails in a chrooted environment)

on send_mail_sb(subjectLine, messageText)
	tell application "Sparrow"
		activate
		set theMessage to make new outgoing message with properties {subject:subjectLine, content:messageText}
		tell theMessage
			compose
		end tell
	end tell
end send_mail_sb

on send_mail_sbr(subjectLine, messageText, myrecipient, myrecipientname)
	tell application "Sparrow"
		activate
		set theMessage to make new outgoing message with properties {subject:subjectLine, content:messageText}
		tell theMessage
			make new to recipient at end of to recipients with properties {name:myrecipientname, address:myrecipient}
			sendmessage
		end tell
	end tell
end send_mail_sbr

on send_mail_sbrp(subjectLine, messageText, myrecipient, myrecipientname, invitationPath)
	set pfile to POSIX file invitationPath
	set myfile to pfile as alias
	tell application "Sparrow"
		activate
		set theMessage to make new outgoing message with properties {subject:subjectLine, content:messageText}
		tell theMessage
			make new to recipient at end of recipients with properties {name:myrecipientname, address:myrecipient}
			make new mail attachment with properties {filename:myfile}
			sendmessage
		end tell
	end tell
end send_mail_sbrp

on send_mail_sbp(subjectLine, messageText, invitationPath)
	set pfile to POSIX file invitationPath
	set myfile to pfile as alias
	tell application "Sparrow"
		activate
		set theMessage to make new outgoing message with properties {subject:subjectLine, content:messageText}
		tell theMessage
			make new mail attachment with properties {filename:myfile}
			compose
		end tell
	end tell
end send_mail_sbp