flake.nix

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = inputs:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "riscv64-linux"
      ];

      perSystem = { pkgs, system, ... }: {
        _module.args.pkgs = import inputs.nixpkgs {
          inherit system;
          overlays = [ inputs.rust-overlay.overlays.default ];
        };

        devShells = {
          default = pkgs.mkShell.override { stdenv = pkgs.clangMultiStdenv; } rec {
            nativeBuildInputs = with pkgs; [ pkg-config wrapGAppsHook ];
            buildInputs = with pkgs; [
              rust-bin.stable.latest.default
              cargo-watch
              alsa-lib udev
              glib gtk3 atk
              libxkbcommon
              vulkan-loader
            ];

            LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath buildInputs;
            shellHook = ''
              export XDG_DATA_DIRS=$GSETTINGS_SCHEMAS_PATH
            '';
          };
        };

        formatter = pkgs.nixpkgs-fmt;
      };
    };
}