build.gradle

apply plugin: 'java'
apply plugin: 'maven'

group = "com.github.insubstantial.plafplugin"
version = "6.2-SNAPSHOT"
versionKey = "6.2-invincible_SNAPSHOT"
release = "internal"
timeStamp = new Date().format("MMMM d, yyyy HH:mm:ss z")

sourceCompatibility = 1.6
targetCompatibility = 1.6

task wrapper(type: Wrapper) {
  gradleVersion = '0.9.2'
}

jar {
  manifest {
    attributes(
      "Laf-Plugin-Version": version,
      "Laf-Plugin-VersionName": versionKey,
      "Laf-Plugin-BuildStamp": timeStamp
    )
  }
}

task sourceJar(type: Jar) {
  from sourceSets.main.java
  from sourceSets.main.resources
  classifier = 'src'
}

task javadocJar(type: Jar) {
  from javadoc.destinationDir
  classifier = 'javadoc'
}

artifacts {
  archives sourceJar
  archives javadocJar
}

configure(install.repositories.mavenInstaller) {
  pom.project {
    modelVersion '4.0.0'
    packaging 'jar'
    name "plaf plugin"
    description "A fork of @kirilcool's laf-plugin project"
    url "http://insubstantial.github.com/plafplugin"
    licenses {
      license {
        name 'The BSD License'
        url 'http://www.opensource.org/licenses/bsd-license.php'
        distribution 'repo'
        comments 'Covers LafPlugin'
      }
      license {
        name 'The zlib/libpng License'
        url 'http://www.opensource.org/licenses/zlib-license'
        distribution 'repo'
        comments 'Covers the XMLElement and XMLParseException classes'
      }
    }
    scm {
      connection 'scm:git:git@github.com:Insubstantial/plafplugin.git'
      developerConnection 'scm:git:git@github.com:Insubstantial/plafplugin.git'
      url 'scm:git:git@github.com:Insubstantial/plafplugin.git'
    }
    developers {
      developer {
        name 'Kirill Grouchnikov'
        email 'kirillcool@yahoo.com'
        roles {
          role 'author'
          role 'developer'
        }
      }
      developer {
        name 'Danno Ferrin'
        email 'danno.ferrin@shemnon.com'
        roles {
          role 'maintainer'
        }
      }
    }
  }
}