Set property on all existing elements in a listing

[cloudflight-cweiss]

Maybe it is already mentionend in the language reference somewhere but I could not find it so here it goes...

I have a setup where I preset a number of "default tenants" which are used on mostly all deployed instances.
Basic template is this:

module listmodify

tenants: Listing<Tenant>

class Tenant {
  tenant: String
  login: Login
}

class Login {
  username: String
  password: String
}

Now i have a file for defining the default tenants:

amends "listmodify-template.pkl"

tenants {
  new {
    tenant = "AT"
  }
  new {
    tenant = "DE"
  }
  new {
    tenant = "CZ"
  }
}

And now i want to generate a fully filled out config for my local environment for example:

amends "default-tenants.pkl"

local defaultLogin = new Login {
  username = "admin"
  password = "admin"
}

// TODO: Set login property on all existing tenant elements
tenants {

}

How can I set the login property on all existing elements in the "tenants" listing?

[bioball]

Use a member predicate, where the predicate is simply true:

amends "default-tenants.pkl"

local defaultLogin = new Login {
  username = "admin"
  password = "admin"
}

tenants {
  [[true]] {
    login = defaultLogin
  }
}

[cloudflight-cweiss]

Ah thanks.....I was trying to use member predicates as the solution but did not think of just using true as predicate to select all members :)