-
Notifications
You must be signed in to change notification settings - Fork 1
/
yos_utils.pas
256 lines (224 loc) · 6.45 KB
/
yos_utils.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
unit YOS_Utils;
{$mode objfpc}{$H+}
interface
uses
Windows, ctypes, Classes, SysUtils;
type
TGTA5Array = packed array of UINT32;
// Helpers
function CurrentTimeMs: int64;
procedure WriteCString(str: string; stream: TStream);
function ReadCString(stream: TStream): string;
function ReadRawData(filename: string): TStrings;
function GetDataItem(dataline: string; index: integer; separators: TSysCharSet): string;
function GetSaveFileName(sgi: integer): string;
function IsInCube(x, y, z, x1, y1, z1, x2, y2, z2: cfloat): boolean;
function IsInAngledCube(x, y, z, x1, y1, z1, x2, y2, z2, a: cfloat): boolean;
// GTA Array functions. Based on: https://gtaforums.com/topic/789788-function-args-to-pedget_ped_nearby_peds/
procedure GTA5_SetArrayLength(var arr: TGTA5Array; newLength: integer);
procedure GTA5_SetArrayItem(var arr: TGTA5Array; index: integer; newValue: UINT32);
function GTA5_GetArrayLength(var arr: TGTA5Array): integer;
function GTA5_GetArrayItem(var arr: TGTA5Array; index: integer): UINT32;
// Debug commands
procedure Log(category, str: string);
var
YosFormatSettings: TFormatSettings;
implementation
var
pFreq: LARGE_INTEGER;
bHasLogFile: boolean;
function CurrentTimeMs: int64;
var
currentTime: LARGE_INTEGER;
begin
QueryPerformanceCounter(@currentTime);
Result := System.trunc((1000 * currentTime.QuadPart) / pFreq.QuadPart);
end;
procedure WriteCString(str: string; stream: TStream);
var
i: integer;
begin
for i := 1 to Length(str) do
stream.WriteByte(ord(str[i]));
stream.WriteByte(0);
end;
function ReadCString(stream: TStream): string;
var
c: char;
begin
Result := '';
repeat
c := chr(stream.ReadByte);
if (c <> #0) then
Result := Result + c;
until c = #0;
end;
function ReadRawData(filename: string): TStrings;
var
f: System.Text;
l: string;
begin
Result := TStringList.Create;
System.Assign(f, filename);
{$I-}
System.Reset(f);
while not EOF(f) do
begin
readln(f, l);
l := Trim(l);
if (l <> '') and (l[1] <> ';') then
Result.Add(l);
end;
System.Close(f);
{$I+}
end;
function GetDataItem(dataline: string; index: integer; separators: TSysCharSet): string;
var
ci, i: integer;
s: string;
begin
ci := 0;
s := '';
for i := 1 to Length(dataline) do
begin
if (dataline[i] in separators) or (i = Length(dataline)) then
begin
if (ci >= index) then
begin
if not (dataline[i] in separators) then
s := s + dataline[i]; // The latest character of the line also counts, if not a separator!
exit(Trim(s)); // If we've found what do we need, just exit quickly!
end
else
begin
s := '';
inc(ci);
end;
end
else
s := s + dataline[i];
end;
// By this point, if we haven't found anything, we're already out of the game...
Result := '';
end;
function GetSaveFileName(sgi: integer): string;
begin
Result := Format('yos_data/saved_games/YOS_V_savefile_%d.sav', [sgi]);
end;
function IsInCube(x, y, z, x1, y1, z1, x2, y2, z2: cfloat): boolean;
var
f: cfloat;
begin
{Let us reorder coords, if they're ill-shaped}
if (x1 > x2) then
begin
f := x2;
x2 := x1;
x1 := f;
end;
if (y1 > y2) then
begin
f := y2;
y2 := y1;
y1 := f;
end;
if (z1 > z2) then
begin
f := z2;
z2 := z1;
z1 := f;
end;
{Calculate if inside the cube}
Result := (x >= x1) and (x <= x2) and (y >= y1) and (y <= y2) and (z >= z1) and (z <= z2);
end;
function IsInAngledCube(x, y, z, x1, y1, z1, x2, y2, z2, a: cfloat): boolean;
var
cx, cy, tx, ty, tx1, ty1, tx2, ty2, rx, ry, rx1, ry1, rx2, ry2, cosa, sina: cfloat;
begin
// Center of the rectangle
cx := (x1 + x2) / 2;
cy := (y1 + y2) / 2;
// Translated rectangle coordinates
tx := x - cx;
ty := y - cy;
tx1 := x1 - cx;
ty1 := y1 - cy;
tx2 := x2 - cx;
ty2 := y2 - cy;
// Rectangle angle (rad)
cosa := cos(a * (pi / 180.0));
sina := sin(a * (pi / 180.0));
// Rotated rectangle points
rx := (tx * cosa) + (ty * sina);
ry := (-tx * sina) + (ty * cosa);
rx1 := (tx1 * cosa) + (ty1 * sina);
ry1 := (-tx1 * sina) + (ty1 * cosa);
rx2 := (tx2 * cosa) + (ty2 * sina);
ry2 := (-tx2 * sina) + (ty2 * cosa);
// Check, if point is in cube
Result := IsInCube(rx, ry, z, rx1, ry1, z1, rx2, ry2, z2);
end;
procedure GTA5_SetArrayLength(var arr: TGTA5Array; newLength: integer);
var
oldMaxIndex, i: integer;
ci: cint;
begin
if (newLength < 0) then
newLength := 0;
oldMaxIndex := High(arr);
// Set GTA5 array length
SetLength(arr, 2 + (2 * newLength));
ci := cint(newLength);
arr[0] := PUINT32(@ci)^;
// Fill newly added space with zeroes
if (High(arr) > oldMaxIndex) then
for i := oldMaxIndex + 1 to High(arr) do
begin
if (i > 1) then // First two items are taboo!
arr[i] := 0;
end;
end;
procedure GTA5_SetArrayItem(var arr: TGTA5Array; index: integer; newValue: UINT32);
begin
arr[2 + (index * 2)] := newValue;
end;
function GTA5_GetArrayLength(var arr: TGTA5Array): integer;
var
len: UINT32;
begin
len := arr[0];
Result := integer(pcint(@len)^);
end;
function GTA5_GetArrayItem(var arr: TGTA5Array; index: integer): UINT32;
begin
Result := arr[2 + (index * 2)];
end;
procedure Log(category, str: string);
const
logFileName: string = 'yos_debug.log';
var
_time: SYSTEMTIME;
f: System.Text;
begin
GetLocalTime(_time);
System.Assign(f, logFileName);
{$I-}
if bHasLogFile and FileExists(logFileName) then
Append(f)
else
begin
bHasLogFile := true;
Rewrite(f);
end;
writeln(f, Format('%.2d/%.2d/%.4d %.2d:%.2d:%.2d.%.3d - [%s]: %s', [_time.Day, _time.Month, _time.Year, _time.Hour, _time.Minute, _time.Second, _time.Millisecond, category, str]));
System.Close(f);
{$I+}
end;
initialization
QueryPerformanceFrequency(@pFreq);
bHasLogFile := false;
YosFormatSettings := DefaultFormatSettings;
YosFormatSettings.DecimalSeparator := '.';
YosFormatSettings.ShortDateFormat := 'DD MMM YYYY';
YosFormatSettings.LongTimeFormat := 'hh:nn:ss';
end.