-
Notifications
You must be signed in to change notification settings - Fork 1
/
qs_ks_utils.F
1843 lines (1638 loc) · 85.8 KB
/
qs_ks_utils.F
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!--------------------------------------------------------------------------------------------------!
! CP2K: A general program to perform molecular dynamics simulations !
! Copyright 2000-2024 CP2K developers group <https://cp2k.org> !
! !
! SPDX-License-Identifier: GPL-2.0-or-later !
!--------------------------------------------------------------------------------------------------!
! **************************************************************************************************
!> \brief routines that build the Kohn-Sham matrix (i.e calculate the coulomb
!> and xc parts
!> \par History
!> 05.2002 moved from qs_scf (see there the history) [fawzi]
!> JGH [30.08.02] multi-grid arrays independent from density and potential
!> 10.2002 introduced pools, uses updated rho as input,
!> removed most temporary variables, renamed may vars,
!> began conversion to LSD [fawzi]
!> 10.2004 moved calculate_w_matrix here [Joost VandeVondele]
!> introduced energy derivative wrt MOs [Joost VandeVondele]
!> \author Fawzi Mohamed
! **************************************************************************************************
MODULE qs_ks_utils
USE admm_types, ONLY: admm_type,&
get_admm_env
USE atomic_kind_types, ONLY: atomic_kind_type
USE cell_types, ONLY: cell_type
USE cp_control_types, ONLY: dft_control_type
USE cp_dbcsr_api, ONLY: &
dbcsr_add, dbcsr_copy, dbcsr_deallocate_matrix, dbcsr_dot, dbcsr_get_info, dbcsr_init_p, &
dbcsr_multiply, dbcsr_p_type, dbcsr_release_p, dbcsr_scale, dbcsr_scale_by_vector, &
dbcsr_set, dbcsr_type
USE cp_dbcsr_operations, ONLY: copy_dbcsr_to_fm,&
copy_fm_to_dbcsr,&
cp_dbcsr_plus_fm_fm_t,&
cp_dbcsr_sm_fm_multiply,&
dbcsr_allocate_matrix_set,&
dbcsr_deallocate_matrix_set
USE cp_ddapc, ONLY: cp_ddapc_apply_CD
USE cp_fm_struct, ONLY: cp_fm_struct_create,&
cp_fm_struct_release,&
cp_fm_struct_type
USE cp_fm_types, ONLY: cp_fm_create,&
cp_fm_get_info,&
cp_fm_release,&
cp_fm_set_all,&
cp_fm_to_fm,&
cp_fm_type
USE cp_log_handling, ONLY: cp_get_default_logger,&
cp_logger_type,&
cp_to_string
USE cp_output_handling, ONLY: cp_p_file,&
cp_print_key_finished_output,&
cp_print_key_should_output,&
cp_print_key_unit_nr
USE hfx_admm_utils, ONLY: tddft_hfx_matrix
USE hfx_derivatives, ONLY: derivatives_four_center
USE hfx_types, ONLY: hfx_type
USE input_constants, ONLY: &
cdft_alpha_constraint, cdft_beta_constraint, cdft_charge_constraint, &
cdft_magnetization_constraint, do_admm_aux_exch_func_none, do_ppl_grid, sic_ad, sic_eo, &
sic_list_all, sic_list_unpaired, sic_mauri_spz, sic_mauri_us, sic_none
USE input_section_types, ONLY: section_vals_get_subs_vals,&
section_vals_type,&
section_vals_val_get
USE kahan_sum, ONLY: accurate_dot_product,&
accurate_sum
USE kinds, ONLY: default_string_length,&
dp
USE kpoint_types, ONLY: get_kpoint_info,&
kpoint_type
USE lri_environment_methods, ONLY: v_int_ppl_update
USE lri_environment_types, ONLY: lri_density_type,&
lri_environment_type,&
lri_kind_type
USE lri_forces, ONLY: calculate_lri_forces,&
calculate_ri_forces
USE lri_ks_methods, ONLY: calculate_lri_ks_matrix,&
calculate_ri_ks_matrix
USE message_passing, ONLY: mp_para_env_type
USE ps_implicit_types, ONLY: MIXED_BC,&
MIXED_PERIODIC_BC,&
NEUMANN_BC,&
PERIODIC_BC
USE pw_env_types, ONLY: pw_env_get,&
pw_env_type
USE pw_methods, ONLY: pw_axpy,&
pw_copy,&
pw_integral_ab,&
pw_integrate_function,&
pw_scale,&
pw_transfer,&
pw_zero
USE pw_poisson_methods, ONLY: pw_poisson_solve
USE pw_poisson_types, ONLY: pw_poisson_implicit,&
pw_poisson_type
USE pw_pool_types, ONLY: pw_pool_type
USE pw_types, ONLY: pw_c1d_gs_type,&
pw_r3d_rs_type
USE qs_cdft_types, ONLY: cdft_control_type
USE qs_charges_types, ONLY: qs_charges_type
USE qs_collocate_density, ONLY: calculate_rho_elec
USE qs_energy_types, ONLY: qs_energy_type
USE qs_environment_types, ONLY: get_qs_env,&
qs_environment_type
USE qs_force_types, ONLY: qs_force_type
USE qs_integrate_potential, ONLY: integrate_v_rspace,&
integrate_v_rspace_diagonal,&
integrate_v_rspace_one_center
USE qs_kind_types, ONLY: get_qs_kind_set,&
qs_kind_type
USE qs_ks_qmmm_methods, ONLY: qmmm_modify_hartree_pot
USE qs_ks_types, ONLY: get_ks_env,&
qs_ks_env_type
USE qs_mo_types, ONLY: get_mo_set,&
mo_set_type
USE qs_rho_types, ONLY: qs_rho_get,&
qs_rho_type
USE task_list_types, ONLY: task_list_type
USE virial_types, ONLY: virial_type
USE xc, ONLY: xc_exc_calc,&
xc_vxc_pw_create1
#include "./base/base_uses.f90"
IMPLICIT NONE
PRIVATE
LOGICAL, PARAMETER :: debug_this_module = .TRUE.
CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'qs_ks_utils'
PUBLIC :: low_spin_roks, sic_explicit_orbitals, calc_v_sic_rspace, print_densities, &
print_detailed_energy, compute_matrix_vxc, sum_up_and_integrate, &
calculate_zmp_potential, get_embed_potential_energy
CONTAINS
! **************************************************************************************************
!> \brief do ROKS calculations yielding low spin states
!> \param energy ...
!> \param qs_env ...
!> \param dft_control ...
!> \param do_hfx ...
!> \param just_energy ...
!> \param calculate_forces ...
!> \param auxbas_pw_pool ...
! **************************************************************************************************
SUBROUTINE low_spin_roks(energy, qs_env, dft_control, do_hfx, just_energy, &
calculate_forces, auxbas_pw_pool)
TYPE(qs_energy_type), POINTER :: energy
TYPE(qs_environment_type), POINTER :: qs_env
TYPE(dft_control_type), POINTER :: dft_control
LOGICAL, INTENT(IN) :: do_hfx, just_energy, calculate_forces
TYPE(pw_pool_type), POINTER :: auxbas_pw_pool
CHARACTER(*), PARAMETER :: routineN = 'low_spin_roks'
INTEGER :: handle, irep, ispin, iterm, k, k_alpha, &
k_beta, n_rep, Nelectron, Nspin, Nterms
INTEGER, DIMENSION(:), POINTER :: ivec
INTEGER, DIMENSION(:, :, :), POINTER :: occupations
LOGICAL :: compute_virial, in_range, &
uniform_occupation
REAL(KIND=dp) :: ehfx, exc
REAL(KIND=dp), DIMENSION(3, 3) :: virial_xc_tmp
REAL(KIND=dp), DIMENSION(:), POINTER :: energy_scaling, rvec, scaling
TYPE(cell_type), POINTER :: cell
TYPE(dbcsr_p_type), DIMENSION(:), POINTER :: matrix_h, matrix_hfx, matrix_p, mdummy, &
mo_derivs, rho_ao
TYPE(dbcsr_p_type), DIMENSION(:, :), POINTER :: matrix_p2
TYPE(dbcsr_type), POINTER :: dbcsr_deriv, fm_deriv, fm_scaled, &
mo_coeff
TYPE(hfx_type), DIMENSION(:, :), POINTER :: x_data
TYPE(mo_set_type), DIMENSION(:), POINTER :: mo_array
TYPE(mp_para_env_type), POINTER :: para_env
TYPE(pw_c1d_gs_type), DIMENSION(:), POINTER :: rho_g
TYPE(pw_env_type), POINTER :: pw_env
TYPE(pw_pool_type), POINTER :: xc_pw_pool
TYPE(pw_r3d_rs_type) :: work_v_rspace
TYPE(pw_r3d_rs_type), DIMENSION(:), POINTER :: rho_r, tau, vxc, vxc_tau
TYPE(qs_ks_env_type), POINTER :: ks_env
TYPE(qs_rho_type), POINTER :: rho
TYPE(section_vals_type), POINTER :: hfx_section, input, &
low_spin_roks_section, xc_section
TYPE(virial_type), POINTER :: virial
IF (.NOT. dft_control%low_spin_roks) RETURN
CALL timeset(routineN, handle)
NULLIFY (ks_env, rho_ao)
! Test for not compatible options
IF (dft_control%qs_control%gapw .OR. dft_control%qs_control%gapw_xc) THEN
CALL cp_abort(__LOCATION__, "GAPW/GAPW_XC are not compatible with low spin ROKS method.")
END IF
IF (dft_control%do_admm) THEN
CALL cp_abort(__LOCATION__, "ADMM not compatible with low spin ROKS method.")
END IF
IF (dft_control%do_admm) THEN
IF (qs_env%admm_env%aux_exch_func /= do_admm_aux_exch_func_none) THEN
CALL cp_abort(__LOCATION__, "ADMM with XC correction functional "// &
"not compatible with low spin ROKS method.")
END IF
END IF
IF (dft_control%qs_control%semi_empirical .OR. dft_control%qs_control%dftb .OR. &
dft_control%qs_control%xtb) THEN
CALL cp_abort(__LOCATION__, "SE/xTB/DFTB are not compatible with low spin ROKS method.")
END IF
CALL get_qs_env(qs_env, &
ks_env=ks_env, &
mo_derivs=mo_derivs, &
mos=mo_array, &
rho=rho, &
pw_env=pw_env, &
input=input, &
cell=cell, &
virial=virial)
CALL qs_rho_get(rho, rho_ao=rho_ao)
compute_virial = virial%pv_calculate .AND. (.NOT. virial%pv_numer)
xc_section => section_vals_get_subs_vals(input, "DFT%XC")
hfx_section => section_vals_get_subs_vals(input, "DFT%XC%HF")
! some assumptions need to be checked
! we have two spins
CPASSERT(SIZE(mo_array, 1) == 2)
Nspin = 2
! we want uniform occupations
CALL get_mo_set(mo_set=mo_array(1), uniform_occupation=uniform_occupation)
CPASSERT(uniform_occupation)
CALL get_mo_set(mo_set=mo_array(2), mo_coeff_b=mo_coeff, uniform_occupation=uniform_occupation)
CPASSERT(uniform_occupation)
IF (do_hfx .AND. calculate_forces .AND. compute_virial) THEN
CALL cp_abort(__LOCATION__, "ROKS virial with HFX not available.")
END IF
NULLIFY (dbcsr_deriv)
CALL dbcsr_init_p(dbcsr_deriv)
CALL dbcsr_copy(dbcsr_deriv, mo_derivs(1)%matrix)
CALL dbcsr_set(dbcsr_deriv, 0.0_dp)
! basic info
CALL get_mo_set(mo_set=mo_array(1), mo_coeff_b=mo_coeff)
CALL dbcsr_get_info(mo_coeff, nfullcols_total=k_alpha)
CALL get_mo_set(mo_set=mo_array(2), mo_coeff_b=mo_coeff)
CALL dbcsr_get_info(mo_coeff, nfullcols_total=k_beta)
! read the input
low_spin_roks_section => section_vals_get_subs_vals(input, "DFT%LOW_SPIN_ROKS")
CALL section_vals_val_get(low_spin_roks_section, "ENERGY_SCALING", r_vals=rvec)
Nterms = SIZE(rvec)
ALLOCATE (energy_scaling(Nterms))
energy_scaling = rvec !? just wondering, should this add up to 1, in which case we should cpp?
CALL section_vals_val_get(low_spin_roks_section, "SPIN_CONFIGURATION", n_rep_val=n_rep)
CPASSERT(n_rep == Nterms)
CALL section_vals_val_get(low_spin_roks_section, "SPIN_CONFIGURATION", i_rep_val=1, i_vals=ivec)
Nelectron = SIZE(ivec)
CPASSERT(Nelectron == k_alpha - k_beta)
ALLOCATE (occupations(2, Nelectron, Nterms))
occupations = 0
DO iterm = 1, Nterms
CALL section_vals_val_get(low_spin_roks_section, "SPIN_CONFIGURATION", i_rep_val=iterm, i_vals=ivec)
CPASSERT(Nelectron == SIZE(ivec))
in_range = ALL(ivec >= 1) .AND. ALL(ivec <= 2)
CPASSERT(in_range)
DO k = 1, Nelectron
occupations(ivec(k), k, iterm) = 1
END DO
END DO
! set up general data structures
! density matrices, kohn-sham matrices
NULLIFY (matrix_p)
CALL dbcsr_allocate_matrix_set(matrix_p, Nspin)
DO ispin = 1, Nspin
ALLOCATE (matrix_p(ispin)%matrix)
CALL dbcsr_copy(matrix_p(ispin)%matrix, rho_ao(1)%matrix, &
name="density matrix low spin roks")
CALL dbcsr_set(matrix_p(ispin)%matrix, 0.0_dp)
END DO
NULLIFY (matrix_h)
CALL dbcsr_allocate_matrix_set(matrix_h, Nspin)
DO ispin = 1, Nspin
ALLOCATE (matrix_h(ispin)%matrix)
CALL dbcsr_copy(matrix_h(ispin)%matrix, rho_ao(1)%matrix, &
name="KS matrix low spin roks")
CALL dbcsr_set(matrix_h(ispin)%matrix, 0.0_dp)
END DO
IF (do_hfx) THEN
NULLIFY (matrix_hfx)
CALL dbcsr_allocate_matrix_set(matrix_hfx, Nspin)
DO ispin = 1, Nspin
ALLOCATE (matrix_hfx(ispin)%matrix)
CALL dbcsr_copy(matrix_hfx(ispin)%matrix, rho_ao(1)%matrix, &
name="HFX matrix low spin roks")
END DO
END IF
! grids in real and g space for rho and vxc
! tau functionals are not supported
NULLIFY (tau, vxc_tau, vxc)
CALL pw_env_get(pw_env, xc_pw_pool=xc_pw_pool)
ALLOCATE (rho_r(Nspin))
ALLOCATE (rho_g(Nspin))
DO ispin = 1, Nspin
CALL auxbas_pw_pool%create_pw(rho_r(ispin))
CALL auxbas_pw_pool%create_pw(rho_g(ispin))
END DO
CALL auxbas_pw_pool%create_pw(work_v_rspace)
! get mo matrices needed to construct the density matrices
! we will base all on the alpha spin matrix, obviously possible in ROKS
CALL get_mo_set(mo_set=mo_array(1), mo_coeff_b=mo_coeff)
NULLIFY (fm_scaled, fm_deriv)
CALL dbcsr_init_p(fm_scaled)
CALL dbcsr_init_p(fm_deriv)
CALL dbcsr_copy(fm_scaled, mo_coeff)
CALL dbcsr_copy(fm_deriv, mo_coeff)
ALLOCATE (scaling(k_alpha))
! for each term, add it with the given scaling factor to the energy, and compute the required derivatives
DO iterm = 1, Nterms
DO ispin = 1, Nspin
! compute the proper density matrices with the required occupations
CALL dbcsr_set(matrix_p(ispin)%matrix, 0.0_dp)
scaling = 1.0_dp
scaling(k_alpha - Nelectron + 1:k_alpha) = occupations(ispin, :, iterm)
CALL dbcsr_copy(fm_scaled, mo_coeff)
CALL dbcsr_scale_by_vector(fm_scaled, scaling, side='right')
CALL dbcsr_multiply('n', 't', 1.0_dp, mo_coeff, fm_scaled, &
0.0_dp, matrix_p(ispin)%matrix, retain_sparsity=.TRUE.)
! compute the densities on the grid
CALL calculate_rho_elec(matrix_p=matrix_p(ispin)%matrix, &
rho=rho_r(ispin), rho_gspace=rho_g(ispin), &
ks_env=ks_env)
END DO
! compute the exchange energies / potential if needed
IF (just_energy) THEN
exc = xc_exc_calc(rho_r=rho_r, rho_g=rho_g, tau=tau, xc_section=xc_section, &
pw_pool=xc_pw_pool)
ELSE
CPASSERT(.NOT. compute_virial)
CALL xc_vxc_pw_create1(vxc_rho=vxc, rho_r=rho_r, &
rho_g=rho_g, tau=tau, vxc_tau=vxc_tau, exc=exc, xc_section=xc_section, &
pw_pool=xc_pw_pool, compute_virial=.FALSE., virial_xc=virial_xc_tmp)
END IF
energy%exc = energy%exc + energy_scaling(iterm)*exc
IF (do_hfx) THEN
! Add Hartree-Fock contribution
DO ispin = 1, Nspin
CALL dbcsr_set(matrix_hfx(ispin)%matrix, 0.0_dp)
END DO
ehfx = energy%ex
CALL tddft_hfx_matrix(matrix_hfx, matrix_p, qs_env, &
recalc_integrals=.FALSE., update_energy=.TRUE.)
energy%ex = ehfx + energy_scaling(iterm)*energy%ex
END IF
! add the corresponding derivatives to the MO derivatives
IF (.NOT. just_energy) THEN
! get the potential in matrix form
DO ispin = 1, Nspin
CALL dbcsr_set(matrix_h(ispin)%matrix, 0.0_dp)
! use a work_v_rspace
CALL pw_axpy(vxc(ispin), work_v_rspace, energy_scaling(iterm)*vxc(ispin)%pw_grid%dvol, 0.0_dp)
CALL integrate_v_rspace(v_rspace=work_v_rspace, pmat=matrix_p(ispin), hmat=matrix_h(ispin), &
qs_env=qs_env, calculate_forces=calculate_forces)
CALL auxbas_pw_pool%give_back_pw(vxc(ispin))
END DO
DEALLOCATE (vxc)
IF (do_hfx) THEN
! add HFX contribution
DO ispin = 1, Nspin
CALL dbcsr_add(matrix_h(ispin)%matrix, matrix_hfx(ispin)%matrix, &
1.0_dp, energy_scaling(iterm))
END DO
IF (calculate_forces) THEN
CALL get_qs_env(qs_env, x_data=x_data, para_env=para_env)
IF (x_data(1, 1)%n_rep_hf /= 1) THEN
CALL cp_abort(__LOCATION__, "Multiple HFX section forces not compatible "// &
"with low spin ROKS method.")
END IF
IF (x_data(1, 1)%do_hfx_ri) THEN
CALL cp_abort(__LOCATION__, "HFX_RI forces not compatible with low spin ROKS method.")
ELSE
irep = 1
NULLIFY (mdummy)
matrix_p2(1:Nspin, 1:1) => matrix_p(1:Nspin)
CALL derivatives_four_center(qs_env, matrix_p2, mdummy, hfx_section, para_env, &
irep, compute_virial, &
adiabatic_rescale_factor=energy_scaling(iterm))
END IF
END IF
END IF
! add this to the mo_derivs, again based on the alpha mo_coeff
DO ispin = 1, Nspin
CALL dbcsr_multiply('n', 'n', 1.0_dp, matrix_h(ispin)%matrix, mo_coeff, &
0.0_dp, dbcsr_deriv, last_column=k_alpha)
scaling = 1.0_dp
scaling(k_alpha - Nelectron + 1:k_alpha) = occupations(ispin, :, iterm)
CALL dbcsr_scale_by_vector(dbcsr_deriv, scaling, side='right')
CALL dbcsr_add(mo_derivs(1)%matrix, dbcsr_deriv, 1.0_dp, 1.0_dp)
END DO
END IF
END DO
! release allocated memory
DO ispin = 1, Nspin
CALL auxbas_pw_pool%give_back_pw(rho_r(ispin))
CALL auxbas_pw_pool%give_back_pw(rho_g(ispin))
END DO
DEALLOCATE (rho_r, rho_g)
CALL dbcsr_deallocate_matrix_set(matrix_p)
CALL dbcsr_deallocate_matrix_set(matrix_h)
IF (do_hfx) THEN
CALL dbcsr_deallocate_matrix_set(matrix_hfx)
END IF
CALL auxbas_pw_pool%give_back_pw(work_v_rspace)
CALL dbcsr_release_p(fm_deriv)
CALL dbcsr_release_p(fm_scaled)
DEALLOCATE (occupations)
DEALLOCATE (energy_scaling)
DEALLOCATE (scaling)
CALL dbcsr_release_p(dbcsr_deriv)
CALL timestop(handle)
END SUBROUTINE low_spin_roks
! **************************************************************************************************
!> \brief do sic calculations on explicit orbitals
!> \param energy ...
!> \param qs_env ...
!> \param dft_control ...
!> \param poisson_env ...
!> \param just_energy ...
!> \param calculate_forces ...
!> \param auxbas_pw_pool ...
! **************************************************************************************************
SUBROUTINE sic_explicit_orbitals(energy, qs_env, dft_control, poisson_env, just_energy, &
calculate_forces, auxbas_pw_pool)
TYPE(qs_energy_type), POINTER :: energy
TYPE(qs_environment_type), POINTER :: qs_env
TYPE(dft_control_type), POINTER :: dft_control
TYPE(pw_poisson_type), POINTER :: poisson_env
LOGICAL, INTENT(IN) :: just_energy, calculate_forces
TYPE(pw_pool_type), POINTER :: auxbas_pw_pool
CHARACTER(*), PARAMETER :: routineN = 'sic_explicit_orbitals'
INTEGER :: handle, i, Iorb, k_alpha, k_beta, Norb
INTEGER, ALLOCATABLE, DIMENSION(:, :) :: sic_orbital_list
LOGICAL :: compute_virial, uniform_occupation
REAL(KIND=dp) :: ener, exc
REAL(KIND=dp), DIMENSION(3, 3) :: virial_xc_tmp
TYPE(cell_type), POINTER :: cell
TYPE(cp_fm_struct_type), POINTER :: fm_struct_tmp
TYPE(cp_fm_type) :: matrix_hv, matrix_v
TYPE(cp_fm_type), ALLOCATABLE, DIMENSION(:) :: mo_derivs_local
TYPE(cp_fm_type), POINTER :: mo_coeff
TYPE(dbcsr_p_type) :: orb_density_matrix_p, orb_h_p
TYPE(dbcsr_p_type), DIMENSION(:), POINTER :: mo_derivs, rho_ao, tmp_dbcsr
TYPE(dbcsr_type), POINTER :: orb_density_matrix, orb_h
TYPE(mo_set_type), DIMENSION(:), POINTER :: mo_array
TYPE(pw_c1d_gs_type) :: work_v_gspace
TYPE(pw_c1d_gs_type), DIMENSION(:), POINTER :: rho_g
TYPE(pw_c1d_gs_type), TARGET :: orb_rho_g, tmp_g
TYPE(pw_env_type), POINTER :: pw_env
TYPE(pw_pool_type), POINTER :: xc_pw_pool
TYPE(pw_r3d_rs_type) :: work_v_rspace
TYPE(pw_r3d_rs_type), DIMENSION(:), POINTER :: rho_r, tau, vxc, vxc_tau
TYPE(pw_r3d_rs_type), TARGET :: orb_rho_r, tmp_r
TYPE(qs_ks_env_type), POINTER :: ks_env
TYPE(qs_rho_type), POINTER :: rho
TYPE(section_vals_type), POINTER :: input, xc_section
TYPE(virial_type), POINTER :: virial
IF (dft_control%sic_method_id .NE. sic_eo) RETURN
CALL timeset(routineN, handle)
NULLIFY (tau, vxc_tau, mo_derivs, ks_env, rho_ao)
! generate the lists of orbitals that need sic treatment
CALL get_qs_env(qs_env, &
ks_env=ks_env, &
mo_derivs=mo_derivs, &
mos=mo_array, &
rho=rho, &
pw_env=pw_env, &
input=input, &
cell=cell, &
virial=virial)
CALL qs_rho_get(rho, rho_ao=rho_ao)
compute_virial = virial%pv_calculate .AND. (.NOT. virial%pv_numer)
xc_section => section_vals_get_subs_vals(input, "DFT%XC")
DO i = 1, SIZE(mo_array) !fm->dbcsr
IF (mo_array(i)%use_mo_coeff_b) THEN !fm->dbcsr
CALL copy_dbcsr_to_fm(mo_array(i)%mo_coeff_b, &
mo_array(i)%mo_coeff) !fm->dbcsr
END IF !fm->dbcsr
END DO !fm->dbcsr
CALL pw_env_get(pw_env, xc_pw_pool=xc_pw_pool)
! we have two spins
CPASSERT(SIZE(mo_array, 1) == 2)
! we want uniform occupations
CALL get_mo_set(mo_set=mo_array(1), uniform_occupation=uniform_occupation)
CPASSERT(uniform_occupation)
CALL get_mo_set(mo_set=mo_array(2), mo_coeff=mo_coeff, uniform_occupation=uniform_occupation)
CPASSERT(uniform_occupation)
NULLIFY (tmp_dbcsr)
CALL dbcsr_allocate_matrix_set(tmp_dbcsr, SIZE(mo_derivs, 1))
DO i = 1, SIZE(mo_derivs, 1) !fm->dbcsr
!
NULLIFY (tmp_dbcsr(i)%matrix)
CALL dbcsr_init_p(tmp_dbcsr(i)%matrix)
CALL dbcsr_copy(tmp_dbcsr(i)%matrix, mo_derivs(i)%matrix)
CALL dbcsr_set(tmp_dbcsr(i)%matrix, 0.0_dp)
END DO !fm->dbcsr
k_alpha = 0; k_beta = 0
SELECT CASE (dft_control%sic_list_id)
CASE (sic_list_all)
CALL get_mo_set(mo_set=mo_array(1), mo_coeff=mo_coeff)
CALL cp_fm_get_info(mo_coeff, ncol_global=k_alpha)
IF (SIZE(mo_array, 1) > 1) THEN
CALL get_mo_set(mo_set=mo_array(2), mo_coeff=mo_coeff)
CALL cp_fm_get_info(mo_coeff, ncol_global=k_beta)
END IF
Norb = k_alpha + k_beta
ALLOCATE (sic_orbital_list(3, Norb))
iorb = 0
DO i = 1, k_alpha
iorb = iorb + 1
sic_orbital_list(1, iorb) = 1
sic_orbital_list(2, iorb) = i
sic_orbital_list(3, iorb) = 1
END DO
DO i = 1, k_beta
iorb = iorb + 1
sic_orbital_list(1, iorb) = 2
sic_orbital_list(2, iorb) = i
IF (SIZE(mo_derivs, 1) == 1) THEN
sic_orbital_list(3, iorb) = 1
ELSE
sic_orbital_list(3, iorb) = 2
END IF
END DO
CASE (sic_list_unpaired)
! we have two spins
CPASSERT(SIZE(mo_array, 1) == 2)
! we have them restricted
CPASSERT(SIZE(mo_derivs, 1) == 1)
CPASSERT(dft_control%restricted)
CALL get_mo_set(mo_set=mo_array(1), mo_coeff=mo_coeff)
CALL cp_fm_get_info(mo_coeff, ncol_global=k_alpha)
CALL get_mo_set(mo_set=mo_array(2), mo_coeff=mo_coeff)
CALL cp_fm_get_info(mo_coeff, ncol_global=k_beta)
Norb = k_alpha - k_beta
ALLOCATE (sic_orbital_list(3, Norb))
iorb = 0
DO i = k_beta + 1, k_alpha
iorb = iorb + 1
sic_orbital_list(1, iorb) = 1
sic_orbital_list(2, iorb) = i
! we are guaranteed to be restricted
sic_orbital_list(3, iorb) = 1
END DO
CASE DEFAULT
CPABORT("")
END SELECT
! data needed for each of the orbs
CALL auxbas_pw_pool%create_pw(orb_rho_r)
CALL auxbas_pw_pool%create_pw(tmp_r)
CALL auxbas_pw_pool%create_pw(orb_rho_g)
CALL auxbas_pw_pool%create_pw(tmp_g)
CALL auxbas_pw_pool%create_pw(work_v_gspace)
CALL auxbas_pw_pool%create_pw(work_v_rspace)
ALLOCATE (orb_density_matrix)
CALL dbcsr_copy(orb_density_matrix, rho_ao(1)%matrix, &
name="orb_density_matrix")
CALL dbcsr_set(orb_density_matrix, 0.0_dp)
orb_density_matrix_p%matrix => orb_density_matrix
ALLOCATE (orb_h)
CALL dbcsr_copy(orb_h, rho_ao(1)%matrix, &
name="orb_density_matrix")
CALL dbcsr_set(orb_h, 0.0_dp)
orb_h_p%matrix => orb_h
CALL get_mo_set(mo_set=mo_array(1), mo_coeff=mo_coeff)
CALL cp_fm_struct_create(fm_struct_tmp, ncol_global=1, &
template_fmstruct=mo_coeff%matrix_struct)
CALL cp_fm_create(matrix_v, fm_struct_tmp, name="matrix_v")
CALL cp_fm_create(matrix_hv, fm_struct_tmp, name="matrix_hv")
CALL cp_fm_struct_release(fm_struct_tmp)
ALLOCATE (mo_derivs_local(SIZE(mo_array, 1)))
DO I = 1, SIZE(mo_array, 1)
CALL get_mo_set(mo_set=mo_array(i), mo_coeff=mo_coeff)
CALL cp_fm_create(mo_derivs_local(I), mo_coeff%matrix_struct)
END DO
ALLOCATE (rho_r(2))
rho_r(1) = orb_rho_r
rho_r(2) = tmp_r
CALL pw_zero(tmp_r)
ALLOCATE (rho_g(2))
rho_g(1) = orb_rho_g
rho_g(2) = tmp_g
CALL pw_zero(tmp_g)
NULLIFY (vxc)
! now apply to SIC correction to each selected orbital
DO iorb = 1, Norb
! extract the proper orbital from the mo_coeff
CALL get_mo_set(mo_set=mo_array(sic_orbital_list(1, iorb)), mo_coeff=mo_coeff)
CALL cp_fm_to_fm(mo_coeff, matrix_v, 1, sic_orbital_list(2, iorb), 1)
! construct the density matrix and the corresponding density
CALL dbcsr_set(orb_density_matrix, 0.0_dp)
CALL cp_dbcsr_plus_fm_fm_t(orb_density_matrix, matrix_v=matrix_v, ncol=1, &
alpha=1.0_dp)
CALL calculate_rho_elec(matrix_p=orb_density_matrix, &
rho=orb_rho_r, rho_gspace=orb_rho_g, &
ks_env=ks_env)
! compute the energy functional for this orbital and its derivative
CALL pw_poisson_solve(poisson_env, orb_rho_g, ener, work_v_gspace)
! no PBC correction is done here, see "calc_v_sic_rspace" for SIC methods
! with PBC aware corrections
energy%hartree = energy%hartree - dft_control%sic_scaling_a*ener
IF (.NOT. just_energy) THEN
CALL pw_transfer(work_v_gspace, work_v_rspace)
CALL pw_scale(work_v_rspace, -dft_control%sic_scaling_a*work_v_rspace%pw_grid%dvol)
CALL dbcsr_set(orb_h, 0.0_dp)
END IF
IF (just_energy) THEN
exc = xc_exc_calc(rho_r=rho_r, rho_g=rho_g, tau=tau, xc_section=xc_section, &
pw_pool=xc_pw_pool)
ELSE
CPASSERT(.NOT. compute_virial)
CALL xc_vxc_pw_create1(vxc_rho=vxc, rho_r=rho_r, &
rho_g=rho_g, tau=tau, vxc_tau=vxc_tau, exc=exc, xc_section=xc_section, &
pw_pool=xc_pw_pool, compute_virial=compute_virial, virial_xc=virial_xc_tmp)
! add to the existing work_v_rspace
CALL pw_axpy(vxc(1), work_v_rspace, -dft_control%sic_scaling_b*vxc(1)%pw_grid%dvol)
END IF
energy%exc = energy%exc - dft_control%sic_scaling_b*exc
IF (.NOT. just_energy) THEN
! note, orb_h (which is being pointed to with orb_h_p) is zeroed above
CALL integrate_v_rspace(v_rspace=work_v_rspace, pmat=orb_density_matrix_p, hmat=orb_h_p, &
qs_env=qs_env, calculate_forces=calculate_forces)
! add this to the mo_derivs
CALL cp_dbcsr_sm_fm_multiply(orb_h, matrix_v, matrix_hv, 1)
! silly trick, copy to an array of the right size and add to mo_derivs
CALL cp_fm_set_all(mo_derivs_local(sic_orbital_list(3, iorb)), 0.0_dp)
CALL cp_fm_to_fm(matrix_hv, mo_derivs_local(sic_orbital_list(3, iorb)), 1, 1, sic_orbital_list(2, iorb))
CALL copy_fm_to_dbcsr(mo_derivs_local(sic_orbital_list(3, iorb)), &
tmp_dbcsr(sic_orbital_list(3, iorb))%matrix)
CALL dbcsr_add(mo_derivs(sic_orbital_list(3, iorb))%matrix, &
tmp_dbcsr(sic_orbital_list(3, iorb))%matrix, 1.0_dp, 1.0_dp)
!
! need to deallocate vxc
CALL xc_pw_pool%give_back_pw(vxc(1))
CALL xc_pw_pool%give_back_pw(vxc(2))
DEALLOCATE (vxc)
END IF
END DO
CALL auxbas_pw_pool%give_back_pw(orb_rho_r)
CALL auxbas_pw_pool%give_back_pw(tmp_r)
CALL auxbas_pw_pool%give_back_pw(orb_rho_g)
CALL auxbas_pw_pool%give_back_pw(tmp_g)
CALL auxbas_pw_pool%give_back_pw(work_v_gspace)
CALL auxbas_pw_pool%give_back_pw(work_v_rspace)
CALL dbcsr_deallocate_matrix(orb_density_matrix)
CALL dbcsr_deallocate_matrix(orb_h)
CALL cp_fm_release(matrix_v)
CALL cp_fm_release(matrix_hv)
CALL cp_fm_release(mo_derivs_local)
DEALLOCATE (rho_r)
DEALLOCATE (rho_g)
CALL dbcsr_deallocate_matrix_set(tmp_dbcsr) !fm->dbcsr
CALL timestop(handle)
END SUBROUTINE sic_explicit_orbitals
! **************************************************************************************************
!> \brief do sic calculations on the spin density
!> \param v_sic_rspace ...
!> \param energy ...
!> \param qs_env ...
!> \param dft_control ...
!> \param rho ...
!> \param poisson_env ...
!> \param just_energy ...
!> \param calculate_forces ...
!> \param auxbas_pw_pool ...
! **************************************************************************************************
SUBROUTINE calc_v_sic_rspace(v_sic_rspace, energy, &
qs_env, dft_control, rho, poisson_env, just_energy, &
calculate_forces, auxbas_pw_pool)
TYPE(pw_r3d_rs_type), POINTER :: v_sic_rspace
TYPE(qs_energy_type), POINTER :: energy
TYPE(qs_environment_type), POINTER :: qs_env
TYPE(dft_control_type), POINTER :: dft_control
TYPE(qs_rho_type), POINTER :: rho
TYPE(pw_poisson_type), POINTER :: poisson_env
LOGICAL, INTENT(IN) :: just_energy, calculate_forces
TYPE(pw_pool_type), POINTER :: auxbas_pw_pool
INTEGER :: i, nelec, nelec_a, nelec_b, nforce
REAL(kind=dp) :: ener, full_scaling, scaling
REAL(KIND=dp), ALLOCATABLE, DIMENSION(:, :) :: store_forces
TYPE(mo_set_type), DIMENSION(:), POINTER :: mo_array
TYPE(pw_c1d_gs_type) :: work_rho, work_v
TYPE(pw_c1d_gs_type), DIMENSION(:), POINTER :: rho_g
TYPE(qs_force_type), DIMENSION(:), POINTER :: force
NULLIFY (mo_array, rho_g)
IF (dft_control%sic_method_id == sic_none) RETURN
IF (dft_control%sic_method_id == sic_eo) RETURN
IF (dft_control%qs_control%gapw) &
CPABORT("sic and GAPW not yet compatible")
! OK, right now we like two spins to do sic, could be relaxed for AD
CPASSERT(dft_control%nspins == 2)
CALL auxbas_pw_pool%create_pw(work_rho)
CALL auxbas_pw_pool%create_pw(work_v)
CALL qs_rho_get(rho, rho_g=rho_g)
! Hartree sic corrections
SELECT CASE (dft_control%sic_method_id)
CASE (sic_mauri_us, sic_mauri_spz)
CALL pw_copy(rho_g(1), work_rho)
CALL pw_axpy(rho_g(2), work_rho, alpha=-1._dp)
CALL pw_poisson_solve(poisson_env, work_rho, ener, work_v)
CASE (sic_ad)
! find out how many elecs we have
CALL get_qs_env(qs_env, mos=mo_array)
CALL get_mo_set(mo_set=mo_array(1), nelectron=nelec_a)
CALL get_mo_set(mo_set=mo_array(2), nelectron=nelec_b)
nelec = nelec_a + nelec_b
CALL pw_copy(rho_g(1), work_rho)
CALL pw_axpy(rho_g(2), work_rho)
scaling = 1.0_dp/REAL(nelec, KIND=dp)
CALL pw_scale(work_rho, scaling)
CALL pw_poisson_solve(poisson_env, work_rho, ener, work_v)
CASE DEFAULT
CPABORT("Unknown sic method id")
END SELECT
! Correct for DDAP charges (if any)
! storing whatever force might be there from previous decoupling
IF (calculate_forces) THEN
CALL get_qs_env(qs_env=qs_env, force=force)
nforce = 0
DO i = 1, SIZE(force)
nforce = nforce + SIZE(force(i)%ch_pulay, 2)
END DO
ALLOCATE (store_forces(3, nforce))
nforce = 0
DO i = 1, SIZE(force)
store_forces(1:3, nforce + 1:nforce + SIZE(force(i)%ch_pulay, 2)) = force(i)%ch_pulay(:, :)
force(i)%ch_pulay(:, :) = 0.0_dp
nforce = nforce + SIZE(force(i)%ch_pulay, 2)
END DO
END IF
CALL cp_ddapc_apply_CD(qs_env, &
work_rho, &
ener, &
v_hartree_gspace=work_v, &
calculate_forces=calculate_forces, &
Itype_of_density="SPIN")
SELECT CASE (dft_control%sic_method_id)
CASE (sic_mauri_us, sic_mauri_spz)
full_scaling = -dft_control%sic_scaling_a
CASE (sic_ad)
full_scaling = -dft_control%sic_scaling_a*nelec
CASE DEFAULT
CPABORT("Unknown sic method id")
END SELECT
energy%hartree = energy%hartree + full_scaling*ener
! add scaled forces, restoring the old
IF (calculate_forces) THEN
nforce = 0
DO i = 1, SIZE(force)
force(i)%ch_pulay(:, :) = force(i)%ch_pulay(:, :)*full_scaling + &
store_forces(1:3, nforce + 1:nforce + SIZE(force(i)%ch_pulay, 2))
nforce = nforce + SIZE(force(i)%ch_pulay, 2)
END DO
END IF
IF (.NOT. just_energy) THEN
ALLOCATE (v_sic_rspace)
CALL auxbas_pw_pool%create_pw(v_sic_rspace)
CALL pw_transfer(work_v, v_sic_rspace)
! also take into account the scaling (in addition to the volume element)
CALL pw_scale(v_sic_rspace, &
dft_control%sic_scaling_a*v_sic_rspace%pw_grid%dvol)
END IF
CALL auxbas_pw_pool%give_back_pw(work_rho)
CALL auxbas_pw_pool%give_back_pw(work_v)
END SUBROUTINE calc_v_sic_rspace
! **************************************************************************************************
!> \brief ...
!> \param qs_env ...
!> \param rho ...
! **************************************************************************************************
SUBROUTINE print_densities(qs_env, rho)
TYPE(qs_environment_type), POINTER :: qs_env
TYPE(qs_rho_type), POINTER :: rho
INTEGER :: img, ispin, n_electrons, output_unit
REAL(dp) :: tot1_h, tot1_s, tot_rho_r, trace, &
trace_tmp
REAL(KIND=dp), DIMENSION(:), POINTER :: tot_rho_r_arr
TYPE(cell_type), POINTER :: cell
TYPE(cp_logger_type), POINTER :: logger
TYPE(dbcsr_p_type), DIMENSION(:, :), POINTER :: matrix_s, rho_ao
TYPE(dft_control_type), POINTER :: dft_control
TYPE(qs_charges_type), POINTER :: qs_charges
TYPE(qs_kind_type), DIMENSION(:), POINTER :: qs_kind_set
TYPE(section_vals_type), POINTER :: input, scf_section
NULLIFY (qs_charges, qs_kind_set, cell, input, logger, scf_section, matrix_s, &
dft_control, tot_rho_r_arr, rho_ao)
logger => cp_get_default_logger()
CALL get_qs_env(qs_env, &
qs_kind_set=qs_kind_set, &
cell=cell, qs_charges=qs_charges, &
input=input, &
matrix_s_kp=matrix_s, &
dft_control=dft_control)
CALL get_qs_kind_set(qs_kind_set, nelectron=n_electrons)
scf_section => section_vals_get_subs_vals(input, "DFT%SCF")
output_unit = cp_print_key_unit_nr(logger, scf_section, "PRINT%TOTAL_DENSITIES", &
extension=".scfLog")
CALL qs_rho_get(rho, tot_rho_r=tot_rho_r_arr, rho_ao_kp=rho_ao)
n_electrons = n_electrons - dft_control%charge
tot_rho_r = accurate_sum(tot_rho_r_arr)
trace = 0
IF (BTEST(cp_print_key_should_output(logger%iter_info, scf_section, "PRINT%TOTAL_DENSITIES"), cp_p_file)) THEN
DO ispin = 1, dft_control%nspins
DO img = 1, dft_control%nimages
CALL dbcsr_dot(rho_ao(ispin, img)%matrix, matrix_s(1, img)%matrix, trace_tmp)
trace = trace + trace_tmp
END DO
END DO
END IF
IF (output_unit > 0) THEN
WRITE (UNIT=output_unit, FMT="(/,T3,A,T41,F20.10)") "Trace(PS):", trace
WRITE (UNIT=output_unit, FMT="((T3,A,T41,2F20.10))") &
"Electronic density on regular grids: ", &
tot_rho_r, &
tot_rho_r + &
REAL(n_electrons, dp), &
"Core density on regular grids:", &
qs_charges%total_rho_core_rspace, &
qs_charges%total_rho_core_rspace - REAL(n_electrons + dft_control%charge, dp)
END IF
IF (dft_control%qs_control%gapw) THEN
tot1_h = qs_charges%total_rho1_hard(1)
tot1_s = qs_charges%total_rho1_soft(1)
DO ispin = 2, dft_control%nspins
tot1_h = tot1_h + qs_charges%total_rho1_hard(ispin)
tot1_s = tot1_s + qs_charges%total_rho1_soft(ispin)
END DO
IF (output_unit > 0) THEN
WRITE (UNIT=output_unit, FMT="((T3,A,T41,2F20.10))") &
"Hard and soft densities (Lebedev):", &
tot1_h, tot1_s
WRITE (UNIT=output_unit, FMT="(T3,A,T41,F20.10)") &
"Total Rho_soft + Rho1_hard - Rho1_soft (r-space): ", &
tot_rho_r + tot1_h - tot1_s, &
"Total charge density (r-space): ", &
tot_rho_r + tot1_h - tot1_s &
+ qs_charges%total_rho_core_rspace, &
"Total Rho_soft + Rho0_soft (g-space):", &
qs_charges%total_rho_gspace
END IF
qs_charges%background = tot_rho_r + tot1_h - tot1_s + &
qs_charges%total_rho_core_rspace
ELSE IF (dft_control%qs_control%gapw_xc) THEN
tot1_h = qs_charges%total_rho1_hard(1)
tot1_s = qs_charges%total_rho1_soft(1)
DO ispin = 2, dft_control%nspins
tot1_h = tot1_h + qs_charges%total_rho1_hard(ispin)
tot1_s = tot1_s + qs_charges%total_rho1_soft(ispin)
END DO
IF (output_unit > 0) THEN
WRITE (UNIT=output_unit, FMT="(/,(T3,A,T41,2F20.10))") &
"Hard and soft densities (Lebedev):", &
tot1_h, tot1_s
WRITE (UNIT=output_unit, FMT="(T3,A,T41,F20.10)") &
"Total Rho_soft + Rho1_hard - Rho1_soft (r-space): ", &
accurate_sum(tot_rho_r_arr) + tot1_h - tot1_s
END IF
qs_charges%background = tot_rho_r + &
qs_charges%total_rho_core_rspace
ELSE
IF (output_unit > 0) THEN
WRITE (UNIT=output_unit, FMT="(T3,A,T41,F20.10)") &
"Total charge density on r-space grids: ", &
tot_rho_r + &
qs_charges%total_rho_core_rspace, &
"Total charge density g-space grids: ", &
qs_charges%total_rho_gspace
END IF
qs_charges%background = tot_rho_r + &
qs_charges%total_rho_core_rspace
END IF
IF (output_unit > 0) WRITE (UNIT=output_unit, FMT="()")
qs_charges%background = qs_charges%background/cell%deth
CALL cp_print_key_finished_output(output_unit, logger, scf_section, &
"PRINT%TOTAL_DENSITIES")
END SUBROUTINE print_densities
! **************************************************************************************************
!> \brief Print detailed energies
!>
!> \param qs_env ...
!> \param dft_control ...
!> \param input ...
!> \param energy ...