-
-
Notifications
You must be signed in to change notification settings - Fork 0
/
configure.ac
288 lines (230 loc) · 8.39 KB
/
configure.ac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
dnl Process this file with autoconf to produce a configure script.
AC_PREREQ(2.63.2)
m4_define(lapiz_major_version, 1)
m4_define(lapiz_minor_version, 25)
m4_define(lapiz_micro_version, 0)
m4_define(lapiz_version, lapiz_major_version.lapiz_minor_version.lapiz_micro_version)
AC_INIT([lapiz], [lapiz_version],
[https://github.com/cafe-desktop/lapiz/issues],
[lapiz], [http://cafe-desktop.org])
AC_CONFIG_HEADERS(config.h)
AC_CONFIG_SRCDIR(lapiz/lapiz.c)
AC_CONFIG_MACRO_DIR([m4])
AC_DEFINE(LAPIZ_MAJOR_VERSION, lapiz_major_version, [Lapiz major version])
AC_SUBST(LAPIZ_MAJOR_VERSION, lapiz_major_version)
AC_DEFINE(LAPIZ_MINOR_VERSION, lapiz_minor_version, [Lapiz minor version])
AC_SUBST(LAPIZ_MINOR_VERSION, lapiz_minor_version)
AC_DEFINE(LAPIZ_MICRO_VERSION, lapiz_micro_version, [Lapiz micro version])
AC_SUBST(LAPIZ_MICRO_VERSION, lapiz_micro_version)
AM_INIT_AUTOMAKE([1.10 dist-xz no-dist-gzip -Wno-portability check-news])
AM_MAINTAINER_MODE
m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
CAFE_COMPILE_WARNINGS
# Checks for programs
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_SYS_LARGEFILE
PKG_PROG_PKG_CONFIG
AC_PATH_PROG([GLA11Y], [gla11y], [true])
# Initialize libtool
LT_PREREQ([2.2.6])
LT_INIT(disable-static)
GTK_DOC_CHECK([1.0],[--flavour=no-tmpl])
AC_CHECK_LIB(m, floor)
dnl make sure we keep ACLOCAL_FLAGS around for maintainer builds to work
AC_SUBST(ACLOCAL_AMFLAGS, "$ACLOCAL_FLAGS -I m4")
dnl toolbar style for GSettings schemas
TOOLBAR_STYLE="LAPIZ_TOOLBAR_SYSTEM"
AC_SUBST(TOOLBAR_STYLE)
dnl ===============================================================
dnl Expanded dirs
dnl ===============================================================
# This macro expands DIR and assigns it to RET.
# If DIR is NONE, then it's replaced by DEFAULT.
# Based on AC_DEFINE_DIR
AC_DEFUN([LAPIZ_FULLPATH], [
test "x$prefix" = xNONE && prefix="$ac_default_prefix"
test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
ac_expand=[$]$1
test "x$ac_expand" = xNONE && ac_expand="[$]$2"
ac_expand=`eval echo [$]ac_expand`
$3=`eval echo [$]ac_expand`
])
dnl FULL_LIBEXECDIR is used for X-CAFE-Bugzilla-ExtraInfoScript expansion
dnl in data/lapiz.desktop.in.in
LAPIZ_FULLPATH(libexecdir, NONE, FULL_LIBEXECDIR)
AC_SUBST(FULL_LIBEXECDIR)
dnl ================================================================
dnl Gettext stuff.
dnl ================================================================
AM_GNU_GETTEXT_VERSION([0.19.8])
AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.8])
AM_GNU_GETTEXT([external])
GETTEXT_PACKAGE=lapiz
AC_SUBST([GETTEXT_PACKAGE])
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Define to the Gettext package name])
dnl ================================================================
dnl Use gvfs metadata or the old xml file store.
dnl ================================================================
AC_ARG_ENABLE([gvfs-metadata],
AS_HELP_STRING([--enable-gvfs-metadata], [Enable using gvfs to store metadata]),
[enable_gvfs_metadata=$enableval],
[enable_gvfs_metadata=yes])
AM_CONDITIONAL(ENABLE_GVFS_METADATA, test "x$enable_gvfs_metadata" != "xno")
if test "x$enable_gvfs_metadata" != "xno"; then
AC_DEFINE([ENABLE_GVFS_METADATA], [1], [Define to enable using gvfs metadata])
fi
dnl ================================================================
dnl spell plugins checks: enchant and iso-codes
dnl ================================================================
ENCHANT_REQUIRED=1.6.0
ISO_CODES_REQUIRED=0.35
AC_ARG_ENABLE([spell],
AS_HELP_STRING([--disable-spell],[Disable spell plugin (default: enabled)]),
[enable_enchant=$enableval],
[enable_enchant=yes])
if test "x$enable_enchant" = "xyes" ; then
ENCHANT_MODNAME=enchant
PKG_CHECK_EXISTS([enchant-2 >= $ENCHANT_REQUIRED], [have_enchant_2=yes], [have_enchant_2=no])
if test "x$have_enchant_2" = "xyes"; then
ENCHANT_MODNAME=enchant-2
fi
AC_MSG_CHECKING([the version of enchant])
ENCHANT_VERSION=`pkg-config --modversion $ENCHANT_MODNAME`
AC_MSG_RESULT([$ENCHANT_VERSION])
PKG_CHECK_MODULES(ENCHANT, [$ENCHANT_MODNAME >= $ENCHANT_REQUIRED], \
have_enchant=yes, have_enchant=no)
if test "x$have_enchant" = "xyes"; then
PKG_CHECK_EXISTS([iso-codes >= $ISO_CODES_REQUIRED],
[have_iso_codes=yes],[have_iso_codes=no])
if test "x$have_iso_codes" = "xyes"; then
AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
$PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
result=yes
else
result=no
have_iso_codes=no
fi
AC_MSG_RESULT([$result])
fi
if test "x$have_iso_codes" = "xyes"; then
AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX],["`$PKG_CONFIG --variable=prefix iso-codes`"],[ISO codes prefix])
AC_DEFINE([HAVE_ISO_CODES],[1],[Define if you have the iso-codes package])
else
AC_MSG_ERROR([iso-codes is required to build the spell plugin. Use --disable-spell to build without spell plugin.])
fi
else
enable_enchant=no
AC_MSG_ERROR([Enchant library not found or too old. Use --disable-spell to build without spell plugin.])
fi
fi
AM_CONDITIONAL(ENABLE_ENCHANT, test x"$enable_enchant" = "xyes")
CTK_REQUIRED=3.22.0
CTKSOURCEVIEW_REQUIRED=3.0.0
PKG_CHECK_MODULES(GMODULE,gmodule-2.0,[GMODULE_ADD="gmodule-2.0"],[GMODULE_ADD=""])
PKG_CHECK_MODULES(LAPIZ, [
libxml-2.0 >= 2.5.0
glib-2.0 >= 2.50.0
$GMODULE_ADD
gthread-2.0 >= 2.13.0
gio-2.0 >= 2.50.0
ctk+-3.0 >= $CTK_REQUIRED
ctksourceview-4 >= $CTKSOURCEVIEW_REQUIRED
libbean-1.0 >= 1.2.0
libbean-ctk-1.0 >= 1.2.0
])
PKG_CHECK_MODULES(X11, [x11])
LAPIZ_CFLAGS="$LAPIZ_CFLAGS $X11_CFLAGS"
LAPIZ_LIBS="$LAPIZ_LIBS $X11_LIBS"
AC_SUBST(LAPIZ_CFLAGS)
AC_SUBST(LAPIZ_LIBS)
PKG_CHECK_MODULES(EGG_SMCLIENT, [sm >= 1.0.0])
AC_SUBST(EGG_SMCLIENT_CFLAGS)
AC_SUBST(EGG_SMCLIENT_LIBS)
# Introspection
GOBJECT_INTROSPECTION_CHECK([0.9.3])
if test "$found_introspection" = "yes"; then
have_introspection=yes
AC_DEFINE([HAVE_INTROSPECTION], [1], [Define to enable GObject Introspection])
else
have_introspection=no
fi
AM_PATH_PYTHON([3.0])
dnl ================================================================
dnl GSettings related settings
dnl ================================================================
GLIB_GSETTINGS
dnl ================================================================
dnl Misc
dnl ================================================================
AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
AC_PATH_PROG(GLIB_MKENUMS, glib-mkenums)
AC_ARG_ENABLE([tests],
AS_HELP_STRING([--enable-tests], [Enable the tests]),
[enable_tests=$enableval],
[enable_tests=yes])
AM_CONDITIONAL(ENABLE_TESTS, test x$enable_tests = xyes)
PLUGIN_LIBTOOL_FLAGS="-module -avoid-version"
AC_SUBST(PLUGIN_LIBTOOL_FLAGS)
LAPIZ_PLUGINS_DATA_DIR="$datadir/lapiz/plugins"
AC_SUBST(LAPIZ_PLUGINS_DATA_DIR)
LAPIZ_PLUGINS_LIBS_DIR="$libdir/lapiz/plugins"
AC_SUBST(LAPIZ_PLUGINS_LIBS_DIR)
YELP_HELP_INIT
AC_CONFIG_FILES([
Makefile
data/lapiz.desktop.in
data/lapiz-bugreport.sh
data/lapiz.pc
data/org.cafe.lapiz.gschema.xml
data/Makefile
docs/Makefile
docs/reference/Makefile
lapiz/dialogs/Makefile
lapiz/smclient/Makefile
lapiz/Makefile
help/Makefile
pixmaps/Makefile
plugins/Makefile
plugins/changecase/Makefile
plugins/docinfo/Makefile
plugins/externaltools/data/Makefile
plugins/externaltools/Makefile
plugins/externaltools/scripts/Makefile
plugins/externaltools/tools/Makefile
plugins/filebrowser/Makefile
plugins/filebrowser/org.cafe.lapiz.plugins.filebrowser.gschema.xml
plugins/modelines/Makefile
plugins/pythonconsole/Makefile
plugins/pythonconsole/pythonconsole/Makefile
plugins/pythonconsole/org.cafe.lapiz.plugins.pythonconsole.gschema.xml
plugins/quickopen/Makefile
plugins/quickopen/quickopen/Makefile
plugins/snippets/data/lang/Makefile
plugins/snippets/data/Makefile
plugins/snippets/Makefile
plugins/snippets/snippets/Makefile
plugins/sort/Makefile
plugins/spell/Makefile
plugins/spell/org.cafe.lapiz.plugins.spell.gschema.xml
plugins/taglist/Makefile
plugins/time/Makefile
plugins/time/org.cafe.lapiz.plugins.time.gschema.xml
plugins/trailsave/Makefile
po/Makefile.in
tests/Makefile
])
AC_OUTPUT
echo "
Configuration:
Source code location: ${srcdir}
Compiler: ${CC}
Compiler flags: ${CFLAGS}
Warning flags: ${WARN_CFLAGS}
Spell Plugin enabled: $enable_enchant
Gvfs metadata enabled: $enable_gvfs_metadata
GObject Introspection: ${have_introspection}
Tests enabled: $enable_tests
"