build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'

version = "0.0.1"
group= "twinrealm" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = "TwinRealm"

minecraft {
    version = "1.7.10-10.13.0.1208"
    runDir = "eclipse"
}

jar {
        manifest {
        attributes 'FMLAT': 'twinrealm_at.cfg'
    }
}

// Provided - Start
// FML doesnt laod coremods and ATs from the classpath

apply plugin: 'idea'

configurations {
    provided
//    provided.extendsFrom(compile)
}

sourceSets {
    main { compileClasspath += [configurations.provided] }
}

idea {
    module {
        scopes.PROVIDED.plus += [configurations.provided]
    }
}

// Provided - Stop

dependencies {
    provided 'net.malisis.malisiscore:malisiscore:1.7.10-0.9.6:dev'
    provided 'ivorius.ivtoolkit:IvToolkit:1.0:dev'
    provided 'ivorius.reccomplex:RecurrentComplex:0.9.2.1:dev'
}

processResources
{
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        // replace version and mcversion
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
        
    // copy everything else, thats not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

// FML doesnt laod coremods and ATs from the classpath
task copyMods(type: Copy, dependsOn: "extractUserDev") {
    from { configurations.provided }
    include "**/*.jar"
    into file(minecraft.runDir + "/mods")
    mustRunAfter "deobfBinJar"
    mustRunAfter "repackMinecraft"
}
tasks.setupDevWorkspace.dependsOn copyMods
tasks.setupDecompWorkspace.dependsOn copyMods

sourceCompatibility = 1.7
targetCompatibility = 1.7