forked from spring-attic/spring-xd
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
1448 lines (1237 loc) · 43.3 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
description = 'Spring XD'
apply plugin: 'base'
apply plugin: 'idea'
buildscript {
repositories {
maven { url "http://repo.springsource.org/plugins-snapshot" }
}
dependencies {
classpath("org.springframework.boot:spring-boot-gradle-plugin:0.5.0.M6")
classpath("org.springframework.build.gradle:propdeps-plugin:0.0.3")
classpath("org.springframework.build.gradle:docbook-reference-plugin:0.2.7-SNAPSHOT")
classpath 'org.asciidoctor:asciidoctor-gradle-plugin:0.4.1'
classpath 'org.ajoberstar:gradle-git:0.4.0'
classpath 'me.champeau.gradle:gradle-javadoc-hotfix-plugin:0.1'
}
}
ext {
linkHomepage = 'https://github.com/spring-projects/spring-xd'
linkCi = 'https://build.springsource.org/browse/XD'
linkIssue = 'https://jira.springsource.org/browse/XD'
linkScmUrl = 'https://github.com/spring-projects/spring-xd'
linkScmConnection = 'https://github.com/spring-projects/spring-xd.git'
linkScmDevConnection = '[email protected]:spring-projects/spring-xd.git'
javadocLinks = [
"http://static.springsource.org/spring-shell/docs/current/api/"
] as String[]
}
// custom class to store the SingleNode server process
class SingleNodeServerProcess {
Process process
}
allprojects {
group = 'org.springframework.xd'
repositories {
mavenCentral()
maven { url 'http://repo.spring.io/libs-milestone' }
maven { url 'http://repo.spring.io/libs-snapshot' }
maven { url 'http://repo.spring.io/plugins-release' }
maven { url 'http://repo.spring.io/plugins-snapshot' }
maven { url 'https://repo.eclipse.org/content/repositories/paho-releases' }
}
}
def javaProjects() {
def nonJavaProjects = ['redis', 'spring-xd-ui']
subprojects.findAll { project -> !nonJavaProjects.contains(project.name) && !project.path.startsWith(':modules.')}
}
def moduleProjects() {
subprojects.findAll { project -> project.path.startsWith(':modules.')}
}
ext {
jackson1Version = '1.9.9'
jacksonVersion = '2.2.2'
jsonPathVersion = '0.8.1'
junitVersion = '4.11'
hamcrestVersion = '1.3'
hamcrestDateVersion = '0.9.3'
hsqldbVersion = '2.3.0'
h2Version = '1.3.172'
jodaTimeVersion = '2.1'
jolokiaVersion = '1.1.2'
snakeYamlVersion = '1.12'
springVersion = '4.0.0.RC1'
springBatchVersion = '2.2.3.BUILD-SNAPSHOT'
springIntegrationVersion = '4.0.0.M1'
springIntegrationMQTTVersion = '4.0.0.M1'
springBootVersion = '0.5.0.M6'
springCloudVersion = '0.9.2'
springBatchAdminMgrVersion = '1.3.0.M1'
springShellVersion = '1.1.0.M1'
springIntegrationSplunkVersion = '1.0.0.M1'
springDataMongoVersion = '1.3.2.RELEASE'
springDataRedisVersion = '1.1.0.RELEASE'
springDataCommonsVersion = '1.6.2.RELEASE'
springDataGemfireVersion = '1.3.2.RELEASE'
tomcatJdbcPoolVersion = '7.0.42'
reactorVersion = '1.0.0.RC1'
lettuceVersion = '2.3.3'
springDataHadoopVersion = '1.0.2.RELEASE'
hadoop12Version = '1.2.1'
hadoop20Version = '2.0.6-alpha'
cdh4Version = '2.0.0-cdh4.3.1'
hdp13Version = '1.2.0'
phd1Version = '2.0.5-alpha-gphd-2.1.0.0'
springHATEOASVersion = '0.7.0.RELEASE'
springPluginVersion = '0.8.0.RELEASE'
tomcatVersion = '7.0.35'
commonsBeanUtilsVersion = '1.6'
slf4jVersion = '1.7.5'
log4jVersion = '1.2.17'
args4jVersion = '2.0.25'
mockitoVersion = '1.9.5'
javaxMailVersion = '1.5.0'
kryoVersion = '2.22'
singleNodeServerProcess = new SingleNodeServerProcess()
}
def forceSpringVersion(p) {
p.configurations.all {
resolutionStrategy {
eachDependency { DependencyResolveDetails details ->
//Force same version of Spring across the board
if (details.requested.group == 'org.springframework') {
details.useVersion "$springVersion"
}
}
}
}
}
configure(javaProjects()) { subproject ->
apply plugin: 'groovy'
apply from: "${rootProject.projectDir}/publish-maven.gradle"
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'javadocHotfix'
forceSpringVersion(subproject)
compileJava {
sourceCompatibility=1.6
targetCompatibility=1.6
}
compileTestJava {
sourceCompatibility=1.7
targetCompatibility=1.7
}
eclipse {
project {
natures += 'org.springframework.ide.eclipse.core.springnature'
}
}
// Include project specific settings
task eclipseSettings(type: Copy) {
from rootProject.files(
"src/eclipse/org.eclipse.jdt.ui.prefs",
"src/eclipse/de.loskutov.anyedit.AnyEditTools.prefs")
into project.file('.settings/')
}
task eclipseJdtPrepare(type: Copy) {
from rootProject.file("src/eclipse/org.eclipse.jdt.core.prefs")
into project.file(".settings/")
}
task cleanEclipseJdtUi(type: Delete) {
delete project.file(".settings/org.eclipse.jdt.ui.prefs")
delete project.file(".settings/org.eclipse.jdt.core.prefs")
}
tasks["eclipseJdt"].dependsOn(eclipseJdtPrepare)
tasks["cleanEclipse"].dependsOn(cleanEclipseJdtUi)
tasks["eclipse"].dependsOn(eclipseSettings)
sourceSets {
test {
groovy {
srcDirs = ['src/test/java']
resources {
srcDirs = ['src/test/resources', 'src/test/java']
}
}
resources {
srcDirs = ['src/test/resources', 'src/test/java']
}
}
}
configurations {
jacoco //Configuration Group used by Sonar to provide Code Coverage using JaCoCo
}
// dependencies that are common across all java projects
dependencies {
testCompile "junit:junit:$junitVersion"
testCompile "org.codehaus.groovy:groovy-all:2.1.0"
testCompile "org.hamcrest:hamcrest-library:$hamcrestVersion"
jacoco group: "org.jacoco", name: "org.jacoco.agent", version: "0.6.2.201302030002", classifier: "runtime"
}
// enable all compiler warnings; individual projects may customize further
[compileJava, compileTestJava]*.options*.compilerArgs = ["-Xlint:all"]
test {
// suppress all console output during testing unless running `gradle -i`
logging.captureStandardOutput(LogLevel.INFO)
jvmArgs "-javaagent:${configurations.jacoco.asPath}=destfile=${buildDir}/jacoco.exec,includes=org.springframework.xd.*"
jvmArgs "-XX:MaxPermSize=256m"
jvmArgs "-Djava.net.preferIPv4Stack=true"
// useful for debugging the GradleWorkerMain
// jvmArgs "-agentlib:jdwp=transport=dt_socket,server=y,suspend=y,address=8000"
// jvmArgs "-Dlog4j.debug=true"
// classpath = files('/some/dir/with/props') + project.sourceSets.test.runtimeClasspath
}
javadoc {
description = "Generates project-level javadoc for use in -javadoc jar"
options.memberLevel = org.gradle.external.javadoc.JavadocMemberLevel.PROTECTED
options.author = true
options.header = project.name
options.links(javadocLinks)
// suppress warnings due to cross-module @see and @link references;
// note that global 'api' task does display all warnings.
logging.captureStandardError LogLevel.INFO
logging.captureStandardOutput LogLevel.INFO // suppress "## warnings" message
}
task sourcesJar(type: Jar) {
classifier = 'sources'
from sourceSets.main.allJava
}
jar {
manifest.attributes["Created-By"] =
"${System.getProperty("java.version")} (${System.getProperty("java.specification.vendor")})"
manifest.attributes["Implementation-Title"] = subproject.name
manifest.attributes["Implementation-Version"] = subproject.version
if (project != project(':spring-xd-exec')) { exclude 'log4j.properties' }
}
task javadocJar(type: Jar) {
classifier = 'javadoc'
from javadoc
}
artifacts {
archives sourcesJar
archives javadocJar
}
}
configure(moduleProjects()) { moduleProject ->
// We only apply the java plugin b/c the eclipse/idea plugins
// require it to emit e.g. a .classpath file. Those projects don't actually
// contain java code, so reset everything (prevents creation of
// the 'build' directory, etc)
apply plugin: 'java'
task build(overwrite: true) {}
task clean(overwrite: true) {}
compileJava {
sourceCompatibility=1.6
targetCompatibility=1.6
}
apply plugin: 'eclipse'
apply plugin: 'idea'
forceSpringVersion(moduleProject)
eclipse {
project {
natures += 'org.springframework.ide.eclipse.core.springnature'
}
}
// FIXME: remove this
configurations {
runtime {
// Workaround for duplicate large jars being included by mistake
exclude module: 'gemfire'
}
}
task copyLibs(type: Copy) {
def containerDeps = project(':spring-xd-dirt').configurations.runtime
inputs.property('deps', moduleProject.configurations.runtime.minus(containerDeps))
outputs.dir project.file('lib/')
from moduleProject.configurations.runtime.minus(containerDeps)
into project.file('lib/')
}
['test','build', 'eclipse', 'idea'].each {t -> tasks[t].dependsOn copyLibs}
task cleanLibs(type: Delete) {
delete copyLibs.outputs
}
['clean', 'cleanEclipse', 'cleanIdea'].each {t -> tasks[t].dependsOn cleanLibs}
project(':spring-xd-dirt').tasks['build'].dependsOn(moduleProject.tasks['build'])
}
project('spring-xd-analytics') {
description = 'Spring XD Anayltics'
dependencies {
compile project(":spring-xd-tuple")
compile "org.springframework:spring-core:$springVersion"
compile "org.springframework.data:spring-data-redis:$springDataRedisVersion"
compile "org.springframework.data:spring-data-commons:$springDataCommonsVersion"
compile "com.lambdaworks:lettuce:$lettuceVersion"
compile "org.springframework.integration:spring-integration-core:$springIntegrationVersion"
compile "joda-time:joda-time:$jodaTimeVersion"
testCompile project(":spring-xd-test")
testCompile "nl.jqno.equalsverifier:equalsverifier:1.1.3"
testCompile "org.springframework:spring-test:$springVersion"
testCompile ("org.mockito:mockito-core:$mockitoVersion") {
exclude group:'org.hamcrest'
}
testCompile "com.fasterxml.jackson.core:jackson-databind:$jacksonVersion"
runtime "log4j:log4j:$log4jVersion",
"org.slf4j:jcl-over-slf4j:$slf4jVersion",
"org.slf4j:slf4j-log4j12:$slf4jVersion"
}
}
project('spring-xd-dirt') {
description = 'Spring XD DIRT'
dependencies {
// See XD-903 for breakdown
// ************* Common to both Server and Container
compile "org.springframework:spring-aop:$springVersion"
compile project(":spring-xd-analytics")
compile "org.springframework.cloud:spring-service-connector:$springCloudVersion"
compile "org.springframework.cloud:cloudfoundry-connector:$springCloudVersion"
compile "org.springframework.boot:spring-boot-autoconfigure:$springBootVersion"
compile "org.springframework.boot:spring-boot-actuator:$springBootVersion"
compile "org.springframework.data:spring-data-redis:$springDataRedisVersion"
compile "org.springframework.integration:spring-integration-redis:$springIntegrationVersion"
compile "org.springframework.integration:spring-integration-http:$springIntegrationVersion"
compile "com.fasterxml.jackson.core:jackson-databind:$jacksonVersion"
compile "log4j:log4j:$log4jVersion"
compile "org.springframework.integration:spring-integration-amqp:$springIntegrationVersion"
compile "org.springframework.integration:spring-integration-event:$springIntegrationVersion"
compile "org.springframework.integration:spring-integration-groovy:$springIntegrationVersion"
compile "org.springframework.integration:spring-integration-jmx:$springIntegrationVersion"
compile "org.jolokia:jolokia-spring:$jolokiaVersion"
compile "com.esotericsoftware.kryo:kryo:$kryoVersion"
compile "com.lambdaworks:lettuce:$lettuceVersion"
compile "args4j:args4j:$args4jVersion"
compile "commons-lang:commons-lang:2.4"
compile "org.hsqldb:hsqldb:$hsqldbVersion"
compile "org.springframework.batch:spring-batch-core:$springBatchVersion"
compile "org.apache.tomcat:tomcat-jdbc:$tomcatJdbcPoolVersion"
compile ("org.springframework.batch:spring-batch-admin-manager:$springBatchAdminMgrVersion") {
exclude group: 'hsqldb'
}
compile ("org.springframework.batch:spring-batch-integration:1.2.2.RELEASE") {
exclude group: 'org.springframework.integration'
exclude group: 'org.springframework'
}
runtime "org.slf4j:jcl-over-slf4j:$slf4jVersion"
runtime "org.slf4j:slf4j-log4j12:$slf4jVersion"
runtime "org.yaml:snakeyaml:$snakeYamlVersion"
runtime "org.postgresql:postgresql:9.2-1002-jdbc4"
runtime "mysql:mysql-connector-java:5.1.23"
// ************* Dirt-Server only
compile project(':spring-xd-rest-domain')
compile "org.springframework:spring-webmvc:$springVersion"
compile "org.springframework.plugin:spring-plugin-core:$springPluginVersion"
compile "org.springframework.data:spring-data-commons:$springDataCommonsVersion"
compile "org.apache.tomcat.embed:tomcat-embed-core:$tomcatVersion"
compile "org.apache.tomcat.embed:tomcat-embed-logging-juli:$tomcatVersion"
compile "org.apache.tomcat:tomcat-jsp-api:$tomcatVersion"
// ************* Dirt-Container only (per se)
compile project(":spring-xd-module")
compile "com.jayway.jsonpath:json-path:$jsonPathVersion"
compile "com.eaio.uuid:uuid:3.2"
// ************* Container: Modules (should move on their own: XD-915)
compile project(":spring-xd-hadoop")
// ************* Container: Imposed by some Module (can't move)
compile "com.sun.mail:javax.mail:$javaxMailVersion"
runtime project(":spring-xd-extension-reactor")
// The following is needed eg by twitter module b/c jackson classes
// are loaded by RestTemplate and RestTemplate is in Dirt
runtime "org.codehaus.jackson:jackson-mapper-asl:$jackson1Version"
// ************* Test
testCompile project(":spring-xd-test")
testCompile "com.jayway.jsonpath:json-path:0.8.1"
testCompile ("org.mockito:mockito-core:$mockitoVersion") {
exclude group:'org.hamcrest'
}
// The following two because of AmqBrokerAndTest
testCompile ("org.apache.activemq:activemq-core:5.6.0") {
exclude group: 'org.mortbay.jetty'
exclude group: 'org.fusesource.fuse-extra'
}
testCompile "org.springframework:spring-jms:$springVersion"
// The following because of org/springframework/integration/x/bus/serializer/TweetSerializationTests.groovy
testCompile "org.springframework.social:spring-social-twitter:1.0.5.RELEASE"
}
apply plugin:'application'
// skip the startScripts task to avoid default start script generation
startScripts.setEnabled(false)
mainClassName = "org.springframework.xd.dirt.server.SingleNodeMain"
test {
systemProperties["xd.home"] = "${rootProject.projectDir}"
}
task configFiles {
def config = file("$rootDir/config")
outputs.dir config
}
task moduleFiles {
def modules = file("$rootDir/modules")
outputs.dir modules
}
task xdUiFiles {
def uiFiles = file("$rootDir/spring-xd-ui")
outputs.dir uiFiles
}
task scriptFiles {
def scripts = file("$rootDir/scripts/xd")
outputs.dir scripts
}
applicationDistribution.from(configFiles) {
into "config"
}
applicationDistribution.from(scriptFiles) {
into "bin"
}
applicationDistribution.from(moduleFiles) {
into "modules"
}
applicationDistribution.from(xdUiFiles) {
into "spring-xd-ui"
}
// Following execution is used by jsTests task to start SingleNodeMainServer as background process
task backgroundAdminServer << { task ->
println "Starting SingleNode server as a background process"
ProcessBuilder processBuilder = new ProcessBuilder("java", "-cp", sourceSets.main.runtimeClasspath.getAsPath(), "org.springframework.xd.dirt.server.SingleNodeMain");
processBuilder.directory(file("$rootDir/spring-xd-dirt"))
def Process proc = processBuilder.start()
proc.consumeProcessOutputStream(System.out)
println("Waiting for the server to startup...")
// Give 15s for the server startup
Thread.sleep(15000)
// Save the process object to destroy after test completion
project.singleNodeServerProcess.process = proc
}
task cleanDataDir(type: Delete) {
delete "$rootDir/data"
}
tasks["backgroundAdminServer"].dependsOn("classes")
tasks["clean"].dependsOn("cleanDataDir")
}
project('spring-xd-exec') {
dependencies {
compile project(':spring-xd-dirt')
}
apply plugin: "spring-boot"
springBoot {
mainClass = 'org.springframework.xd.dirt.boot.SingleNodeApplication'
layout = 'ZIP'
}
jar {
exclude 'build'
exclude 'target'
// FIXME: unhack this
exclude '**/gemfire-*.jar'
exclude '**/aspectweaver-*.jar'
into('.') { from '../spring-xd-dirt/src/main/resources/log4j.properties' }
into('modules') { from '../modules' }
into('config') { from '../config' }
into('spring-xd-ui') { from '../spring-xd-ui' }
}
moduleProjects().each { moduleProject ->
project.jar.dependsOn moduleProject.copyLibs
}
}
// Extension projects, supporting module definitions.
project('spring-xd-extension-http') {
description = 'Spring XD HTTP'
dependencies {
compile "org.springframework.integration:spring-integration-core:$springIntegrationVersion"
compile "io.netty:netty:3.6.6.Final"
compile "org.springframework:spring-web:$springVersion"
testCompile project(":spring-xd-test")
}
}
project('spring-xd-extension-gemfire') {
description = 'Spring XD Gemfire'
dependencies {
compile "org.springframework.integration:spring-integration-gemfire:$springIntegrationVersion"
}
}
project('spring-xd-extension-twitter') {
description = 'Spring XD Twitter'
dependencies {
compile "org.springframework.integration:spring-integration-twitter:$springIntegrationVersion"
}
}
project('spring-xd-extension-splunk') {
description = 'Spring XD Splunk'
dependencies {
compile "org.springframework.integration:spring-integration-splunk:$springIntegrationSplunkVersion"
compile "org.springframework.integration:spring-integration-core:$springIntegrationVersion"
runtime "com.splunk:splunk:1.2.0"
}
}
project('spring-xd-extension-mongodb') {
description = 'Spring XD Mongodb'
dependencies {
compile project(':spring-xd-tuple')
compile "org.springframework.batch:spring-batch-core:$springBatchVersion"
compile "org.springframework.data:spring-data-mongodb:$springDataMongoVersion"
}
}
project('spring-xd-extension-jdbc') {
description = 'Spring XD JDBC'
dependencies {
compile "org.springframework:spring-jdbc:$springVersion"
compile "org.springframework:spring-tx:$springVersion"
compile "org.springframework.batch:spring-batch-infrastructure:$springBatchVersion"
compile "org.springframework.integration:spring-integration-core:$springIntegrationVersion"
runtime "org.springframework.integration:spring-integration-jdbc:$springIntegrationVersion"
runtime "com.fasterxml.jackson.core:jackson-databind:$jacksonVersion"
compile "org.hsqldb:hsqldb:$hsqldbVersion"
runtime "mysql:mysql-connector-java:5.1.23"
runtime "org.postgresql:postgresql:9.2-1002-jdbc4"
}
}
project('spring-xd-extension-reactor') {
description = 'Spring XD Reactor'
dependencies {
compile "org.projectreactor:reactor-spring:$reactorVersion",
"org.projectreactor:reactor-tcp:$reactorVersion",
"org.springframework.integration:spring-integration-core:$springIntegrationVersion"
testCompile project(":spring-xd-test")
testCompile "com.jayway.jsonpath:json-path:0.8.1"
testCompile("org.mockito:mockito-core:$mockitoVersion") {
exclude group: 'org.hamcrest'
}
testRuntime "org.slf4j:jcl-over-slf4j:$slf4jVersion",
"org.slf4j:slf4j-log4j12:$slf4jVersion",
"log4j:log4j:$log4jVersion"
}
}
project('spring-xd-extension-hdfs') {
description = 'Spring XD HDFS'
def hadoopDefault = "hadoop20"
def hadoopDistro = project.hasProperty("hadoopDistro") ? project.getProperty("hadoopDistro") : hadoopDefault
def hadoopSuffix = hadoopDistro.equals("hadoop12") ? "" : "-" + hadoopDistro
dependencies {
compile "org.springframework:spring-aop:$springVersion"
compile "org.springframework:spring-context:$springVersion"
compile "org.springframework:spring-context-support:$springVersion"
compile "org.springframework:spring-tx:$springVersion"
compile ("org.springframework.data:spring-data-hadoop:${springDataHadoopVersion}${hadoopSuffix}") {
exclude group: 'org.mortbay.jetty'
exclude group: 'org.codehaus.jackson'
exclude group: 'hsqldb'
exclude group: 'javax.servlet'
exclude group: 'javax.servlet.jsp'
}
compile "com.cloudera.cdk:cdk-data-core:0.8.0"
compile "org.springframework.batch:spring-batch-core:$springBatchVersion"
testCompile "org.springframework:spring-test:$springVersion"
testRuntime "org.xerial.snappy:snappy-java:1.1.0"
}
}
project('spring-xd-hadoop') {
description = 'Spring XD Hadoop'
dependencies {
compile project(':spring-xd-extension-hdfs')
compile "org.springframework:spring-aop:$springVersion"
compile "org.springframework:spring-context:$springVersion"
compile "org.springframework:spring-context-support:$springVersion"
compile "org.springframework:spring-jdbc:$springVersion"
compile "org.springframework:spring-tx:$springVersion"
compile "org.springframework.integration:spring-integration-core:$springIntegrationVersion"
compile "org.springframework.batch:spring-batch-core:$springBatchVersion"
compile "org.springframework.data:spring-data-mongodb:$springDataMongoVersion"
compile ("org.springframework.data:spring-data-hadoop:$springDataHadoopVersion") {
exclude group: 'org.mortbay.jetty'
exclude group: 'org.codehaus.jackson'
exclude group: 'hsqldb'
}
testRuntime "org.xerial.snappy:snappy-java:1.1.0"
}
}
project('spring-xd-hadoop:hadoop12') {
description = 'Hadoop 1.2 dependencies'
dependencies {
runtime ("org.springframework.data:spring-data-hadoop:$springDataHadoopVersion")
runtime ("org.apache.hadoop:hadoop-core:$hadoop12Version")
runtime ("org.apache.hadoop:hadoop-client:$hadoop12Version")
runtime ("org.apache.hadoop:hadoop-streaming:$hadoop12Version")
runtime ("org.apache.hadoop:hadoop-tools:$hadoop12Version")
}
task copyToLib(dependsOn: build, type: Copy) {
into "$buildDir/lib"
from configurations.default
include 'spring-data-hadoop-*'
include 'hadoop-*'
include 'jetty-util-*'
}
}
project('spring-xd-hadoop:hadoop20') {
description = 'Hadoop 2.0 dependencies'
dependencies {
runtime ("org.springframework.data:spring-data-hadoop:${springDataHadoopVersion}-hadoop20")
runtime ("org.apache.hadoop:hadoop-common:$hadoop20Version")
runtime ("org.apache.hadoop:hadoop-distcp:$hadoop20Version")
runtime ("org.apache.hadoop:hadoop-hdfs:$hadoop20Version")
runtime ("org.apache.hadoop:hadoop-mapreduce-client-core:$hadoop20Version")
runtime ("org.apache.hadoop:hadoop-mapreduce-client-jobclient:$hadoop20Version")
runtime ("org.apache.hadoop:hadoop-streaming:$hadoop20Version")
runtime ("org.apache.hadoop:hadoop-yarn-common:$hadoop20Version")
}
task copyToLib(dependsOn: build, type: Copy) {
into "$buildDir/lib"
from configurations.default
include 'spring-data-hadoop-*'
include 'hadoop-*'
include 'avro-*'
include 'protobuf-java-*'
include 'jetty-util-*'
}
}
project('spring-xd-hadoop:cdh4') {
description = 'Cloudera CDH 4.3.1 dependencies'
dependencies {
runtime ("org.springframework.data:spring-data-hadoop:${springDataHadoopVersion}-cdh4")
runtime ("org.apache.hadoop:hadoop-common:$cdh4Version")
runtime ("org.apache.hadoop:hadoop-distcp:$cdh4Version")
runtime ("org.apache.hadoop:hadoop-hdfs:$cdh4Version")
runtime ("org.apache.hadoop:hadoop-mapreduce-client-core:$cdh4Version")
runtime ("org.apache.hadoop:hadoop-mapreduce-client-jobclient:$cdh4Version")
runtime ("org.apache.hadoop:hadoop-streaming:$cdh4Version")
runtime ("org.apache.hadoop:hadoop-streaming:$cdh4Version")
}
task copyToLib(dependsOn: build, type: Copy) {
into "$buildDir/lib"
from configurations.default
include 'spring-data-hadoop-*'
include 'hadoop-*'
include 'avro-*'
include 'protobuf-java-*'
include 'jetty-util-*'
}
}
project('spring-xd-hadoop:hdp13') {
description = 'Hortonworks HDP 1.3 dependencies'
dependencies {
runtime ("org.springframework.data:spring-data-hadoop:${springDataHadoopVersion}-hdp13")
runtime ("org.apache.hadoop:hadoop-core:$hdp13Version")
runtime ("org.apache.hadoop:hadoop-client:$hdp13Version")
runtime ("org.apache.hadoop:hadoop-streaming:$hdp13Version")
runtime ("org.apache.hadoop:hadoop-tools:$hdp13Version")
}
task copyToLib(dependsOn: build, type: Copy) {
into "$buildDir/lib"
from configurations.default
include 'spring-data-hadoop-*'
include 'hadoop-*'
include 'jetty-util-*'
}
}
project('spring-xd-hadoop:phd1') {
description = 'Pivotal HD 1.0 dependencies'
dependencies {
runtime ("org.springframework.data:spring-data-hadoop:${springDataHadoopVersion}-phd1")
runtime ("org.apache.hadoop:hadoop-common:$phd1Version")
runtime ("org.apache.hadoop:hadoop-client:$phd1Version")
runtime ("org.apache.hadoop:hadoop-distcp:$phd1Version")
runtime ("org.apache.hadoop:hadoop-hdfs:$phd1Version")
runtime ("org.apache.hadoop:hadoop-mapreduce-client-core:$phd1Version")
runtime ("org.apache.hadoop:hadoop-mapreduce-client-jobclient:$phd1Version")
runtime ("org.apache.hadoop:hadoop-streaming:$phd1Version")
runtime ("org.apache.hadoop:hadoop-yarn-common:$phd1Version")
}
task copyToLib(dependsOn: build, type: Copy) {
into "$buildDir/lib"
from configurations.default
include 'spring-data-hadoop-*'
include 'hadoop-*'
include 'avro-*'
include 'protobuf-java-*'
include 'jetty-util-*'
}
}
// 'Binary' distributions projects
project ('spring-xd-gemfire-server') {
description = 'Gemfire Server to support XD Development and Demos'
dependencies {
compile "commons-beanutils:commons-beanutils:$commonsBeanUtilsVersion"
compile "org.springframework.data:spring-data-gemfire:$springDataGemfireVersion"
compile project(':spring-xd-tuple')
runtime "log4j:log4j:$log4jVersion",
"org.slf4j:jcl-over-slf4j:$slf4jVersion",
"org.slf4j:slf4j-log4j12:$slf4jVersion"
}
apply plugin:'application'
// skip the startScripts task to avoid default start script generation
startScripts.setEnabled(false)
task(launch, dependsOn: 'classes', type: JavaExec) {
main = 'org.springframework.xd.gemfire.CacheServer'
classpath = sourceSets.test.runtimeClasspath
if (rootProject.hasProperty('config')) {
args = ["${rootProject.getProperty('config')}"]
}
}
mainClassName = 'org.springframework.xd.gemfire.CacheServer'
task configFiles {
def configs = file("$rootDir/spring-xd-gemfire-server/config")
outputs.dir configs
}
applicationDistribution.from(configFiles) {
into "config"
}
task scriptFiles {
def scripts = file("$rootDir/scripts/gemfire")
outputs.dir scripts
}
applicationDistribution.from(scriptFiles) {
into "bin"
}
}
project('redis') {
description = 'Redis distribution'
task syncScriptFiles(type: Sync) {
from "$rootDir/scripts/redis"
into project.file("${project.buildDir}/bin")
}
task sourceDist {
def distFile = file("$rootDir/redis/dist")
outputs.dir distFile
}
task syncDistFile(type: Sync) {
from "$rootDir/redis/dist"
into project.file("${project.buildDir}/dist")
}
task bundleRedis(dependsOn: ['syncScriptFiles', 'syncDistFile']) {
description = "Bundle redis source dist with install script"
}
task clean(type: Delete) {
description = "Wipes Redis build directory"
delete 'build'
}
}
// Subprojects of Spring XD proper
project('spring-xd-module') {
description = 'Spring XD Module'
dependencies {
compile "org.springframework.integration:spring-integration-core:$springIntegrationVersion"
compile "org.springframework.boot:spring-boot-autoconfigure:$springBootVersion"
}
}
project('spring-xd-tuple') {
description = 'Spring XD Tuple'
dependencies {
compile "com.fasterxml.jackson.core:jackson-databind:$jacksonVersion"
compile "org.springframework:spring-context:$springVersion"
compile "org.springframework.integration:spring-integration-core:$springIntegrationVersion"
compile "org.springframework.batch:spring-batch-infrastructure:$springBatchVersion"
compile "org.springframework:spring-jdbc:$springVersion"
testCompile ("org.mockito:mockito-core:$mockitoVersion") {
exclude group:'org.hamcrest'
}
}
}
project('spring-xd-rest-client') {
description = 'Spring XD REST Client'
dependencies {
compile "org.springframework:spring-web:$springVersion"
compile project(':spring-xd-rest-domain')
compile "com.fasterxml.jackson.core:jackson-databind:$jacksonVersion"
compile 'org.codehaus.jackson:jackson-core-asl:1.9.13'
compile "joda-time:joda-time:$jodaTimeVersion"
}
}
project('spring-xd-rest-domain') {
description = 'Spring XD REST Domain'
dependencies {
compile ("org.springframework.hateoas:spring-hateoas:$springHATEOASVersion") {
exclude module: "spring-asm"
}
compile "com.fasterxml.jackson.core:jackson-databind:$jacksonVersion"
compile 'org.codehaus.jackson:jackson-core-asl:1.9.13'
}
}
// Module definition projects (for projects w/ classpath)
project('modules') {
description = 'Spring XD Modules'
dependencies {
compile project(':spring-xd-dirt')
}
}
project('modules.source.mail') {
dependencies {
runtime "org.springframework.integration:spring-integration-mail:$springIntegrationVersion"
// Need to leave javax.mail at the dirt-server level for
// shell integration tests to work.
// "com.sun.mail:javax.mail:$javaxMailVersion"
}
}
project('modules.source.imap') {
dependencies {
runtime "org.springframework.integration:spring-integration-mail:$springIntegrationVersion"
// Need to leave javax.mail at the dirt-server level for
// shell integration tests to work.
// "com.sun.mail:javax.mail:$javaxMailVersion"
}
}
project('modules.source.file') {
dependencies {
runtime "org.springframework.integration:spring-integration-file:$springIntegrationVersion"
}
}
project('modules.source.tail') {
dependencies {
runtime "org.springframework.integration:spring-integration-file:$springIntegrationVersion"
}
}
project('modules.source.http') {
dependencies {
runtime project(":spring-xd-extension-http")
}
}
project('modules.source.tcp') {
dependencies {
runtime "org.springframework.integration:spring-integration-ip:$springIntegrationVersion"
}
}
project('modules.source.tcp-client') {
dependencies {
runtime "org.springframework.integration:spring-integration-ip:$springIntegrationVersion"
}
}
project('modules.sink.tcp') {
dependencies {
runtime "org.springframework.integration:spring-integration-ip:$springIntegrationVersion"
}
}
project('modules.source.mqtt') {
dependencies {
runtime ("org.springframework.integration:spring-integration-mqtt:$springIntegrationMQTTVersion") {
// spring-integration-mqtt has a different lifecycle than SI and may bring a version
// of SI which is believed by gradle to be newer than our preferred version.
exclude group: 'org.springframework.integration'
}
}
}
project('modules.sink.mqtt') {
dependencies {
runtime ("org.springframework.integration:spring-integration-mqtt:$springIntegrationMQTTVersion") {
// spring-integration-mqtt has a different lifecycle than SI and may bring a version
// of SI which is believed by gradle to be newer than our preferred version.
exclude group: 'org.springframework.integration'
}
}
}
project('modules.source.syslog-tcp') {
dependencies {
runtime "org.springframework.integration:spring-integration-syslog:$springIntegrationVersion"
}
}
project('modules.source.syslog-udp') {
dependencies {
runtime "org.springframework.integration:spring-integration-syslog:$springIntegrationVersion"
}
}
project('modules.source.jms') {
dependencies {
runtime "org.springframework.integration:spring-integration-jms:$springIntegrationVersion"
runtime ("org.apache.activemq:activemq-core:5.6.0") {
exclude group: 'org.mortbay.jetty'
exclude group: 'org.fusesource.fuse-extra'
exclude group: 'org.slf4j'
}
}
}
project('modules.source.gemfire') {
dependencies {
runtime (project(":spring-xd-extension-gemfire")) {
exclude group: 'org.slf4j'
exclude group: 'commons-logging'
}
}
}
project('modules.source.gemfire-cq') {
dependencies {
runtime (project(":spring-xd-extension-gemfire")) {
exclude group: 'org.slf4j'
exclude group: 'commons-logging'
}
}
}
project('modules.source.twitterstream') {
dependencies {
runtime(project(":spring-xd-extension-twitter")) {
exclude group: 'org.codehaus.jackson'
}
}
}
project('modules.source.twittersearch') {
dependencies {
runtime(project(":spring-xd-extension-twitter")) {
exclude group: 'org.codehaus.jackson'
}
}
}