build.gradle

/*
 * This build file was generated by the Gradle 'init' task.
 *
 * This generated file contains a sample Java project to get you started.
 * For more details take a look at the Java Quickstart chapter in the Gradle
 * user guide available at https://docs.gradle.org/3.3/userguide/tutorial_java_projects.html
 */

// Apply the java plugin to add support for Java
apply plugin: 'java'
apply plugin: 'application'
apply plugin: 'eclipse'

// "gradle run" should execute the server with the configuration from "config.json"

mainClassName = "uk.ac.cam.cl.historyphone.Server"
run {
    args = ["config.json"]
}

// tasks to build the runtime and test databases from SQL scripts

configurations {
    createdb
}

task makeDatabase(type: JavaExec) {
     main = "org.hsqldb.cmdline.SqlTool"
     args = ["--inlineRC=url=jdbc:hsqldb:file:db/data,user=sa,password=", "src/main/sql/makedb.sql"]
     classpath configurations.createdb

     inputs.files "src/main/sql/makedb.sql"
     outputs.dir "db"
}
build.dependsOn makeDatabase

task makeTestDatabase(type: JavaExec) {
     main = "org.hsqldb.cmdline.SqlTool"
     args = ["--inlineRC=url=jdbc:hsqldb:file:${buildDir}/test/db/testdb,user=sa,password=", "src/test/sql/testdb.sql"]
     classpath configurations.createdb

     inputs.files "src/test/sql/testdb.sql"
     outputs.dir "${buildDir}/test/db"
}
test.dependsOn makeTestDatabase

// In this section you declare where to find the dependencies of your project
repositories {
    // Use jcenter for resolving your dependencies.
    // You can declare any Maven/Ivy/file repository here.
    jcenter()
}

dependencies {
    compile 'com.google.guava:guava:20.0' 
    compile group: 'org.glassfish', name: 'javax.json', version: '1.0.4'
    compile group: 'org.hsqldb', name: 'hsqldb', version: '2.3.4'

    createdb 'org.hsqldb:sqltool:2.3.4'
    createdb group: 'org.hsqldb', name: 'hsqldb', version: '2.3.4'

    // Use JUnit test framework
    testCompile 'junit:junit:4.12'

    testCompile group: 'org.glassfish', name: 'javax.json', version: '1.0.4'
}