How to add XML namespaces

[citizenrich]

Hi folks, I'd like to add an XML namespace to the pkl file. Here's an example XML file.

<?xml version="1.0" encoding="UTF-8"?>
<testsuite id="Fun_Example" xmlns="http://www.gitb.com/tdl/v1/" xmlns:gitb="http://www.gitb.com/core/v1/">
</testsuite>

How would I accomplish that?

[bioball]

Typically, you'd do this by defining converters in your renderer. For example:

import "pkl:xml"

class TestSuite {
  id: String
}

testSuite: TestSuite = new {
  id = "Fun_Example"
}

output {
  value = testSuite
  renderer = new xml.Renderer {
    converters {
      [TestSuite] = (it) -> (xml.Element("testsuite")) {
        attributes {
          ["id"] = it.id
          ["xmlns"] = "http://www.gitb.com/tdl/v1/"
          ["xmlns:gitb"] = "http://www.gitb.com/core/v1/"
        }
      }
    }
  }
}

If you need to apply this namespace to many different types, you can share converter logic by introducing a mixin:

local withGitbNs: Mixin = new {
  attributes {
    ["xmlns"] = "http://www.gitb.com/tdl/v1/"
    ["xmlns:gitb"] = "http://www.gitb.com/core/v1/"
  }
}

output {
  value = testSuite
  renderer = new xml.Renderer {
    converters {
      [TestSuite] = (it) -> (xml.Element("testsuite")) {
        attributes {
          ["id"] = it.id
        }
      } |> withGitbNs
    }
  }
}