build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

ext.versionMajor = 0
ext.versionMinor = 9
ext.versionPatch = 19

buildscript {
    ext.kotlin_version = '1.9.22'
    repositories {
        google()
        mavenCentral()

    }
    dependencies {
        classpath 'com.android.tools.build:gradle:8.7.3'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()

    }
}

private Integer makeVersionCode(int minSdkVersion, boolean wear) {
    long version = minSdkVersion * 1000000 +
            ext.versionMajor * 10000 +
            ext.versionMinor * 100 +
            ext.versionPatch
    if (wear) {
        return 100000000 + version
    } else {
        return version
    }
}

private String makeVersionName() {
    return "${ext.versionMajor}.${ext.versionMinor}.${ext.versionPatch}"
}

private int getNightlyVersionCode() {
    return project.hasProperty("commitCount") ? project.commitCount.toInteger() * 10: 0
}

private String getNightlyVersionName() {
    return project.hasProperty("commitHash") ? "nightly-" + project.commitHash : ""
}

tasks.register('clean', Delete) {
    delete rootProject.buildDir
}