build.gradle

/*
 * Copyright (C) 2015 Aleksei Skoriatin
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed To in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

buildscript {
    repositories {
        jcenter()
        mavenLocal()
    }
    dependencies {
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.5'
    }
}

subprojects {
    if (JavaVersion.current().isJava8Compatible()) {
        tasks.withType(Javadoc) {
            options.addStringOption('Xdoclint:none', '-quiet')
        }
    }

    repositories {
        jcenter()
        mavenLocal()
    }

    if (!project.name.equals('java-async-tests')) {
        apply plugin: 'java'
        apply plugin: 'maven'
        apply plugin: 'maven-publish'
        apply plugin: 'com.jfrog.bintray'

        sourceCompatibility = 1.7
        targetCompatibility = 1.7

        task javadocJar(type: Jar) {
            classifier = 'javadoc'
            from javadoc
        }

        task sourcesJar(type: Jar) {
            classifier = 'sources'
            from sourceSets.main.allSource
        }

        artifacts {
            archives sourcesJar, javadocJar
        }

        publishing {
            publications {
                mavenJava(MavenPublication) {
                    from components.java

                    artifact sourcesJar
                    artifact javadocJar
                }
            }
        }

        bintray {
            if (project.hasProperty("bintrayApiKey")) {
                user = bintrayUserName
                key = bintrayApiKey
            }

            publications = ['mavenJava']
            publish = true
            pkg {
                repo = 'maven'
                name = project.name
                websiteUrl = 'https://github.com/ixkor/java-async'
                issueTrackerUrl = 'https://github.com/ixkor/java-async/issues'
                vcsUrl = 'https://github.com/ixkor/java-async.git'
                licenses = ['Apache-2.0']
                publicDownloadNumbers = true
            }
        }
    }
}