build.gradle

group 'com.myunidays'
version '1.0-SNAPSHOT'

apply plugin: 'java-library'
apply plugin: 'maven-publish'

sourceCompatibility = 1.8

ext {
    repoPassword = project.hasProperty('repoPassword') ? project.getProperty('repoPassword') : ''
}

repositories {
    mavenCentral()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.12'
    testCompile group: 'org.mockito', name: 'mockito-core', version: '2.+'
    compile group: 'commons-codec', name: 'commons-codec', version: '1.11'
    compile group: 'org.apache.httpcomponents', name: 'httpasyncclient', version: '4.1.4'
}

task sourceJar(type: Jar) {
    from sourceSets.main.allJava
    classifier "sources"
}

task javadocJar(type: Jar) {
    from javadoc
    classifier = 'javadoc'
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java
            artifact sourceJar
            artifact javadocJar
            pom {
                name = "UNiDAYS Tracking API client"
                description = "UNiDAYS Tracking API client"

                licenses {
                    license {
                        name = "MIT"
                        url = "https://github.com/MyUNiDAYS/unidays-java/blob/master/LICENSE"
                    }
                }

                developers {
                    developer {
                        name = 'Unidays Developer'
                        email = 'dev.api@myunidays.com'
                    }
                }

                scm {
                    url = "https://github.com/MyUNiDAYS/unidays-java"
                    connection = 'scm:git:https://github.com/MyUNiDAYS/unidays-java.git'
                }
            }
        }
    }
    repositories {
        maven {
            def releasesRepoUrl = 'https://oss.sonatype.org/content/repositories/releases/'
            def snapshotsRepoUrl = 'https://oss.sonatype.org/content/repositories/snapshots/'
            url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
            credentials {
                username 'mg67Hpyo'
                password project.repoPassword
            }
        }
    }
}