-
Notifications
You must be signed in to change notification settings - Fork 0
/
kbr_forth.S
2625 lines (2368 loc) · 72.5 KB
/
kbr_forth.S
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/* kbr_forth: K. B. R.'s simple FORTH compiler for x86-64 GNU/Linux.
Based on the public domain FORTH compiler `jonesforth` by Richard
W. M. Jones <[email protected]> http://annexia.org/forth.
License: Creative Commons 0 (CC0)
<http://creativecommons.org/publicdomain/zero/1.0/>. To the extent
possible under law, K. B. R. has waived all copyright and related or
neighboring rights to `kbr_forth`.
*/
/* This file contains the basic assembly implementation of kbr_forth.
It uses GNU as-specific syntax and should be assembled by GCC (see
`Makefile`).
*/
.intel_syntax noprefix
// Numeric codes for Linux syscalls.
#include <asm/unistd.h>
// Version.
.set KBR_FORTH_VERSION_MAJOR, 0
.set KBR_FORTH_VERSION_MINOR, 1
.set KBR_FORTH_VERSION_PATCH, 0
/* fatal_error prints string error_msg preceded by "FATAL ERROR: " and
followed by a newline to stderr, and exits the program with exit status
status.
*/
.macro fatal_error error_msg:req, status=100
//// the error message
.section .rodata
10001:
.ascii "FATAL ERROR: \error_msg\n"
10002:
.text
// long /* ssize_t */ write(int fildes, void *buf,
// unsigned long /* size_t */ nbyte)
/// EDI = fildes = 2 /* STDERR_FILENO */
mov edi, 2
/// RSI = buf = message start
lea rsi, [10001b]
/// RDX = nbyte = message end - message start
lea rdx, [10002b - 10001b]
mov rax, __NR_write
syscall
// NOTE: no need to check return value
// void exit(int status)
/// EDI = status = status
mov edi, \status
mov rax, __NR_exit
syscall
// NOTE: no need to check return value
.endm
/* Design
======
This FORTH has 64-bit (8-byte) cells.
The dictionary is a linked list of words, in the following format:
NULL
▲
╎
┏━━╎━━━━━━━━━━━━━┳━━━━━━━┯━━━━━━━━┳━━━━━━━━━━━┳━━━━━━━━━━━┳╍╍╍╍╍╍╍╍╍╍╍╍┓
┃ link pointer ┃ flags │ length ┃ name ┃ padding ┃ definition ┃
┃ 8 B ┃ 3 b │ 5 b ┃ length B ┃ padlen B ┃ ┃
┗━━━━━━━━━━━━━━━━┻━━━━━━━┷━━━━━━━━┻━━━━━━━━━━━┻━━━━━━━━━━━┻╍╍╍╍╍╍╍╍╍╍╍╍┛
▲
╎
╎
. . . .
▲
╎
┏━━╎━━━━━━━━━━━━━┳━━━━━━━┯━━━━━━━━┳━━━━━━━━━━━┳━━━━━━━━━━━┳╍╍╍╍╍╍╍╍╍╍╍╍┓
┃ link pointer ┃ flags │ length ┃ name ┃ padding ┃ definition ┃
┃ 8 B ┃ 3 b │ 5 b ┃ length B ┃ padlen B ┃ ┃
┗━━━━━━━━━━━━━━━━┻━━━━━━━┷━━━━━━━━┻━━━━━━━━━━━┻━━━━━━━━━━━┻╍╍╍╍╍╍╍╍╍╍╍╍┛
▲
╎
┏━━╎━━━━━━━━━━━━━┳━━━━━━━┯━━━━━━━━┳━━━━━━━━━━━┳━━━━━━━━━━━┳╍╍╍╍╍╍╍╍╍╍╍╍┓
┃ link pointer ┃ flags │ length ┃ name ┃ padding ┃ definition ┃
┃ 8 B ┃ 3 b │ 5 b ┃ length B ┃ padlen B ┃ ┃
┗━━━━━━━━━━━━━━━━┻━━━━━━━┷━━━━━━━━┻━━━━━━━━━━━┻━━━━━━━━━━━┻╍╍╍╍╍╍╍╍╍╍╍╍┛
▲
╎
╎
. . . .
▲
╎
┏━━╎━━━━━━━━━━━━━┳━━━━━━━┯━━━━━━━━┳━━━━━━━━━━━┳━━━━━━━━━━━┳╍╍╍╍╍╍╍╍╍╍╍╍┓
┃ link pointer ┃ flags │ length ┃ name ┃ padding ┃ definition ┃
┃ 8 B ┃ 3 b │ 5 b ┃ length B ┃ padlen B ┃ ┃
┗━━━━━━━━━━━━━━━━┻━━━━━━━┷━━━━━━━━┻━━━━━━━━━━━┻━━━━━━━━━━━┻╍╍╍╍╍╍╍╍╍╍╍╍┛
▲
╎
╎
LATEST
The FORTH variable LATEST points to the most recently defined word, each
word contains a pointer to the word defined directly before it, and the
oldest word contains a pointer to NULL.
The padding ensures that the definition always starts on a 64-bit
boundary. It is therefore the smallest number of zero-bytes such that
(1 + length + padlen) % 8 = 0.
A definition normally has the following format for words implemented in
assembly (where codeword points to the start of assembly):
┏━━━━━━━━━━━━━┳╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍┳━━━━━━━━━━━━━━━━━━━┓
┃ codeword ┃ assembly ┃ assembly NEXT ┃
┃ 8 B ┃ [0 – ∞) B ┃ unknown B ┃
┗━━╎━━━━━━━━━━┻╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍╍┻━━━━━━━━━━━━━━━━━━━┛
╎ ▲
└╌╌╌╌╌╌╌╌╌╌╌╌╌┘
and normally the following format for words implemented in FORTH (where
codeword is DOCOL):
┏━━━━━━━━━━━━━┳╍╍╍╍╍╍╍╍╍╍╍╍╍┳╍╍╍╍╍╍╍╍╍╍╍╍╍┳╸╺╸╺╸╺━╸╺╸╺╸╺┳╍╍╍╍╍╍╍╍╍╍╍╍╍┓
┃ codeword ┃ cw ptr 1 ┃ cw ptr 2 ┃ . . . ┃ cw ptr EXIT ┃
┃ 8 B ┃ 8 B ┃ 8 B ┃ ┃ 8 B ┃
┗━━━━━━━━━━━━━┻╍╍╍╍╍╍╍╍╍╍╍╍╍┻╍╍╍╍╍╍╍╍╍╍╍╍╍┻╸╺╸╺╸╺━╸╺╸╺╸╺┻╍╍╍╍╍╍╍╍╍╍╍╍╍┛
RSI always contains the address of the next codeword to be entered after
the current word finishes.
*/
/* NEXT is used at the end of each word. It increments RSI to point to
the address of the *new* next codeword, and jumps to what the *old* next
codeword points to.
*/
.macro NEXT
lodsq
jmp [rax]
.endm
/* RSP points to the top of the data stack. The data stack grows
towards zero in memory. It starts directly before `data_stack_top` and
ends at a system-dependent location. RSP must point before (non-empty
stack) or at (empty stack) `data_stack_top`.
╎ . . . ╎
╎ ╎
│ BELOW STACK │
┟━━━━━━━━━━━━━┧
╏ . ╏
╏ . ╏
╏ ╏
╏ FREE SPACE ╏
╏ ╏
╏ . ╏
╏ . ╏
┣━━━━━━━━━━━━━┫
┃ cell n ┃◀ ── RSP
┣━━━━━━━━━━━━━┫
┃ cell n - 1 ┃
− │ ┣━━━━━━━━━━━━━┫
│ ╏ . ╏
addr │ ╏ . ╏
│ ╏ . ╏
+ ▼ ┣━━━━━━━━━━━━━┫
┃ cell 1 ┃
┣━━━━━━━━━━━━━┫
┃ cell 0 ┃
┞━━━━━━━━━━━━━┦
│ ABOVE STACK │◁ ── data_stack_top
├─ ─ ─ ─ ─ ─ ─┤
╎ . . . ╎
*/
/* DS_RSP_VALID calls fatal_error if RSP does not point to a valid
address within the data stack.
*/
.macro DS_RSP_VALID
#ifndef NDEBUG
cmp rsp, data_stack_top
jbe 11001f
// if RSP > top: not within stack
fatal_error "top of data stack is not a valid address within data stack"
11001:
#else
// noop for non-DEBUG
#endif
.endm
/* DS_PUSH pushes x on the data stack.
*/
.macro DS_PUSH x:req
// NOTE: stack overflow is left to be detected by the system
push \x
.endm
/* DS_POP pops the top of the data stack into x.
*/
.macro DS_POP x:req
#ifndef NDEBUG
cmp rsp, data_stack_top
jb 12001f
// if RSP == top: stack empty, cannot pop
fatal_error "data stack underflow"
12001:
#endif
pop \x
.endm
/* DS_DROP drops top n elements of data stack.
*/
.macro DS_DROP n=1
lea rsp, [rsp + (8 * \n)]
DS_RSP_VALID
.endm
/* DS_MIN_SIZE calls fatal_error if there are not at least n elements on
data stack.
*/
.macro DS_MIN_SIZE n:req
#ifndef NDEBUG
// ! preserve RAX !
push rax
//// compare
mov rax, data_stack_top
sub rax, rsp
// n + 1 because of the previously pushed RAX
cmp rax, 8 * (\n + 1)
jae 13001f
// if stack size < n
fatal_error "need at least \n elements on data stack"
13001:
// ! restore RAX !
pop rax
#else
// noop for non-DEBUG
#endif
.endm
/* RBP points to the top of the return stack (unlike its conventional
use as base of the stack frame). The return stack grows towards zero in
memory. It starts directly before `return_stack_top` and ends at
`return_stack`. RBP must point between `return_stack` (full stack) and
`return_stack_top` (empty stack), inclusive.
╎ . . . ╎
╎ ╎
│ BELOW STACK │
┟━━━━━━━━━━━━━┧
╏ LAST SPACE ╏◀ ── return_stack
┣╍╍╍╍╍╍╍╍╍╍╍╍╍┫
╏ . ╏
╏ . ╏
╏ ╏
╏ FREE SPACE ╏
╏ ╏
╏ . ╏
╏ . ╏
┣━━━━━━━━━━━━━┫
┃ cell n ┃◀ ── RBP
┣━━━━━━━━━━━━━┫
┃ cell n - 1 ┃
− │ ┣━━━━━━━━━━━━━┫
│ ╏ . ╏
addr │ ╏ . ╏
│ ╏ . ╏
+ ▼ ┣━━━━━━━━━━━━━┫
┃ cell 1 ┃
┣━━━━━━━━━━━━━┫
┃ cell 0 ┃
┞━━━━━━━━━━━━━┦
│ ABOVE STACK │◀ ── return_stack_top
├─ ─ ─ ─ ─ ─ ─┤
╎ . . . ╎
*/
/* RS_RBP_VALID calls fatal_error if RBP does not point to a valid
address within the return stack.
*/
.macro RS_RBP_VALID
#ifndef NDEBUG
cmp rbp, offset return_stack
jb 14001f
cmp rbp, offset return_stack_top
jbe 14002f
14001:
// if RBP < return_stack or RBP > return_stack_top: not within stack
fatal_error "top of return stack is not a valid address within return stack"
14002:
#else
// noop for non-DEBUG
#endif
.endm
/* RS_PUSH pushes x on the return stack.
*/
.macro RS_PUSH x:req
#ifndef NDEBUG
cmp rbp, offset return_stack
ja 15001f
// if RBP == return_stack: stack full, cannot push
fatal_error "return stack overflow"
15001:
#endif
lea rbp, [rbp - 8]
mov [rbp], \x
.endm
/* RS_POP pops the top of the return stack into x.
*/
.macro RS_POP x:req
#ifndef NDEBUG
cmp rbp, offset return_stack_top
jb 16001f
// if RBP == return_stack_top: stack empty, cannot pop
fatal_error "return stack underflow"
16001:
#endif
mov \x, [rbp]
lea rbp, [rbp + 8]
.endm
/* RS_DROP drops top n elements of return stack.
*/
.macro RS_DROP n=1
lea rbp, [rbp + (8 * \n)]
RS_RBP_VALID
.endm
/* DOCOL is used as the codeword in FORTH-implemented words. It pushes
the old RSI on the return stack, makes RSI the address of the first
codeword pointer in the word, and calls NEXT.
*/
.text
.align 8
DOCOL:
RS_PUSH rsi
// RAX contains address of codeword from NEXT
lea rsi, [rax + 8]
NEXT
/* Entry point
===========
We set any necessary flags and variables, the return stack, data stack,
and the data segment. Finally we jump to the FORTH word QUIT.
*/
.text
.global _start
_start:
// clear flag DF: make sure LODS and friends increment their register
cld
// initialize data stack
mov data_stack_top, rsp
mov var_S0, rsp
// initialize return stack
lea rbp, [return_stack_top]
// set up data segment
call data_segment_set_up
// initialize & run interpreter
lea rsi, [cold_start]
NEXT
.section .rodata
.align 8
cold_start:
.8byte QUIT
/* FORTH primitives
================
Some of these are defined in assembly not because they cannot by defined
in FORTH, but for speed.
*/
/* Bitmask for length in length-flags byte.
*/
.set FLAG_LENGTH_MASK, 0b00011111
/* Bitmask for immediate flag in length-flags byte. When set, the word
is run immediately by INTERPRET even in compile mode.
*/
.set FLAG_IMMEDIATE, 0b01000000
/* Bitmask for hidden flag in length-flags byte. When set, the word
cannot be found by FIND.
*/
.set FLAG_HIDDEN, 0b00100000
// link to previously defined word, used in define_header
// initial value 0: oldest word points to NULL
.set link_ptr, 0
/* Auxiliary macro used by define_word and define_code.
*/
.macro define_header label:req, name:req, flags:req
.section .rodata
.align 8
.global name_\label
name_\label :
// link pointer
.8byte link_ptr
// set link pointer to this word
.set link_ptr, name_\label
// length-flags byte
.set name_length, 17002f - 17001f
.byte \flags | name_length
// name
17001:
.ascii "\name"
17002:
// padding
.align 8
.global \label
\label :
// codeword to follow
.endm
/* define_word defines a FORTH word as if it were FORTH-implemented. It
must be followed by the codeword pointers making up the word. label is
the name of the word as a label; name is the name string of the word;
flags is a bitmask of the word flags.
*/
.macro define_word label:req, name:req, flags=0
define_header \label, "\name", \flags
// codeword: DOCOL
.8byte DOCOL
// codeword pointers to follow
.endm
/* define_code defines a FORTH word with assembly implementation. It
must be followed by the assembly code making up the word. label is the
name of the word as a label; name is the name string of the word; flags
is a bitmask of the word flags.
*/
.macro define_code label:req, name:req, flags=0
define_header \label, "\name", \flags
// codeword: pointer to the assembly code
.8byte code_\label
.text
.global code_\label
code_\label :
// assembly code to follow
.endm
/* Stack manipulation
------------------
*/
/* ( w -- ) Drop top element.
*/
define_code DROP, "DROP"
DS_DROP
NEXT
/* ( wu ... w2 w1 u -- ) Drop u and top u elements below it.
*/
define_code NDROP, "NDROP"
DS_POP rax
DS_DROP rax
NEXT
/* ( w1 w2 -- w2 w1 ) Swap top 2 elements.
*/
define_code SWAP, "SWAP"
DS_POP rax
DS_POP rbx
DS_PUSH rax
DS_PUSH rbx
NEXT
/* ( w1 -- w1 w1 ) Duplicate top element.
*/
define_code DUP, "DUP"
DS_MIN_SIZE 1
mov rax, [rsp]
DS_PUSH rax
NEXT
/* ( w1 w2 -- w1 w2 w1 ) Duplicate w1 on top of stack.
*/
define_code OVER, "OVER"
DS_MIN_SIZE 2
mov rax, [rsp + 8]
DS_PUSH rax
NEXT
/* ( w1 w2 w3 -- w2 w3 w1 ) Rotate top 3 elements downwards.
*/
define_code ROT, "ROT"
DS_POP rax
DS_POP rbx
DS_POP rcx
DS_PUSH rbx
DS_PUSH rax
DS_PUSH rcx
NEXT
/* ( w1 w2 w3 -- w3 w1 w2 ) Rotate top 3 elements upwards.
*/
define_code $HYPHEN_MINUS$ROT, "-ROT"
DS_POP rax
DS_POP rbx
DS_POP rcx
DS_PUSH rax
DS_PUSH rcx
DS_PUSH rbx
NEXT
/* ( w1 w2 -- ) Drop top 2 elements.
*/
define_code $DIGIT_TWO$DROP, "2DROP"
DS_DROP 2
NEXT
/* ( w1 w2 -- w1 w2 w1 w2 ) Duplicate top 2 elements.
*/
define_code $DIGIT_TWO$DUP, "2DUP"
DS_MIN_SIZE 2
mov rax, [rsp]
mov rbx, [rsp + 8]
DS_PUSH rbx
DS_PUSH rax
NEXT
/* ( w1 w2 w3 w4 -- w3 w4 w1 w2 ) Swap top 2 pairs of elements.
*/
define_code $DIGIT_TWO$SWAP, "2SWAP"
DS_POP rax
DS_POP rbx
DS_POP rcx
DS_POP rdx
DS_PUSH rbx
DS_PUSH rax
DS_PUSH rdx
DS_PUSH rcx
NEXT
/* ( w -- w ) OR ( w -- ) Duplicate top element if it is non-zero.
*/
define_code $QUESTION_MARK$DUP, "?DUP"
DS_MIN_SIZE 1
mov rax, [rsp]
// NOTE: not using RCX with JRCXZ here as that would be slower
test rax, rax
// jump if zero
jz 1f
// if non-zero: duplicate
DS_PUSH rax
1:
NEXT
/* Arithmetics
-----------
*/
/* ( n1 -- nr ) Increment top element by 1.
*/
define_code $DIGIT_ONE$$PLUS_SIGN$, "1+"
DS_MIN_SIZE 1
inc qword ptr [rsp]
NEXT
/* ( n1 -- nr ) Decrement top element by 1.
*/
define_code $DIGIT_ONE$$HYPEN_MINUS$, "1-"
DS_MIN_SIZE 1
dec qword ptr [rsp]
NEXT
/* ( n1 -- nr ) Increment top element by 8, a cell's size.
*/
define_code $DIGIT_EIGHT$$PLUS_SIGN$, "8+"
DS_MIN_SIZE 1
add qword ptr [rsp], 8
NEXT
/* ( n1 -- nr ) Decrement top element by 8, a cell's size.
*/
define_code $DIGIT_EIGHT$$HYPEN_MINUS$, "8-"
DS_MIN_SIZE 1
sub qword ptr [rsp], 8
NEXT
/* ( n1 n2 -- nsum ) Add top 2 elements.
*/
define_code $PLUS_SIGN$, "+"
DS_MIN_SIZE 2
DS_POP rax
add [rsp], rax
NEXT
/* ( nminuend nsubtrahend -- ndifference ) Subtract top 2 elements.
*/
define_code $HYPHEN_MINUS$, "-"
DS_MIN_SIZE 2
DS_POP rax
sub [rsp], rax
NEXT
/* ( n1 n2 -- nproduct ) Multiply top 2 elements.
*/
define_code $ASTERISK$, "*"
DS_POP rax
DS_POP rbx
imul rax, rbx
// ignore overflow: flag OF
DS_PUSH rax
NEXT
/* ( u1 u2 -- uproduct ) Multiply top 2 elements.
*/
define_code U$ASTERISK$, "U*"
DS_POP rax
DS_POP rbx
mul rbx
// ignore overflow: flag OF
DS_PUSH rax
NEXT
/* ( ndividend ndivisor -- nremainder nquotient ) Integer-divide top 2
elements, resulting in a remainder and a quotient.
*/
define_code $SOLIDUS$MOD, "/MOD"
// RBX = divisor
DS_POP rbx
// RDX:RAX = dividend
xor rdx, rdx
DS_POP rax
// RAX = quotient; RDX = remainder
idiv rbx
// ignore divide by zero and overflow: exception #DE
DS_PUSH rdx
DS_PUSH rax
NEXT
/* ( udividend udivisor -- uremainder uquotient ) Integer-divide top 2
elements, resulting in a remainder and a quotient.
*/
define_code U$SOLIDUS$MOD, "U/MOD"
// RBX = divisor
DS_POP rbx
// RDX:RAX = dividend
xor rdx, rdx
DS_POP rax
// RAX = quotient; RDX = remainder
div rbx
// ignore divide by zero and overflow: exception #DE
DS_PUSH rdx
DS_PUSH rax
NEXT
/* Auxiliary macro used by compare operators.
*/
.macro operator_cmp_2 cc:req
DS_POP rax
DS_POP rbx
cmp rbx, rax
set\cc al
movzx rax, al
DS_PUSH rax
.endm
/* ( w1 w2 -- f ) Check whether w1 = w2.
*/
define_code $EQUALS_SIGN$, "="
operator_cmp_2 e
NEXT
/* ( w1 w2 -- f ) Check whether w1 ≠ w2.
*/
define_code $LESS_THAN_SIGN$$GREATER_THAN_SIGN$, "<>"
operator_cmp_2 ne
NEXT
/* ( n1 n2 -- f ) Check whether n1 < n2.
*/
define_code $LESS_THAN_SIGN$, "<"
operator_cmp_2 l
NEXT
/* ( u1 u2 -- f ) Check whether u1 < u2.
*/
define_code U$LESS_THAN_SIGN$, "U<"
operator_cmp_2 b
NEXT
/* ( n1 n2 -- f ) Check whether n1 > n2.
*/
define_code $GREATER_THAN_SIGN$, ">"
operator_cmp_2 g
NEXT
/* ( u1 u2 -- f ) Check whether u1 > u2.
*/
define_code U$GREATER_THAN_SIGN$, "U>"
operator_cmp_2 a
NEXT
/* ( n1 n2 -- f ) Check whether n1 ≤ n2.
*/
define_code $LESS_THAN_SIGN$$EQUALS_SIGN$, "<="
operator_cmp_2 le
NEXT
/* ( u1 u2 -- f ) Check whether u1 ≤ u2.
*/
define_code U$LESS_THAN_SIGN$$EQUALS_SIGN$, "U<="
operator_cmp_2 be
NEXT
/* ( n1 n2 -- f ) Check whether n1 ≥ n2.
*/
define_code $GREATER_THAN_SIGN$$EQUALS_SIGN$, ">="
operator_cmp_2 ge
NEXT
/* ( u1 u2 -- f ) Check whether u1 ≥ u2.
*/
define_code U$GREATER_THAN_SIGN$$EQUALS_SIGN$, "U>="
operator_cmp_2 ae
NEXT
/* Auxiliary macro used by compare-to-0 predicates.
*/
.macro operator_test_1 cc:req
DS_POP rax
test rax, rax
set\cc al
movzx rax, al
DS_PUSH rax
.endm
/* ( w -- f ) Check whether w = 0.
*/
define_code $DIGIT_ZERO$$EQUALS_SIGN$, "0="
operator_test_1 z
NEXT
/* ( w -- f ) Check whether w ≠ 0.
*/
define_code $DIGIT_ZERO$$LESS_THAN_SIGN$$GREATER_THAN_SIGN$, "0<>"
operator_test_1 nz
NEXT
/* ( n -- f ) Check whether n < 0.
*/
define_code $DIGIT_ZERO$$LESS_THAN_SIGN$, "0<"
operator_test_1 l
NEXT
/* ( n -- f ) Check whether n > 0.
*/
define_code $DIGIT_ZERO$$GREATER_THAN_SIGN$, "0>"
operator_test_1 g
NEXT
/* ( n -- f ) Check whether n ≤ 0.
*/
define_code $DIGIT_ZERO$$LESS_THAN_SIGN$$EQUALS_SIGN$, "0<="
operator_test_1 le
NEXT
/* ( n -- f ) Check whether n ≥ 0.
*/
define_code $DIGIT_ZERO$$GREATER_THAN_SIGN$$EQUALS_SIGN$, "0>="
operator_test_1 ge
NEXT
/* ( w1 w2 -- wr ) Bitwise AND top 2 elements.
*/
define_code AND, "AND"
DS_MIN_SIZE 2
DS_POP rax
and [rsp], rax
NEXT
/* ( w1 w2 -- wr ) Bitwise OR top 2 elements.
*/
define_code OR, "OR"
DS_MIN_SIZE 2
DS_POP rax
or [rsp], rax
NEXT
/* ( w1 w2 -- wr ) Bitwise XOR top 2 elements.
*/
define_code XOR, "XOR"
DS_MIN_SIZE 2
DS_POP rax
xor [rsp], rax
NEXT
/* ( w1 -- wr ) Bitwise negate top element.
*/
define_code INVERT, "INVERT"
DS_MIN_SIZE 1
not qword ptr [rsp]
NEXT
/* Auxiliary macro used by bitwise shifts. */
.macro pop_shift_count reg:req
DS_POP \reg
#ifndef NDEBUG
cmp \reg, 63
jbe 1f
fatal_error "bitwise shift count greater than 63"
1:
#endif
.endm
/* ( w1 ucount -- wr ) Shift w1 ucount bits to the left, filling with
0-bits on the right. ucount must not be greater than 63.
*/
define_code $LESS_THAN_SIGN$$LESS_THAN_SIGN$, "<<"
DS_MIN_SIZE 2
pop_shift_count rcx
shl qword ptr [rsp], cl
NEXT
/* ( w1 ucount -- wr ) Shift w1 ucount bits to the right, filling with
0-bits on the left. ucount must not be greater than 63.
*/
define_code $GREATER_THAN_SIGN$$GREATER_THAN_SIGN$, ">>"
DS_MIN_SIZE 2
pop_shift_count rcx
shr qword ptr [rsp], cl
NEXT
/* ( w1 ucount -- wr ) Shift w1 ucount bits to the right, filling with
w1's sign bit on the left (arithmetic shift). ucount must not be
greater than 63.
*/
define_code A$GREATER_THAN_SIGN$$GREATER_THAN_SIGN$, "A>>"
DS_MIN_SIZE 2
pop_shift_count rcx
sar qword ptr [rsp], cl
NEXT
/* Special words
-------------
*/
/* ( -- ) Exit the FORTH-implemented word previously entered via DOCOL.
Restore RSI to one down on the return stack, and enter the next word via
NEXT.
*/
define_code EXIT, "EXIT"
RS_POP rsi
NEXT
/* Cell literals are implemented via LIT. LIT pushes the cell contained
in the next codeword pointer after it on stack.
╺╸╺╸╺╸╺┳━━━━━━━━━━━┳━━━━━━━━━━━┳╸╺╸╺╸╺╸
... ┃ LIT ┃ w ┃ ...
┃ 8 B ┃ 8 B ┃
╺╸╺╸╺╸╺┻━━━━━━━━━━━┻━━━━━━━━━━━┻╸╺╸╺╸╺╸
*/
/* ( -- w ) Push the cell literal in the next codeword to be entered
(that is, pointed to by RSI) on stack, and increase RSI to point to the
next codeword after the literal.
*/
define_code LIT, "LIT"
lodsq
DS_PUSH rax
NEXT
/* Memory access
-------------
*/
/* ( a-addr -- w ) Fetch cell at a-addr.
*/
define_code $COMMERCIAL_AT$, "@"
DS_POP rax
DS_PUSH [rax]
NEXT
/* ( w a-addr -- ) Store w at a-addr.
*/
define_code $EXCLAMATION_MARK$, "!"
DS_POP rax
DS_POP rbx
mov [rax], rbx
NEXT
/* ( n a-addr -- ) Add n to number at a-addr.
*/
define_code $PLUS_SIGN$$EXCLAMATION_MARK$, "+!"
DS_POP rax
DS_POP rbx
add [rax], rbx
NEXT
/* ( n a-addr -- ) Subtract n from number at a-addr.
*/
define_code $HYPHEN_MINUS$$EXCLAMATION_MARK$, "-!"
DS_POP rax
DS_POP rbx
sub [rax], rbx
NEXT
/* ( c-addr -- c ) Fetch byte at c-addr as a cell.
*/
define_code C$COMMERCIAL_AT$, "C@"
DS_POP rax
movzx rbx, byte ptr [rax]
DS_PUSH rbx
NEXT
/* ( c c-addr -- ) Store byte c at c-addr.
*/
define_code C$EXCLAMATION_MARK$, "C!"
DS_POP rax
DS_POP rbx
mov [rax], bl
NEXT
/* ( c-1 c-2 -- c-1-new c-2-new ) Copy byte at c-1 into byte at c-2, and
increment both by 1.
*/
define_code C$COMMERCIAL_AT$C$EXCLAMATION_MARK$, "C@C!"
DS_MIN_SIZE 2
// RDI = c-2
DS_POP rdi
// RBX = c-1
mov rbx, [rsp]
// AL = [c-1]
mov al, [rbx]
// [RDI++] = AL
stosb
// c-1++
inc qword ptr [rsp]
// push incremented c-2
DS_PUSH rdi
NEXT
/* ( c-from c-to u -- ) Copy u bytes starting at c-from to c-to.
*/
define_code CMOVE, "CMOVE"
// ! preserve RSI !
mov rdx, rsi
DS_POP rcx
DS_POP rdi
DS_POP rsi
// move RCX bytes from from [RSI] to [RDI]
rep movsb
// ! restore RSI !
mov rsi, rdx
NEXT
/* FORTH built-in variables
========================
A variable is a word which pushes an address in memory on the stack.
The contents of the variable are at that address, and may be accessed
and modified via @ and !.
*/
/* define_variable defines a word for a built-in FORTH variable. label
is the name of the variable as a label; name is the name string of the
variable; initial is the initial value of the variable; flags is a
bitmask of the word flags.
*/
.macro define_variable label:req, name:req, initial=0, flags=0
define_code \label, "\name", \flags
// assembly for the variable word
DS_PUSH "offset var_\label"
NEXT
// location of the variable
.data
.align 8
var_\label :
.8byte \initial
.endm
/* ( -- a-addr ) Address of the most recent word entry in the
dictionary.
*/
define_variable LATEST, "LATEST", name_SYSCALL
// NOTE: SYSCALL must be the last defined built-in word for this
// initial value to be correct
/* ( -- c-addr ) Address of next free byte in data segment. Compiled
words are placed here when compiling.
*/
define_variable HERE, "HERE"
/* ( -- u ) State of the interpreter. 0 is immediate mode, non-0 is
compiling mode.
*/
define_variable STATE, "STATE"
/* ( -- a-addr ) Address of the top of data stack.