-
Notifications
You must be signed in to change notification settings - Fork 1
/
qs_mfp.F
1403 lines (1170 loc) · 72.2 KB
/
qs_mfp.F
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!--------------------------------------------------------------------------------------------------!
! CP2K: A general program to perform molecular dynamics simulations !
! Copyright 2000-2024 CP2K developers group <https://cp2k.org> !
! !
! SPDX-License-Identifier: GPL-2.0-or-later !
!--------------------------------------------------------------------------------------------------!
MODULE qs_mfp
USE atomic_kind_types, ONLY: get_atomic_kind
USE basis_set_types, ONLY: gto_basis_set_p_type,&
gto_basis_set_type
USE cell_types, ONLY: cell_type
USE commutator_rpnl, ONLY: build_com_vnl_giao
USE cp_control_types, ONLY: dft_control_type
USE cp_dbcsr_api, ONLY: dbcsr_add,&
dbcsr_copy,&
dbcsr_desymmetrize,&
dbcsr_get_block_p,&
dbcsr_p_type,&
dbcsr_scale,&
dbcsr_set,&
dbcsr_type
USE cp_dbcsr_operations, ONLY: cp_dbcsr_sm_fm_multiply
USE cp_fm_basic_linalg, ONLY: cp_fm_trace
USE cp_fm_types, ONLY: cp_fm_create,&
cp_fm_release,&
cp_fm_set_all,&
cp_fm_to_fm,&
cp_fm_type
USE cp_log_handling, ONLY: cp_get_default_logger,&
cp_logger_type
USE cp_output_handling, ONLY: cp_print_key_finished_output,&
cp_print_key_unit_nr
USE input_section_types, ONLY: section_vals_get_subs_vals,&
section_vals_type
USE kinds, ONLY: dp
USE parallel_gemm_api, ONLY: parallel_gemm
USE particle_types, ONLY: particle_type
USE qs_environment_types, ONLY: get_qs_env,&
qs_environment_type
USE qs_integral_utils, ONLY: basis_set_list_setup
USE qs_kind_types, ONLY: get_qs_kind,&
qs_kind_type
USE qs_linres_methods, ONLY: linres_solver
USE qs_linres_types, ONLY: linres_control_type,&
vcd_env_type
USE qs_mo_types, ONLY: mo_set_type
USE qs_neighbor_list_types, ONLY: get_iterator_info,&
get_neighbor_list_set_p,&
neighbor_list_iterate,&
neighbor_list_iterator_create,&
neighbor_list_iterator_p_type,&
neighbor_list_iterator_release,&
neighbor_list_set_p_type
USE qs_p_env_types, ONLY: qs_p_env_type
USE qs_vcd_ao, ONLY: hr_mult_by_delta_1d
USE qs_vcd_utils, ONLY: vcd_read_restart,&
vcd_write_restart
!$ USE OMP_LIB, ONLY: omp_get_max_threads, omp_get_thread_num, omp_get_num_threads
!$ USE OMP_LIB, ONLY: omp_lock_kind, &
!$ omp_init_lock, omp_set_lock, &
!$ omp_unset_lock, omp_destroy_lock
#include "./base/base_uses.f90"
IMPLICIT NONE
PRIVATE
PUBLIC :: mfp_build_operator_gauge_independent
PUBLIC :: mfp_build_operator_gauge_dependent
PUBLIC :: mfp_response
PUBLIC :: mfp_aat
PUBLIC :: multiply_by_position
CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'qs_mfp'
REAL(dp), DIMENSION(3, 3, 3), PARAMETER :: Levi_Civita = RESHAPE((/ &
0.0_dp, 0.0_dp, 0.0_dp, 0.0_dp, 0.0_dp, -1.0_dp, 0.0_dp, 1.0_dp, 0.0_dp, &
0.0_dp, 0.0_dp, 1.0_dp, 0.0_dp, 0.0_dp, 0.0_dp, -1.0_dp, 0.0_dp, 0.0_dp, &
0.0_dp, -1.0_dp, 0.0_dp, 1.0_dp, 0.0_dp, 0.0_dp, 0.0_dp, 0.0_dp, 0.0_dp/), &
(/3, 3, 3/))
CONTAINS
! **************************************************************************************************
!> \brief ...
!> \param vcd_env ...
!> \param qs_env ...
!> \author Edward Ditler
! **************************************************************************************************
SUBROUTINE mfp_aat(vcd_env, qs_env)
TYPE(vcd_env_type) :: vcd_env
TYPE(qs_environment_type), POINTER :: qs_env
CHARACTER(LEN=*), PARAMETER :: routineN = 'mfp_aat'
INTEGER, PARAMETER :: ispin = 1
REAL(dp), DIMENSION(3), PARAMETER :: gauge_origin = 0._dp
REAL(dp), PARAMETER :: f_spin = 2._dp
INTEGER :: alpha, delta, gamma, handle, ikind, nao, &
nmo
LOGICAL :: ghost
REAL(dp) :: aat_linmom, aat_moment, aat_moment_der, &
aat_overlap, aat_tmp, charge, lc_tmp, &
tmp_trace
TYPE(cp_fm_type) :: buf, buf2, matrix_dSdB_mo
TYPE(neighbor_list_set_p_type), DIMENSION(:), &
POINTER :: sab_all
TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
CALL timeset(routineN, handle)
! Some setup
nmo = vcd_env%dcdr_env%nmo(ispin)
nao = vcd_env%dcdr_env%nao
ASSOCIATE (mo_coeff => vcd_env%dcdr_env%mo_coeff(ispin), aat_atom => vcd_env%aat_atom_mfp)
CALL get_qs_env(qs_env=qs_env, &
sab_all=sab_all, &
qs_kind_set=qs_kind_set, &
particle_set=particle_set)
! Set up the matrices
CALL cp_fm_create(buf, vcd_env%dcdr_env%likemos_fm_struct(ispin)%struct)
CALL cp_fm_create(buf2, vcd_env%dcdr_env%likemos_fm_struct(ispin)%struct)
CALL cp_fm_create(matrix_dSdB_mo, vcd_env%dcdr_env%momo_fm_struct(ispin)%struct)
! First prepare the coefficients dCB_prime = -dCB - 0.5 S1_ij
! The first negative because we get the negative coefficients out of the linres solver
! The second term due to the occ-occ block of the U matrix in C1 = U * C0
DO alpha = 1, 3
! CALL cp_fm_scale_and_add(0._dp, vcd_env%dCB_prime(alpha), -1._dp, vcd_env%dCB(alpha))
CALL cp_dbcsr_sm_fm_multiply(vcd_env%matrix_dSdB(alpha)%matrix, mo_coeff, &
buf, ncol=nmo, alpha=1._dp, beta=0._dp)
CALL parallel_gemm("T", "N", nmo, nmo, nao, &
1.0_dp, mo_coeff, buf, &
0.0_dp, matrix_dSdB_mo)
CALL parallel_gemm("N", "N", nao, nmo, nmo, &
-0.5_dp, mo_coeff, matrix_dSdB_mo, &
0.0_dp, vcd_env%dCB_prime(alpha))
END DO
! The AATs in MFP consist of four terms
!
! i) (i CB_alpha) * CR_beta * S0
! ii) (i CB_alpha) * C0 * < mu | d/dR_beta^\lambda nu >
! iii) -1/c * ε_{alpha gamma delta} * C0 * C0 * < mu | r_delta | d/dR_beta^\lambda nu > * R^mu_gamma
! iv) -1/c * ε_{alpha gamma delta} * C0 * CR_beta * < mu | r_delta | nu > * R^mu_gamma
! iii) -1/c * ε_{alpha gamma delta} * C0 * C0 * < mu | r_delta | d/dR_beta^\lambda nu > * R^mu_gamma
! +1/c * ε_{alpha gamma delta} * C0 * C0 * < mu | r_delta ∂_beta | nu > * R^mu_gamma * delta_nu^lambda
!
!
! vcd_env%moments_der_right(delta, beta)%matrix
! = +/- < mu | r_delta ∂_beta | nu > * (nu == lambda)
DO alpha = 1, 3
aat_moment_der = 0._dp
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
CALL dbcsr_copy(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
vcd_env%moments_der_right(delta, vcd_env%dcdr_env%beta)%matrix)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE., &
gauge_origin=gauge_origin)
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, mo_coeff, buf, ncol=nmo)
CALL cp_fm_trace(buf, mo_coeff, tmp_trace)
aat_moment_der = aat_moment_der - lc_tmp*tmp_trace
END DO
END DO
aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) &
= aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) + aat_moment_der
END DO
! And additionally we have the reference dependence
! + ε_{alpha gamma delta} * P0 * < mu | R^mu_gamma * r_delta ∂_beta | nu > * delta_nu^lambda
! - ε_{alpha gamma delta} * P0 * < mu | r_delta ∂_beta | nu > * R^G_gamma * delta_nu^lambda
! - ε_{alpha gamma delta} * P0 * < mu | R^mu_gamma * ∂_beta | nu > * R^G_delta * delta_nu^lambda
! + ε_{alpha gamma delta} * P0 * < mu | ∂_beta | nu > * R^G_gamma * R^G_delta * delta_nu^lambda
DO alpha = 1, 3
aat_tmp = 0._dp
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
! - < mu | r_delta ∂_beta | nu > * R^G_gamma * delta_nu^lambda
! I have
! vcd_env%moments_der_right(delta, beta)%matrix = -< mu | r_delta ∂_beta | nu > * (nu == lambda)
CALL cp_dbcsr_sm_fm_multiply(vcd_env%moments_der_right(delta, vcd_env%dcdr_env%beta)%matrix, &
mo_coeff, buf, ncol=nmo)
CALL cp_fm_trace(buf, mo_coeff, tmp_trace)
aat_tmp = aat_tmp + lc_tmp*tmp_trace*vcd_env%magnetic_origin_atom(gamma)
! - < mu | R^mu_gamma * ∂_beta | nu > * R^G_delta * delta_nu^lambda
! I have
! dipvel_ao(beta) = < a | ∂_beta | b >
CALL dbcsr_copy(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, vcd_env%dipvel_ao(vcd_env%dcdr_env%beta)%matrix)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE.)
CALL hr_mult_by_delta_1d(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, qs_kind_set, "ORB", &
sab_all, direction_Or=.TRUE., lambda=vcd_env%dcdr_env%lambda)
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, mo_coeff, buf, &
ncol=nmo, alpha=1._dp, beta=0._dp)
CALL cp_fm_trace(buf, mo_coeff, tmp_trace)
aat_tmp = aat_tmp - lc_tmp*tmp_trace*vcd_env%spatial_origin_atom(delta)
! + < mu | ∂_beta | nu > * R^G_gamma * R^G_delta * delta_nu^lambda
! I have
! dipvel_ao(beta) = < a | ∂_beta | b >
CALL dbcsr_copy(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, vcd_env%dipvel_ao(vcd_env%dcdr_env%beta)%matrix)
CALL hr_mult_by_delta_1d(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, qs_kind_set, "ORB", &
sab_all, direction_Or=.TRUE., lambda=vcd_env%dcdr_env%lambda)
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, mo_coeff, buf, &
ncol=nmo, alpha=1._dp, beta=0._dp)
CALL cp_fm_trace(buf, mo_coeff, tmp_trace)
aat_tmp = aat_tmp + lc_tmp*tmp_trace &
*vcd_env%spatial_origin_atom(delta)*vcd_env%magnetic_origin_atom(gamma)
END DO
END DO
aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) &
= aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) + aat_tmp
END DO
! ii) (i CB_alpha) * C0 * < mu | d/dR_beta^\lambda nu >
! = - (i CB_alpha) * C0 * < mu | ∂_beta | nu > * delta_nu^lambda
!
! dipvel_ao = + < a | ∂ | b >, so I can take that and multiply with the delta
CALL dbcsr_desymmetrize(vcd_env%dipvel_ao(vcd_env%dcdr_env%beta)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix)
CALL hr_mult_by_delta_1d(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, qs_kind_set, "ORB", &
sab_all, direction_Or=.TRUE., lambda=vcd_env%dcdr_env%lambda)
DO alpha = 1, 3
CALL cp_fm_set_all(buf, 0.0_dp)
aat_linmom = 0.0_dp
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
mo_coeff, buf, ncol=nmo, alpha=1._dp, beta=0._dp)
CALL cp_fm_trace(buf, vcd_env%dCB(alpha), aat_linmom)
! the minus, because dipvel_ao is the derivative wrt to the electronic coordinate,
! but we need the nuclear coordinate here.
aat_linmom = -f_spin*aat_linmom
aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) &
= aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) + aat_linmom
END DO
DO alpha = 1, 3
CALL cp_fm_set_all(buf, 0.0_dp)
aat_linmom = 0.0_dp
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, mo_coeff, buf, ncol=nmo)
CALL cp_fm_trace(buf, vcd_env%dCB_prime(alpha), aat_linmom)
! the minus, because dipvel_ao is the derivative wrt to the electronic coordinate,
! but we need the nuclear coordinate here.
aat_linmom = -f_spin*aat_linmom
aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) &
= aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) + aat_linmom
END DO
! The reference dependent dSdB term is
! i/2c (- < mu | nu > * R^mu_gamma + < mu | nu > * R^nu_gamma) * R^G_delta
DO alpha = 1, 3
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp2(3)%matrix, 0._dp)
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, 0._dp)
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix, 0._dp)
CALL dbcsr_desymmetrize(vcd_env%dcdr_env%matrix_s(1)%matrix, vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix)
CALL dbcsr_desymmetrize(vcd_env%dcdr_env%matrix_s(1)%matrix, vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix)
! < mu | nu > * R^mu_gamma
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE., &
gauge_origin=gauge_origin)
! < mu | nu > * R^nu_gamma
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.TRUE., &
gauge_origin=gauge_origin)
! - < mu | nu > * R^mu_gamma + < mu | nu > * R^nu_gamma
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix, -1._dp, +1._dp)
! and accumulate the results
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp2(3)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, &
1._dp, vcd_env%spatial_origin_atom(delta)*lc_tmp/2._dp)
END DO
END DO
! With the reference dependent overlap derivative in vcd_env%dcdr_env%matrix_nosym_temp2(3)%matrix,
! we now build the corresponding coefficients as buf2 = -0.5 * C0 * S1(ref)
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp2(3)%matrix, mo_coeff, &
buf, ncol=nmo, alpha=1._dp, beta=0._dp)
CALL parallel_gemm("T", "N", nmo, nmo, nao, &
1.0_dp, mo_coeff, buf, &
0.0_dp, matrix_dSdB_mo)
CALL parallel_gemm("N", "N", nao, nmo, nmo, &
-0.5_dp, mo_coeff, matrix_dSdB_mo, &
0.0_dp, buf2)
! vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix still is < a | ∂ | b > * (nu==lambda)
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, mo_coeff, buf, ncol=nmo)
CALL cp_fm_trace(buf, buf2, aat_linmom)
aat_linmom = -f_spin*aat_linmom
aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) &
= aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) + aat_linmom
END DO
! iv) -1/c * ε_{alpha gamma delta} * C0 * CR_beta * < mu | r_delta | nu > * R^mu_gamma
DO alpha = 1, 3
aat_moment = 0._dp
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
CALL dbcsr_desymmetrize(vcd_env%dcdr_env%moments(delta)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE., &
gauge_origin=gauge_origin)
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, mo_coeff, buf, ncol=nmo)
CALL cp_fm_trace(buf, vcd_env%dcdr_env%dCR_prime(ispin), tmp_trace)
aat_moment = aat_moment - lc_tmp*tmp_trace
END DO
END DO
aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) &
= aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) + aat_moment
END DO
! And additionally we have the reference dependence
! - ε_{alpha gamma delta} * C0 * CR_beta * < mu | R^mu_gamma r_delta | nu >
! + ε_{alpha gamma delta} * C0 * CR_beta * < mu | r_delta | nu > * R^G_gamma
! + ε_{alpha gamma delta} * C0 * CR_beta * < mu | R^mu_gamma | nu > * R^G_delta
! - ε_{alpha gamma delta} * C0 * CR_beta * < mu | nu > * R^G_gamma * R^G_delta
DO alpha = 1, 3
aat_moment = 0._dp
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
! < mu | r_delta | nu > * R^G_gamma
CALL dbcsr_desymmetrize(vcd_env%dcdr_env%moments(delta)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix)
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, mo_coeff, buf, ncol=nmo)
CALL cp_fm_trace(buf, vcd_env%dcdr_env%dCR_prime(ispin), tmp_trace)
aat_moment = aat_moment + lc_tmp*tmp_trace*vcd_env%magnetic_origin_atom(gamma)
! < mu | R^mu_gamma | nu > * R^G_delta
CALL dbcsr_desymmetrize(vcd_env%dcdr_env%matrix_s(1)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE.)
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, mo_coeff, buf, ncol=nmo)
CALL cp_fm_trace(buf, vcd_env%dcdr_env%dCR_prime(ispin), tmp_trace)
aat_moment = aat_moment + lc_tmp*tmp_trace*vcd_env%spatial_origin_atom(delta)
! < mu | nu > * R^G_gamma * R^G_delta
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_s(1)%matrix, mo_coeff, buf, ncol=nmo)
CALL cp_fm_trace(buf, vcd_env%dcdr_env%dCR_prime(ispin), tmp_trace)
aat_moment = aat_moment + lc_tmp*tmp_trace &
*vcd_env%magnetic_origin_atom(gamma)*vcd_env%spatial_origin_atom(delta)
END DO
END DO
aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) &
= aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) + aat_moment
END DO
! i) 2 * (iCB_alpha) * CR_beta * S0
!
DO alpha = 1, 3
CALL cp_fm_set_all(buf, 0.0_dp)
aat_overlap = 0.0_dp
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_s(1)%matrix, vcd_env%dcdr_env%dCR_prime(ispin), buf, ncol=nmo)
CALL cp_fm_trace(buf, vcd_env%dCB(alpha), aat_overlap)
aat_overlap = f_spin*aat_overlap
! dCB_prime * dCR_prime = + iP1
aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) &
= aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) + aat_overlap
END DO
DO alpha = 1, 3
CALL cp_fm_set_all(buf, 0.0_dp)
aat_overlap = 0.0_dp
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_s(1)%matrix, vcd_env%dcdr_env%dCR_prime(ispin), buf, ncol=nmo)
CALL cp_fm_trace(buf, vcd_env%dCB_prime(alpha), aat_overlap)
aat_overlap = f_spin*aat_overlap
! dCB_prime * dCR_prime = + iP1
aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) &
= aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) + aat_overlap
END DO
! The reference dependent dSdB term is
! i/2c (- < mu | nu > * R^mu_gamma + < mu | nu > * R^nu_gamma) * R^G_delta
DO alpha = 1, 3
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp2(3)%matrix, 0._dp)
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, 0._dp)
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix, 0._dp)
CALL dbcsr_desymmetrize(vcd_env%dcdr_env%matrix_s(1)%matrix, vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix)
CALL dbcsr_desymmetrize(vcd_env%dcdr_env%matrix_s(1)%matrix, vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix)
! < mu | nu > * R^mu_gamma
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE., &
gauge_origin=gauge_origin)
! < mu | nu > * R^nu_gamma
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.TRUE., &
gauge_origin=gauge_origin)
! !! A = alpha*A + beta*B or
! - < mu | nu > * R^mu_gamma + < mu | nu > * R^nu_gamma
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix, -1._dp, +1._dp)
! and accumulate the results
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp2(3)%matrix, vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, &
1._dp, -vcd_env%spatial_origin_atom(delta)*lc_tmp/2._dp)
END DO
END DO
! With the reference dependent overlap derivative in vcd_env%dcdr_env%matrix_nosym_temp2(3)%matrix,
! we now build the corresponding coefficients as buf2 = -0.5 * C0 * S1(ref)
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp2(3)%matrix, mo_coeff, &
buf, ncol=nmo, alpha=1._dp, beta=0._dp)
CALL parallel_gemm("T", "N", nmo, nmo, nao, &
1.0_dp, mo_coeff, buf, &
0.0_dp, matrix_dSdB_mo)
CALL parallel_gemm("N", "N", nao, nmo, nmo, &
-0.5_dp, mo_coeff, matrix_dSdB_mo, &
0.0_dp, buf2)
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_s(1)%matrix, vcd_env%dcdr_env%dCR_prime(ispin), buf, ncol=nmo)
CALL cp_fm_trace(buf, buf2, aat_overlap)
aat_overlap = f_spin*aat_overlap
! dCB_prime * dCR_prime = + iP1
aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) &
= aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) + aat_overlap
END DO
! Nuclear contribution
CALL get_atomic_kind(particle_set(vcd_env%dcdr_env%lambda)%atomic_kind, kind_number=ikind)
CALL get_qs_kind(qs_kind_set(ikind), core_charge=charge, ghost=ghost)
IF (.NOT. ghost) THEN
DO alpha = 1, 3
aat_tmp = 0._dp
DO gamma = 1, 3
IF (Levi_Civita(alpha, gamma, vcd_env%dcdr_env%beta) == 0._dp) CYCLE
aat_tmp = aat_tmp + charge &
*Levi_Civita(alpha, gamma, vcd_env%dcdr_env%beta) &
*(particle_set(vcd_env%dcdr_env%lambda)%r(gamma) - vcd_env%magnetic_origin_atom(gamma))
aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) &
= aat_atom(vcd_env%dcdr_env%beta, alpha, vcd_env%dcdr_env%lambda) + aat_tmp/4.
END DO
END DO
END IF
END ASSOCIATE
CALL cp_fm_release(buf)
CALL cp_fm_release(buf2)
CALL cp_fm_release(matrix_dSdB_mo)
CALL timestop(handle)
END SUBROUTINE mfp_aat
! **************************************************************************************************
!> \brief ...
!> \param vcd_env ...
!> \param qs_env ...
!> \param alpha ...
!> \author Edward Ditler
! **************************************************************************************************
SUBROUTINE mfp_build_operator_gauge_dependent(vcd_env, qs_env, alpha)
TYPE(vcd_env_type) :: vcd_env
TYPE(qs_environment_type), POINTER :: qs_env
INTEGER :: alpha
CHARACTER(LEN=*), PARAMETER :: routineN = 'mfp_build_operator_gauge_dependent'
INTEGER, PARAMETER :: ispin = 1
INTEGER :: delta, gamma, handle, nao, nmo
REAL(dp) :: eps_ppnl, lc_tmp
REAL(dp), DIMENSION(3) :: gauge_origin
TYPE(cell_type), POINTER :: cell
TYPE(cp_fm_type) :: buf
TYPE(dbcsr_p_type), DIMENSION(:), POINTER :: matrix_ks
TYPE(dft_control_type), POINTER :: dft_control
TYPE(neighbor_list_set_p_type), DIMENSION(:), &
POINTER :: sab_all, sap_ppnl
TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
! --------------------------------------------------------------- !
! The operator consists of four parts:
! 1. R^mu x r * H^KS
! 2. H^KS * R^nu x r
! 3. [Vnl, (R^mu - Omag) x r]
! 4. (r - Omag) x ∂
! and additionally the overlap derivative comes in as
! 5. -dSdB * C0 * CHC
! --------------------------------------------------------------- !
CALL timeset(routineN, handle)
! Some setup
nmo = vcd_env%dcdr_env%nmo(ispin)
nao = vcd_env%dcdr_env%nao
ASSOCIATE (mo_coeff => vcd_env%dcdr_env%mo_coeff(ispin))
CALL get_qs_env(qs_env=qs_env, &
sab_all=sab_all, &
qs_kind_set=qs_kind_set, &
particle_set=particle_set, &
sap_ppnl=sap_ppnl, &
cell=cell, &
dft_control=dft_control, & ! For the eps_ppnl
matrix_ks=matrix_ks)
gauge_origin(:) = vcd_env%magnetic_origin_atom
eps_ppnl = dft_control%qs_control%eps_ppnl
CALL cp_fm_create(buf, vcd_env%dcdr_env%likemos_fm_struct(ispin)%struct)
CALL cp_fm_set_all(vcd_env%op_dB(ispin), 0._dp)
CALL cp_fm_set_all(buf, 0._dp)
! The first two terms in the operator are
! i/2c sum_{gamma delta} ε_{alpha gamma delta}
! (R^mu_gamma - O^mag_gamma) * < (r_delta - O^spatial) * H >
! - (R^nu_gamma - O^mag_gamma) * < H * (r_delta - O^spatial) >)
! they expand into
! i) R^mu_gamma * matrix_rh(delta) - R^nu_gamma * matrix_hr(delta)
! ii) - O^mag_gamma * (matrix_rh(delta) - matrix_hr(delta))
! iii) - (R^mu_gamma - R^nu_gamma) * O^spatial_delta * matrix_ks
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, 0._dp)
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
! i)
! R^mu_gamma * matrix_rh(delta) - R^nu_gamma * matrix_hr(delta)
! R^mu_gamma * matrix_rh(delta)
CALL dbcsr_copy(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, vcd_env%matrix_rh(ispin, delta)%matrix)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE., &
gauge_origin=gauge_origin)
! - R^nu_gamma * matrix_hr(delta)
CALL dbcsr_copy(vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, vcd_env%matrix_hr(ispin, delta)%matrix)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.TRUE., &
gauge_origin=gauge_origin)
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, 1._dp, -1._dp)
! and accumulate the results
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, 1._dp, lc_tmp/2._dp)
! ii)
! - O^mag_gamma * (matrix_rh(delta) - matrix_hr(delta))
CALL dbcsr_copy(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, vcd_env%matrix_rh(ispin, delta)%matrix)
CALL dbcsr_copy(vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, vcd_env%matrix_hr(ispin, delta)%matrix)
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, 1._dp, -1._dp)
CALL dbcsr_scale(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, -vcd_env%magnetic_origin_atom(gamma))
! and accumulate the results
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, 1._dp, lc_tmp/2._dp)
! iii)
! - (R^mu_gamma - R^nu_gamma) * O^spatial_delta * matrix_ks
CALL dbcsr_desymmetrize(matrix_ks(ispin)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix)
CALL dbcsr_desymmetrize(matrix_ks(ispin)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE., &
gauge_origin=gauge_origin)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.TRUE., &
gauge_origin=gauge_origin)
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, &
1._dp, -1._dp)
CALL dbcsr_scale(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, -vcd_env%spatial_origin_atom(delta))
! and accumulate the results
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, 1._dp, lc_tmp/2._dp)
END DO
END DO
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, mo_coeff, &
vcd_env%op_dB(ispin), ncol=nmo, alpha=1._dp, beta=1.0_dp)
! The third term in the operator is
! i/2c sum_{gamma delta} ε_{alpha gamma delta}
! sum_\eta < (R^eta_gamma - O^mag) * [Vnl^eta, r_delta] >
!
! build_com_vnl_giao calculates
! matrix_rv(gamma, delta) =
! sum_\eta < mu | R^eta_gamma * Vnl^eta * r_delta | nu >
! or the other way around: r_delta * Vnl^eta
DO gamma = 1, 3
DO delta = 1, 3
CALL dbcsr_set(vcd_env%matrix_nosym_temp_33(gamma, delta)%matrix, 0._dp)
CALL dbcsr_set(vcd_env%matrix_nosym_temp2_33(gamma, delta)%matrix, 0._dp)
END DO
END DO
! V * r_delta * R^eta_gamma
CALL build_com_vnl_giao(qs_kind_set=qs_kind_set, sab_all=sab_all, sap_ppnl=sap_ppnl, &
eps_ppnl=dft_control%qs_control%eps_ppnl, &
particle_set=particle_set, matrix_rv=vcd_env%matrix_nosym_temp_33, &
ref_point=[0._dp, 0._dp, 0._dp], cell=cell, direction_Or=.TRUE.)
! r_delta * V * R^eta_gamma
CALL build_com_vnl_giao(qs_kind_set=qs_kind_set, sab_all=sab_all, sap_ppnl=sap_ppnl, &
eps_ppnl=dft_control%qs_control%eps_ppnl, &
particle_set=particle_set, matrix_rv=vcd_env%matrix_nosym_temp2_33, &
ref_point=[0._dp, 0._dp, 0._dp], cell=cell, direction_Or=.FALSE.)
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, 0._dp)
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
! + V * r_delta * R^eta_gamma
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, vcd_env%matrix_nosym_temp_33(gamma, delta)%matrix, &
1._dp, lc_tmp)
! - r_delta * V * R^eta_gamma
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, vcd_env%matrix_nosym_temp2_33(gamma, delta)%matrix, &
1._dp, -lc_tmp)
END DO
END DO
! Same factor 1/2 as above for Hr - rH
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, mo_coeff, &
vcd_env%op_dB(ispin), ncol=nmo, alpha=1._dp/2._dp, beta=1.0_dp)
! And the O^mag dependent term:
! - sum_\eta < O^mag * [Vnl^eta, r_delta] >
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, 0._dp)
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
! vcd_env%hcom(delta) = - < mu | [V, r_delta] | nu >
CALL dbcsr_desymmetrize(vcd_env%hcom(delta)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix)
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
1._dp, vcd_env%magnetic_origin_atom(gamma)*lc_tmp/(2._dp))
END DO
END DO
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, mo_coeff, &
vcd_env%op_dB(ispin), ncol=nmo, alpha=1.0_dp, beta=1.0_dp)
! The fourth term in the operator is
! -i/2c sum_{gamma delta} ε_{alpha gamma delta}
! (r_gamma - O^mag_gamma) * ∂_delta
! It's also the P^1 term of the NVPT AAT with the reversed sign
! So in the first term alpha=+1
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, 0._dp)
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
! moments_der(gamma, delta) = - < a | r_gamma \partial_delta | b >
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, vcd_env%moments_der(gamma, delta)%matrix, &
1._dp, lc_tmp/(2._dp))
END DO
END DO
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, mo_coeff, &
vcd_env%op_dB(ispin), ncol=nmo, alpha=1.0_dp, beta=1.0_dp)
! And the O^mag dependent term
! + i/2c sum_{gamma delta} ε_{alpha gamma delta}
! O^mag_gamma * ∂_delta
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, 0._dp)
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
! dipvel_ao(delta) = + < a | ∂_delta | b >
CALL dbcsr_desymmetrize(vcd_env%dipvel_ao(delta)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix)
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
1._dp, vcd_env%magnetic_origin_atom(gamma)*lc_tmp/(2._dp))
END DO
END DO
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, mo_coeff, &
vcd_env%op_dB(ispin), ncol=nmo, alpha=1.0_dp, beta=1.0_dp)
! And the overlap derivative
! i/2c * sum_{gamma delta} ε_{alpha gamma delta}
! < r_delta > * (R^mu_gamma - R^nu_gamma)
! The reference independent part
CALL dbcsr_set(vcd_env%matrix_dSdB(alpha)%matrix, 0._dp)
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, 0._dp)
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, 0._dp)
CALL dbcsr_desymmetrize(vcd_env%dcdr_env%moments(delta)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix)
CALL dbcsr_desymmetrize(vcd_env%dcdr_env%moments(delta)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix)
! moments * R^mu_gamma
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE., &
gauge_origin=gauge_origin)
! moments * R^nu_gamma
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.TRUE., &
gauge_origin=gauge_origin)
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, 1._dp, -1._dp)
! and accumulate the results
CALL dbcsr_add(vcd_env%matrix_dSdB(alpha)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, 1._dp, lc_tmp/2._dp)
END DO
END DO
! the overlap derivative goes in as -S(1,B) * C0 * E0
CALL cp_dbcsr_sm_fm_multiply(vcd_env%matrix_dSdB(alpha)%matrix, mo_coeff, &
buf, ncol=nmo, alpha=1.0_dp, beta=0.0_dp)
CALL parallel_gemm('N', 'N', nao, nmo, nmo, &
-1.0_dp, buf, vcd_env%dcdr_env%chc(ispin), & ! the negative sign is here
1.0_dp, vcd_env%op_dB(ispin))
! And the reference dependent part of the overlap
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp2(3)%matrix, 0._dp)
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, 0._dp)
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix, 0._dp)
CALL dbcsr_desymmetrize(vcd_env%dcdr_env%matrix_s(1)%matrix, vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix)
CALL dbcsr_desymmetrize(vcd_env%dcdr_env%matrix_s(1)%matrix, vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix)
! < mu | nu > * R^mu_gamma
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE., &
gauge_origin=gauge_origin)
! < mu | nu > * R^nu_gamma
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.TRUE., &
gauge_origin=gauge_origin)
! !! A = alpha*A + beta*B or
! - < mu | nu > * R^mu_gamma + < mu | nu > * R^nu_gamma
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp2(2)%matrix, -1._dp, +1._dp)
! and accumulate the results
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp2(3)%matrix, vcd_env%dcdr_env%matrix_nosym_temp2(1)%matrix, &
1._dp, vcd_env%spatial_origin_atom(delta)*lc_tmp/2._dp)
END DO
END DO
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp2(3)%matrix, mo_coeff, &
buf, ncol=nmo, alpha=1.0_dp, beta=0.0_dp)
CALL parallel_gemm('N', 'N', nao, nmo, nmo, &
-1.0_dp, buf, vcd_env%dcdr_env%chc(ispin), & ! again, the negative sign is here
1.0_dp, vcd_env%op_dB(ispin))
! CALL cp_fm_set_all(vcd_env%op_dB(ispin), 0._dp)
CALL cp_fm_release(buf)
END ASSOCIATE
! We have built op_dB but plug -op_dB into the linres_solver
! CALL cp_fm_scale(-1.0_dp, vcd_env%op_dB(ispin))
CALL timestop(handle)
END SUBROUTINE mfp_build_operator_gauge_dependent
! **************************************************************************************************
!> \brief ...
!> \param vcd_env ...
!> \param qs_env ...
!> \param alpha ...
!> \author Edward Ditler
! **************************************************************************************************
SUBROUTINE mfp_build_operator_gauge_independent(vcd_env, qs_env, alpha)
TYPE(vcd_env_type) :: vcd_env
TYPE(qs_environment_type), POINTER :: qs_env
INTEGER :: alpha
CHARACTER(LEN=*), PARAMETER :: routineN = 'mfp_build_operator_gauge_independent'
INTEGER, PARAMETER :: ispin = 1
INTEGER :: delta, gamma, handle, nao, nmo
REAL(dp) :: eps_ppnl, lc_tmp
REAL(dp), DIMENSION(3) :: gauge_origin
TYPE(cell_type), POINTER :: cell
TYPE(cp_fm_type) :: buf
TYPE(dbcsr_p_type), DIMENSION(:), POINTER :: matrix_ks
TYPE(dft_control_type), POINTER :: dft_control
TYPE(neighbor_list_set_p_type), DIMENSION(:), &
POINTER :: sab_all, sap_ppnl
TYPE(particle_type), DIMENSION(:), POINTER :: particle_set
TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
! --------------------------------------------------------------- !
! The operator consists of three parts:
! 1. (R^mu - R^nu) x r * H_KS
! 2. [Vnl, (R^mu - R^nu) x r]
! 3. (r - R^nu) x ∂
! and additionally the overlap derivative comes in as
! 4. -dSdB * C0 * CHC
! --------------------------------------------------------------- !
CALL timeset(routineN, handle)
! Some setup
nmo = vcd_env%dcdr_env%nmo(ispin)
nao = vcd_env%dcdr_env%nao
ASSOCIATE (mo_coeff => vcd_env%dcdr_env%mo_coeff(ispin))
CALL get_qs_env(qs_env=qs_env, &
sab_all=sab_all, &
qs_kind_set=qs_kind_set, &
particle_set=particle_set, &
sap_ppnl=sap_ppnl, &
cell=cell, &
dft_control=dft_control, & ! For the eps_ppnl
matrix_ks=matrix_ks)
gauge_origin(:) = 0._dp
eps_ppnl = dft_control%qs_control%eps_ppnl
CALL cp_fm_create(buf, vcd_env%dcdr_env%likemos_fm_struct(ispin)%struct)
CALL cp_fm_set_all(vcd_env%op_dB(ispin), 0._dp)
CALL cp_fm_set_all(buf, 0._dp)
! The first term in the operator is
! i/2c sum_{gamma delta} ε_{alpha gamma delta}
! (R^mu_gamma - R^nu_gamma) < (r_delta - Ospatial) H >
! In vcd_second_prepare we build
! vcd_env%matrix_hr(1, delta) = < mu | H * r_delta | nu >
! and vcd_env%matrix_rh(1, delta) = < mu | r_delta * H | nu >
! So we need
! (R^mu_gamma - R^nu_gamma) * vcd_env%matrix_rh
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, 0._dp)
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
! The reference independent part
! vcd_env%matrix_rh * R^mu_gamma
CALL dbcsr_copy(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, vcd_env%matrix_rh(ispin, delta)%matrix)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE., &
gauge_origin=gauge_origin)
! - vcd_env%matrix_rh * R^nu_gamma
CALL dbcsr_copy(vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, vcd_env%matrix_rh(ispin, delta)%matrix)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.TRUE., &
gauge_origin=gauge_origin)
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, 1._dp, -1._dp)
! and accumulate the results
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, 1._dp, lc_tmp/2._dp)
! And the Ospatial dependent part
! - (R^mu_gamma - R^nu_gamma) * Ospatial * matrix_ks
CALL dbcsr_desymmetrize(matrix_ks(ispin)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix)
CALL dbcsr_desymmetrize(matrix_ks(ispin)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.FALSE., &
gauge_origin=gauge_origin)
CALL multiply_by_position(vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, &
qs_kind_set, particle_set, "ORB", sab_all, gamma, basis_function_nu=.TRUE., &
gauge_origin=gauge_origin)
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, vcd_env%dcdr_env%matrix_nosym_temp(2)%matrix, &
1._dp, -1._dp)
CALL dbcsr_scale(vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, -vcd_env%spatial_origin_atom(delta))
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, &
vcd_env%dcdr_env%matrix_nosym_temp(1)%matrix, 1._dp, lc_tmp/2._dp)
END DO
END DO
CALL cp_dbcsr_sm_fm_multiply(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, mo_coeff, &
vcd_env%op_dB(ispin), ncol=nmo, alpha=1._dp, beta=1.0_dp)
! The second term in the operator is
! i/2c sum_{gamma delta} ε_{alpha gamma delta}
! sum_\eta < (R^eta_gamma - R^nu_gamma) * [Vnl^eta, r_delta] >
!
! build_com_vnl_giao calculates
! matrix_rv(gamma, delta) =
! sum_\eta < mu | R^eta_gamma * Vnl^eta * r_delta | nu >
! or the other way around: r_delta * Vnl^eta
DO gamma = 1, 3
DO delta = 1, 3
CALL dbcsr_set(vcd_env%matrix_nosym_temp_33(gamma, delta)%matrix, 0._dp)
CALL dbcsr_set(vcd_env%matrix_nosym_temp2_33(gamma, delta)%matrix, 0._dp)
END DO
END DO
! V * r_delta * R^eta_gamma
CALL build_com_vnl_giao(qs_kind_set=qs_kind_set, sab_all=sab_all, sap_ppnl=sap_ppnl, &
eps_ppnl=dft_control%qs_control%eps_ppnl, &
particle_set=particle_set, matrix_rv=vcd_env%matrix_nosym_temp_33, &
ref_point=[0._dp, 0._dp, 0._dp], cell=cell, direction_Or=.TRUE.)
! r_delta * V * R^eta_gamma
CALL build_com_vnl_giao(qs_kind_set=qs_kind_set, sab_all=sab_all, sap_ppnl=sap_ppnl, &
eps_ppnl=dft_control%qs_control%eps_ppnl, &
particle_set=particle_set, matrix_rv=vcd_env%matrix_nosym_temp2_33, &
ref_point=[0._dp, 0._dp, 0._dp], cell=cell, direction_Or=.FALSE.)
CALL dbcsr_set(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, 0._dp)
DO gamma = 1, 3
DO delta = 1, 3
lc_tmp = Levi_Civita(alpha, gamma, delta)
IF (lc_tmp == 0._dp) CYCLE
! + V * r_delta * R^eta_gamma
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, &
vcd_env%matrix_nosym_temp_33(gamma, delta)%matrix, &
1._dp, lc_tmp)
! - r_delta * V * R^eta_gamma
CALL dbcsr_add(vcd_env%dcdr_env%matrix_nosym_temp(3)%matrix, &
vcd_env%matrix_nosym_temp2_33(gamma, delta)%matrix, &
1._dp, -lc_tmp)
END DO