-
Notifications
You must be signed in to change notification settings - Fork 0
/
umbrellaint_fortran.f90
343 lines (244 loc) · 9.68 KB
/
umbrellaint_fortran.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! Umbrella Integrator - Fortranized Key Subroutines !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! f2py compilation example:
! python3 -m numpy.f2py -c umbrellaint_fortran.f90 -m umbrellaint_fortran --opt='-O3' --f90flags="-fopenmp" -lgomp
!! point_in !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
subroutine point_in(coord, grid, thr, result, n)
!--------------------------------------------------------------------
! Evaluate if a point is close to any grid point
!--------------------------------------------------------------------
implicit none
! Variable definition
integer, intent(in) :: n
real(8), intent(in) :: coord(2), grid(n,2), thr
logical, intent(out) :: result
integer :: i
real(8) :: grid_dist(n)
! distance of grid to point
!$OMP parallel do shared(grid_dist) private(i)
do i=1,n
grid_dist(i) = (grid(i,1)-coord(1))**2 + (grid(i,2)-coord(2))**2
enddo
!$OMP end parallel do
! result true if less than thr, else false
result = minval(grid_dist) <= thr**2
end subroutine
!! Umbrella Integration derivatives in 1D !!!!!!!!!!!!!!!!!!!!!!!!!!!
subroutine ui_derivate_1d(bins, a_fc, a_rc0, a_mean, a_std, a_N, beta, n, n_bins, dA_bins)
!--------------------------------------------------------------------
! Calculate Umbrella Integration's derivatives in 1D
!--------------------------------------------------------------------
implicit none
! Variable definition
integer, intent(in) :: n ! No data elements
integer, intent(in) :: n_bins ! No bins elements
real(8), intent(in) :: bins(n_bins)
real(8), intent(in) :: a_fc(n)
real(8), intent(in) :: a_rc0(n)
real(8), intent(in) :: a_mean(n)
real(8), intent(in) :: a_std(n)
real(8), intent(in) :: a_N(n)
real(8), intent(in) :: beta
real(8), intent(out) :: dA_bins(n_bins)
integer :: ib, i
real(8) :: rc, normal, derivate(n)
real(8), parameter :: TAU_SQRT=SQRT(8.D0*DATAN(1.D0))
! calculate gradient field of free energy over array grid [Kastner 2005 - Eq.7]
!$OMP parallel do shared(dA_bins) private(ib, i, rc, normal, derivate)
do ib=1,n_bins
rc = bins(ib)
normal = normal_tot(rc)
! calculate derivative term of every data point on that grid point
do i=1,n
derivate(i) = a_N(i)*probability(rc,i)/normal * dA(rc,i)
enddo
! sum all the derivatives on that grid point
dA_bins(ib) = SUM(derivate)
enddo
!$OMP end parallel do
contains
! normal probability [Kastner 2005 - Eq.5] ------------------------
function probability(rc, i)
implicit none
real(8), intent(in) :: rc
integer, intent(in) :: i
real(8) :: probability
real(8) :: diff
diff = rc - a_mean(i)
probability = EXP(-0.5D0 * (diff/a_std(i))**2) / (a_std(i)*TAU_SQRT)
end function
! local derivative of free energy [Kastner 2005 - Eq.6] ------------
function dA(rc, i)
implicit none
real(8), intent(in) :: rc
integer, intent(in) :: i
real(8) :: dA
dA = (rc - a_mean(i)) / (beta * a_std(i)**2) - a_fc(i) * (rc - a_rc0(i))
end function
! normalization total [Kastner 2005 - Eq.8] ----------------------
function normal_tot(rc)
implicit none
real(8), intent(in) :: rc
real(8) :: normal_tot
integer :: i
normal_tot = 0.D0
do i=1,n
normal_tot = normal_tot + a_N(i) * probability(rc, i)
enddo
end function
end subroutine
!! Umbrella Integration derivatives in 2D !!!!!!!!!!!!!!!!!!!!!!!!!!!
subroutine ui_derivate_2d_rgrid(grid, m_fc, m_rc0, m_mean, m_prec, m_det_sqrt, m_N, beta, ni, nj, n_ig, n_jg, dA_grid)
!--------------------------------------------------------------------
! Calculate Umbrella Integration's derivatives in a rectangular grid
!--------------------------------------------------------------------
implicit none
! Variable definition
integer, intent(in) :: ni, nj ! Dimension of data
integer, intent(in) :: n_ig, n_jg ! Dimension of grid
real(8), intent(in) :: grid(n_jg,n_ig,2)
real(8), intent(in) :: m_fc(nj,ni,2,2)
real(8), intent(in) :: m_rc0(nj,ni,2)
real(8), intent(in) :: m_mean(nj,ni,2)
real(8), intent(in) :: m_prec(nj,ni,2,2)
real(8), intent(in) :: m_det_sqrt(nj,ni)
real(8), intent(in) :: m_N(nj,ni)
real(8), intent(in) :: beta
real(8), intent(out) :: dA_grid(n_jg,n_ig,2)
integer :: ig, jg, i, j
real(8) :: rc(2), normal, derivate(nj,ni,2)
real(8), parameter :: TAU=8.D0*DATAN(1.D0)
! calculate gradient field of free energy over array grid [Kastner 2009 - Eq.11]
!$OMP parallel do shared(dA_grid) private(ig, jg, rc, normal, derivate, i, j)
do ig=1,n_ig
do jg=1,n_jg
rc = grid(jg,ig,:)
normal = normal_tot(rc)
! calculate derivative term of every data point on that grid point
do i=1,ni
do j=1,nj
derivate(j,i,:) = m_N(j,i)*probability(rc,j,i)/normal * dA(rc,j,i)
enddo
enddo
! sum all the derivatives on that grid point
dA_grid(jg,ig,:) = (/ 0.D0, 0.D0 /)
do i=1,ni
do j=1,nj
dA_grid(jg,ig,:) = dA_grid(jg,ig,:) + derivate(j,i,:)
enddo
enddo
enddo
enddo
!$OMP end parallel do
contains
! normal probability [Kastner 2009 - Eq.9] ------------------------
function probability(rc, j, i)
implicit none
real(8), intent(in) :: rc(2)
integer, intent(in) :: j, i
real(8) :: probability
real(8) :: diff(2)
diff = rc - m_mean(j,i,:)
probability = EXP( -0.5D0 * DOT_PRODUCT(diff,MATMUL(m_prec(j,i,:,:),diff)) ) &
/ (m_det_sqrt(j,i) * TAU)
end function
! local derivative of free energy [Kastner 2009 - Eq.10] ------------
function dA(rc, j, i)
implicit none
real(8), intent(in) :: rc(2)
integer, intent(in) :: j, i
real(8) :: dA(2)
dA = MATMUL((rc - m_mean(j,i,:))/beta, m_prec(j,i,:,:)) &
- MATMUL((rc - m_rc0(j,i,:)), m_fc(j,i,:,:))
end function
! normalization total [Kastner 2009 - Eq.11] ----------------------
function normal_tot(rc)
implicit none
real(8), intent(in) :: rc(2)
real(8) :: normal_tot
integer :: j, i
normal_tot = 0.D0
do i=1,ni
do j=1,nj
normal_tot = normal_tot + m_N(j,i) * probability(rc, j, i)
enddo
enddo
end function
end subroutine
!! Umbrella Integration derivatives for igrid in 2D !!!!!!!!!!!!!!!!!
subroutine ui_derivate_2d_igrid(grid, a_fc, a_rc0, a_mean, a_prec, a_det_sqrt, a_N, beta, impossible, n, n_ig, dA_grid)
!--------------------------------------------------------------------
! Calculate Umbrella Integration's derivatives in a incomplete grid
!--------------------------------------------------------------------
implicit none
! Variable definition
integer, intent(in) :: n ! No data elements
integer, intent(in) :: n_ig ! No grid elements
real(8), intent(in) :: grid(n_ig,2)
real(8), intent(in) :: a_fc(n,2,2)
real(8), intent(in) :: a_rc0(n,2)
real(8), intent(in) :: a_mean(n,2)
real(8), intent(in) :: a_prec(n,2,2)
real(8), intent(in) :: a_det_sqrt(n)
real(8), intent(in) :: a_N(n)
real(8), intent(in) :: beta
real(8), intent(in) :: impossible
real(8), intent(out) :: dA_grid(n_ig,2)
integer :: ig, i
real(8) :: rc(2), normal, derivate(n,2)
real(8), parameter :: thr=1.D-9 ! consider impossible if lower
real(8), parameter :: TAU=8.D0*DATAN(1.D0)
! calculate gradient field of free energy over array grid [Kastner 2009 - Eq.11]
!$OMP parallel do shared(dA_grid) private(ig, rc, normal, derivate, i)
do ig=1,n_ig
rc = grid(ig,:)
normal = normal_tot(rc)
if (normal > thr) then
! calculate derivative term of every data point on that grid point
do i=1,n
derivate(i,:) = a_N(i)*probability(rc,i)/normal * dA(rc,i)
enddo
! sum all the derivatives on that grid point
dA_grid(ig,:) = (/ 0.D0, 0.D0 /)
do i=1,n
dA_grid(ig,:) = dA_grid(ig,:) + derivate(i,:)
enddo
else
dA_grid(ig,:) = (/ impossible, impossible /)
endif
enddo
!$OMP end parallel do
contains
! normal probability [Kastner 2009 - Eq.9] ------------------------
function probability(rc, i)
implicit none
real(8), intent(in) :: rc(2)
integer, intent(in) :: i
real(8) :: probability
real(8) :: diff(2)
diff = rc - a_mean(i,:)
probability = EXP( -0.5D0 * DOT_PRODUCT(diff,MATMUL(a_prec(i,:,:),diff)) ) &
/ (a_det_sqrt(i) * TAU)
end function
! local derivative of free energy [Kastner 2009 - Eq.10] ------------
function dA(rc, i)
implicit none
real(8), intent(in) :: rc(2)
integer, intent(in) :: i
real(8) :: dA(2)
dA = MATMUL((rc - a_mean(i,:))/beta, a_prec(i,:,:)) &
- MATMUL((rc - a_rc0(i,:)), a_fc(i,:,:))
end function
! normalization total [Kastner 2009 - Eq.11] ----------------------
function normal_tot(rc)
implicit none
real(8), intent(in) :: rc(2)
real(8) :: normal_tot
integer :: i
normal_tot = 0.D0
do i=1,n
normal_tot = normal_tot + a_N(i) * probability(rc, i)
enddo
end function
end subroutine