-
Notifications
You must be signed in to change notification settings - Fork 1
/
shr_flux_mod.F90
1463 lines (1220 loc) · 61.5 KB
/
shr_flux_mod.F90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!===============================================================================
! SVN $Id: shr_flux_mod.F90 70843 2015-05-26 22:42:14Z tcraig $
! SVN $URL: https://svn-ccsm-models.cgd.ucar.edu/csm_share/branches/aofluxd/shr/shr_flux_mod.F90 $
!===============================================================================
!BOP ===========================================================================
!
! !MODULE: flux_mod -- CCSM shared flux calculations.
!
! !DESCRIPTION:
!
! CCSM shared flux calculations.
!
! !REVISION HISTORY:
! 2006-Nov-07 - B. Kauffman - first version, code taken/migrated from cpl6
!
! !INTERFACE: ------------------------------------------------------------------
module shr_flux_mod
! !USES:
use shr_kind_mod ! shared kinds
use shr_const_mod ! shared constants
use shr_sys_mod ! shared system routines
use shr_log_mod, only: s_loglev => shr_log_Level
use shr_log_mod, only: s_logunit => shr_log_Unit
implicit none
private ! default private
! !PUBLIC TYPES:
! none
! !PUBLIC MEMBER FUNCTIONS:
public :: shr_flux_atmOcn ! computes atm/ocn fluxes
public :: shr_flux_atmOcn_diurnal ! computes atm/ocn fluxes with diurnal cycle
public :: shr_flux_atmIce ! computes atm/ice fluxes
public :: shr_flux_MOstability ! boundary layer stability scales/functions
public :: shr_flux_adjust_constants ! adjust constant values used in flux calculations.
! !PUBLIC DATA MEMBERS:
integer(SHR_KIND_IN),parameter,public :: shr_flux_MOwScales = 1 ! w scales option
integer(SHR_KIND_IN),parameter,public :: shr_flux_MOfunctions = 2 ! functions option
real (SHR_KIND_R8),parameter,public :: shr_flux_MOgammaM = 3.59_SHR_KIND_R8
real (SHR_KIND_R8),parameter,public :: shr_flux_MOgammaS = 7.86_SHR_KIND_R8
!EOP
!--- rename kinds for local readability only ---
integer,parameter :: R8 = SHR_KIND_R8 ! 8 byte real
integer,parameter :: IN = SHR_KIND_IN ! native/default integer
integer,parameter :: debug = 0 ! internal debug level
! The follow variables are not declared as parameters so that they can be
! adjusted to support aquaplanet and potentially other simple model modes.
! The shr_flux_adjust_constants subroutine is called to set the desired
! values. The default values are from shr_const_mod. Currently they are
! only used by the shr_flux_atmocn and shr_flux_atmice routines.
real(R8) :: loc_zvir = shr_const_zvir
real(R8) :: loc_cpdair = shr_const_cpdair
real(R8) :: loc_cpvir = shr_const_cpvir
real(R8) :: loc_karman = shr_const_karman
real(R8) :: loc_g = shr_const_g
real(R8) :: loc_latvap = shr_const_latvap
real(R8) :: loc_latice = shr_const_latice
real(R8) :: loc_stebol = shr_const_stebol
!===============================================================================
contains
!===============================================================================
!===============================================================================
subroutine shr_flux_adjust_constants( &
zvir, cpair, cpvir, karman, gravit, &
latvap, latice, stebol)
! Adjust local constants. Used to support simple models.
real(R8), optional, intent(in) :: zvir
real(R8), optional, intent(in) :: cpair
real(R8), optional, intent(in) :: cpvir
real(R8), optional, intent(in) :: karman
real(R8), optional, intent(in) :: gravit
real(R8), optional, intent(in) :: latvap
real(R8), optional, intent(in) :: latice
real(R8), optional, intent(in) :: stebol
!----------------------------------------------------------------------------
if (present(zvir)) loc_zvir = zvir
if (present(cpair)) loc_cpdair = cpair
if (present(cpvir)) loc_cpvir = cpvir
if (present(karman)) loc_karman = karman
if (present(gravit)) loc_g = gravit
if (present(latvap)) loc_latvap = latvap
if (present(latice)) loc_latice = latice
if (present(stebol)) loc_stebol = stebol
end subroutine shr_flux_adjust_constants
!===============================================================================
! !BOP =========================================================================
!
! !IROUTINE: shr_flux_atmOcn -- internal atm/ocn flux calculation
!
! !DESCRIPTION:
!
! Internal atm/ocn flux calculation
!
! !REVISION HISTORY:
! 2002-Jun-10 - B. Kauffman - code migrated from cpl5 to cpl6
! 2003-Apr-02 - B. Kauffman - taux & tauy now utilize ocn velocity
! 2003-Apr-02 - B. Kauffman - tref,qref,duu10n mods as per Bill Large
! 2006-Nov-07 - B. Kauffman - code migrated from cpl6 to share
!
! !INTERFACE: ------------------------------------------------------------------
SUBROUTINE shr_flux_atmOcn(nMax ,zbot ,ubot ,vbot ,thbot , &
& qbot ,rbot ,tbot ,us ,vs , &
& ts ,mask ,sen ,lat ,lwup , &
& evap ,taux ,tauy ,tref ,qref , &
& duu10n, ustar_sv ,re_sv ,ssq_sv, &
& missval )
! !USES:
implicit none
! !INPUT/OUTPUT PARAMETERS:
!--- input arguments --------------------------------
integer(IN),intent(in) :: nMax ! data vector length
integer(IN),intent(in) :: mask (nMax) ! ocn domain mask 0 <=> out of domain
real(R8) ,intent(in) :: zbot (nMax) ! atm level height (m)
real(R8) ,intent(in) :: ubot (nMax) ! atm u wind (m/s)
real(R8) ,intent(in) :: vbot (nMax) ! atm v wind (m/s)
real(R8) ,intent(in) :: thbot(nMax) ! atm potential T (K)
real(R8) ,intent(in) :: qbot (nMax) ! atm specific humidity (kg/kg)
real(R8) ,intent(in) :: rbot (nMax) ! atm air density (kg/m^3)
real(R8) ,intent(in) :: tbot (nMax) ! atm T (K)
real(R8) ,intent(in) :: us (nMax) ! ocn u-velocity (m/s)
real(R8) ,intent(in) :: vs (nMax) ! ocn v-velocity (m/s)
real(R8) ,intent(in) :: ts (nMax) ! ocn temperature (K)
!--- output arguments -------------------------------
real(R8),intent(out) :: sen (nMax) ! heat flux: sensible (W/m^2)
real(R8),intent(out) :: lat (nMax) ! heat flux: latent (W/m^2)
real(R8),intent(out) :: lwup (nMax) ! heat flux: lw upward (W/m^2)
real(R8),intent(out) :: evap (nMax) ! water flux: evap ((kg/s)/m^2)
real(R8),intent(out) :: taux (nMax) ! surface stress, zonal (N)
real(R8),intent(out) :: tauy (nMax) ! surface stress, maridional (N)
real(R8),intent(out) :: tref (nMax) ! diag: 2m ref height T (K)
real(R8),intent(out) :: qref (nMax) ! diag: 2m ref humidity (kg/kg)
real(R8),intent(out) :: duu10n(nMax) ! diag: 10m wind speed squared (m/s)^2
real(R8),intent(out),optional :: ustar_sv(nMax) ! diag: ustar
real(R8),intent(out),optional :: re_sv (nMax) ! diag: sqrt of exchange coefficient (water)
real(R8),intent(out),optional :: ssq_sv (nMax) ! diag: sea surface humidity (kg/kg)
real(R8),intent(in) ,optional :: missval ! masked value
! !EOP
!--- local constants --------------------------------
real(R8),parameter :: umin = 0.5_R8 ! minimum wind speed (m/s)
real(R8),parameter :: zref = 10.0_R8 ! reference height (m)
real(R8),parameter :: ztref = 2.0_R8 ! reference height for air T (m)
!--- local variables --------------------------------
integer(IN) :: n ! vector loop index
real(R8) :: vmag ! surface wind magnitude (m/s)
real(R8) :: thvbot ! virtual temperature (K)
real(R8) :: ssq ! sea surface humidity (kg/kg)
real(R8) :: delt ! potential T difference (K)
real(R8) :: delq ! humidity difference (kg/kg)
real(R8) :: stable ! stability factor
real(R8) :: rdn ! sqrt of neutral exchange coeff (momentum)
real(R8) :: rhn ! sqrt of neutral exchange coeff (heat)
real(R8) :: ren ! sqrt of neutral exchange coeff (water)
real(R8) :: rd ! sqrt of exchange coefficient (momentum)
real(R8) :: rh ! sqrt of exchange coefficient (heat)
real(R8) :: re ! sqrt of exchange coefficient (water)
real(R8) :: ustar ! ustar
real(R8) :: qstar ! qstar
real(R8) :: tstar ! tstar
real(R8) :: hol ! H (at zbot) over L
real(R8) :: xsq ! ?
real(R8) :: xqq ! ?
real(R8) :: psimh ! stability function at zbot (momentum)
real(R8) :: psixh ! stability function at zbot (heat and water)
real(R8) :: psix2 ! stability function at ztref reference height
real(R8) :: alz ! ln(zbot/zref)
real(R8) :: al2 ! ln(zref/ztref)
real(R8) :: u10n ! 10m neutral wind
real(R8) :: tau ! stress at zbot
real(R8) :: cp ! specific heat of moist air
real(R8) :: bn ! exchange coef funct for interpolation
real(R8) :: bh ! exchange coef funct for interpolation
real(R8) :: fac ! vertical interpolation factor
real(R8) :: spval ! local missing value
!--- local functions --------------------------------
real(R8) :: qsat ! function: the saturation humididty of air (kg/m^3)
real(R8) :: cdn ! function: neutral drag coeff at 10m
real(R8) :: psimhu ! function: unstable part of psimh
real(R8) :: psixhu ! function: unstable part of psimx
real(R8) :: Umps ! dummy arg ~ wind velocity (m/s)
real(R8) :: Tk ! dummy arg ~ temperature (K)
real(R8) :: xd ! dummy arg ~ ?
qsat(Tk) = 640380.0_R8 / exp(5107.4_R8/Tk)
cdn(Umps) = 0.0027_R8 / Umps + 0.000142_R8 + 0.0000764_R8 * Umps
psimhu(xd) = log((1.0_R8+xd*(2.0_R8+xd))*(1.0_R8+xd*xd)/8.0_R8) - 2.0_R8*atan(xd) + 1.571_R8
psixhu(xd) = 2.0_R8 * log((1.0_R8 + xd*xd)/2.0_R8)
!--- formats ----------------------------------------
character(*),parameter :: subName = '(shr_flux_atmOcn) '
character(*),parameter :: F00 = "('(shr_flux_atmOcn) ',4a)"
!-------------------------------------------------------------------------------
! PURPOSE:
! computes atm/ocn surface fluxes
!
! NOTES:
! o all fluxes are positive downward
! o net heat flux = net sw + lw up + lw down + sen + lat
! o here, tstar = <WT>/U*, and qstar = <WQ>/U*.
! o wind speeds should all be above a minimum speed (eg. 1.0 m/s)
!
! ASSUMPTIONS:
! o Neutral 10m drag coeff: cdn = .0027/U10 + .000142 + .0000764 U10
! o Neutral 10m stanton number: ctn = .0327 sqrt(cdn), unstable
! ctn = .0180 sqrt(cdn), stable
! o Neutral 10m dalton number: cen = .0346 sqrt(cdn)
! o The saturation humidity of air at T(K): qsat(T) (kg/m^3)
!-------------------------------------------------------------------------------
if (debug > 0 .and. s_loglev > 0) write(s_logunit,F00) "enter"
if (present(missval)) then
spval = missval
else
spval = shr_const_spval
endif
al2 = log(zref/ztref)
DO n=1,nMax
if (mask(n) /= 0) then
!--- compute some needed quantities ---
vmag = max(umin, sqrt( (ubot(n)-us(n))**2 + (vbot(n)-vs(n))**2) )
thvbot = thbot(n) * (1.0_R8 + loc_zvir * qbot(n)) ! virtual temp (K)
ssq = 0.98_R8 * qsat(ts(n)) / rbot(n) ! sea surf hum (kg/kg)
delt = thbot(n) - ts(n) ! pot temp diff (K)
delq = qbot(n) - ssq ! spec hum dif (kg/kg)
alz = log(zbot(n)/zref)
cp = loc_cpdair*(1.0_R8 + loc_cpvir*ssq)
!------------------------------------------------------------
! first estimate of Z/L and ustar, tstar and qstar
!------------------------------------------------------------
!--- neutral coefficients, z/L = 0.0 ---
stable = 0.5_R8 + sign(0.5_R8 , delt)
rdn = sqrt(cdn(vmag))
rhn = (1.0_R8-stable) * 0.0327_R8 + stable * 0.018_R8
ren = 0.0346_R8
!--- ustar, tstar, qstar ---
ustar = rdn * vmag
tstar = rhn * delt
qstar = ren * delq
!--- compute stability & evaluate all stability functions ---
hol = loc_karman*loc_g*zbot(n)* &
(tstar/thbot(n)+qstar/(1.0_R8/loc_zvir+qbot(n)))/ustar**2
hol = sign( min(abs(hol),10.0_R8), hol )
stable = 0.5_R8 + sign(0.5_R8 , hol)
xsq = max(sqrt(abs(1.0_R8 - 16.0_R8*hol)) , 1.0_R8)
xqq = sqrt(xsq)
psimh = -5.0_R8*hol*stable + (1.0_R8-stable)*psimhu(xqq)
psixh = -5.0_R8*hol*stable + (1.0_R8-stable)*psixhu(xqq)
!--- shift wind speed using old coefficient ---
rd = rdn / (1.0_R8 + rdn/loc_karman*(alz-psimh))
u10n = vmag * rd / rdn
!--- update transfer coeffs at 10m and neutral stability ---
rdn = sqrt(cdn(u10n))
ren = 0.0346_R8
rhn = (1.0_R8-stable)*0.0327_R8 + stable * 0.018_R8
!--- shift all coeffs to measurement height and stability ---
rd = rdn / (1.0_R8 + rdn/loc_karman*(alz-psimh))
rh = rhn / (1.0_R8 + rhn/loc_karman*(alz-psixh))
re = ren / (1.0_R8 + ren/loc_karman*(alz-psixh))
!--- update ustar, tstar, qstar using updated, shifted coeffs --
ustar = rd * vmag
tstar = rh * delt
qstar = re * delq
!------------------------------------------------------------
! iterate to converge on Z/L, ustar, tstar and qstar
!------------------------------------------------------------
!--- compute stability & evaluate all stability functions ---
hol = loc_karman*loc_g*zbot(n)* &
(tstar/thbot(n)+qstar/(1.0_R8/loc_zvir+qbot(n)))/ustar**2
hol = sign( min(abs(hol),10.0_R8), hol )
stable = 0.5_R8 + sign(0.5_R8 , hol)
xsq = max(sqrt(abs(1.0_R8 - 16.0_R8*hol)) , 1.0_R8)
xqq = sqrt(xsq)
psimh = -5.0_R8*hol*stable + (1.0_R8-stable)*psimhu(xqq)
psixh = -5.0_R8*hol*stable + (1.0_R8-stable)*psixhu(xqq)
!--- shift wind speed using old coeffs ---
rd = rdn / (1.0_R8 + rdn/loc_karman*(alz-psimh))
u10n = vmag * rd/rdn
!--- update transfer coeffs at 10m and neutral stability ---
rdn = sqrt(cdn(u10n))
ren = 0.0346_R8
rhn = (1.0_R8 - stable)*0.0327_R8 + stable * 0.018_R8
!--- shift all coeffs to measurement height and stability ---
rd = rdn / (1.0_R8 + rdn/loc_karman*(alz-psimh))
rh = rhn / (1.0_R8 + rhn/loc_karman*(alz-psixh))
re = ren / (1.0_R8 + ren/loc_karman*(alz-psixh))
!--- update ustar, tstar, qstar using updated, shifted coeffs ---
ustar = rd * vmag
tstar = rh * delt
qstar = re * delq
!------------------------------------------------------------
! compute the fluxes
!------------------------------------------------------------
tau = rbot(n) * ustar * ustar
!--- momentum flux ---
taux(n) = tau * (ubot(n)-us(n)) / vmag
tauy(n) = tau * (vbot(n)-vs(n)) / vmag
!--- heat flux ---
sen (n) = cp * tau * tstar / ustar
lat (n) = loc_latvap * tau * qstar / ustar
lwup(n) = -loc_stebol * ts(n)**4
!--- water flux ---
evap(n) = lat(n)/loc_latvap
!------------------------------------------------------------
! compute diagnositcs: 2m ref T & Q, 10m wind speed squared
!------------------------------------------------------------
hol = hol*ztref/zbot(n)
xsq = max( 1.0_R8, sqrt(abs(1.0_R8-16.0_R8*hol)) )
xqq = sqrt(xsq)
psix2 = -5.0_R8*hol*stable + (1.0_R8-stable)*psixhu(xqq)
fac = (rh/loc_karman) * (alz + al2 - psixh + psix2 )
tref(n) = thbot(n) - delt*fac
tref(n) = tref(n) - 0.01_R8*ztref ! pot temp to temp correction
fac = (re/loc_karman) * (alz + al2 - psixh + psix2 )
qref(n) = qbot(n) - delq*fac
duu10n(n) = u10n*u10n ! 10m wind speed squared
!------------------------------------------------------------
! optional diagnostics, needed for water tracer fluxes (dcn)
!------------------------------------------------------------
if (present(ustar_sv)) ustar_sv(n) = ustar
if (present(re_sv )) re_sv(n) = re
if (present(ssq_sv )) ssq_sv(n) = ssq
else
!------------------------------------------------------------
! no valid data here -- out of domain
!------------------------------------------------------------
sen (n) = spval ! sensible heat flux (W/m^2)
lat (n) = spval ! latent heat flux (W/m^2)
lwup (n) = spval ! long-wave upward heat flux (W/m^2)
evap (n) = spval ! evaporative water flux ((kg/s)/m^2)
taux (n) = spval ! x surface stress (N)
tauy (n) = spval ! y surface stress (N)
tref (n) = spval ! 2m reference height temperature (K)
qref (n) = spval ! 2m reference height humidity (kg/kg)
duu10n(n) = spval ! 10m wind speed squared (m/s)^2
if (present(ustar_sv)) ustar_sv(n) = spval
if (present(re_sv )) re_sv (n) = spval
if (present(ssq_sv )) ssq_sv (n) = spval
endif
ENDDO
END subroutine shr_flux_atmOcn
!===============================================================================
! !BOP =========================================================================
!
! !IROUTINE: shr_flux_atmOcn_diurnal -- internal atm/ocn flux calculation
!
! !DESCRIPTION:
!
! Internal atm/ocn flux calculation
!
! !REVISION HISTORY:
! 2002-Jun-10 - B. Kauffman - code migrated from cpl5 to cpl6
! 2003-Apr-02 - B. Kauffman - taux & tauy now utilize ocn velocity
! 2003-Apr-02 - B. Kauffman - tref,qref,duu10n mods as per Bill Large
! 2006-Nov-07 - B. Kauffman - code migrated from cpl6 to share
!
! !INTERFACE: ------------------------------------------------------------------
SUBROUTINE shr_flux_atmOcn_diurnal &
(nMax ,zbot ,ubot ,vbot ,thbot , &
qbot ,rbot ,tbot ,us ,vs , &
ts ,mask ,sen ,lat ,lwup , &
evap ,taux ,tauy ,tref ,qref , &
uGust, lwdn , swdn , swup, prec , &
swpen, ocnsal, ocn_prognostic, flux_diurnal, &
latt, long , warm , salt , speed, regime, &
warmMax, windMax, qSolAvg, windAvg, &
warmMaxInc, windMaxInc, qSolInc, windInc, nInc, &
tBulk, tSkin, tSkin_day, tSkin_night, &
cSkin, cSkin_night, secs ,dt, &
duu10n, ustar_sv ,re_sv ,ssq_sv, &
missval, cold_start )
! !USES:
implicit none
! !INPUT/OUTPUT PARAMETERS:
!--- input arguments --------------------------------
integer(IN),intent(in) :: nMax ! data vector length
integer(IN),intent(in) :: mask (nMax) ! ocn domain mask 0 <=> out of domain
real(R8) ,intent(in) :: zbot (nMax) ! atm level height (m)
real(R8) ,intent(in) :: ubot (nMax) ! atm u wind (m/s)
real(R8) ,intent(in) :: vbot (nMax) ! atm v wind (m/s)
real(R8) ,intent(in) :: thbot(nMax) ! atm potential T (K)
real(R8) ,intent(in) :: qbot (nMax) ! atm specific humidity (kg/kg)
real(R8) ,intent(in) :: rbot (nMax) ! atm air density (kg/m^3)
real(R8) ,intent(in) :: tbot (nMax) ! atm T (K)
real(R8) ,intent(in) :: us (nMax) ! ocn u-velocity (m/s)
real(R8) ,intent(in) :: vs (nMax) ! ocn v-velocity (m/s)
real(R8) ,intent(in) :: ts (nMax) ! ocn temperature (K)
!--- new arguments -------------------------------
real(R8),intent(inout) :: swpen (nMax) ! NEW
real(R8),intent(inout) :: ocnsal(nMax) ! NEW (kg/kg)
logical ,intent(in) :: ocn_prognostic ! NEW
logical ,intent(in) :: flux_diurnal ! NEW logical for diurnal on/off
real(R8),intent(in) :: uGust (nMax) ! NEW not used
real(R8),intent(in) :: lwdn (nMax) ! NEW
real(R8),intent(in) :: swdn (nMax) ! NEW
real(R8),intent(in) :: swup (nMax) ! NEW
real(R8),intent(in) :: prec (nMax) ! NEW
real(R8),intent(in) :: latt (nMax) ! NEW
real(R8),intent(in) :: long (nMax) ! NEW
real(R8),intent(inout) :: warm (nMax) ! NEW
real(R8),intent(inout) :: salt (nMax) ! NEW
real(R8),intent(inout) :: speed (nMax) ! NEW
real(R8),intent(inout) :: regime(nMax) ! NEW
real(R8),intent(out) :: warmMax(nMax) ! NEW
real(R8),intent(out) :: windMax(nMax) ! NEW
real(R8),intent(inout) :: qSolAvg(nMax) ! NEW
real(R8),intent(inout) :: windAvg(nMax) ! NEW
real(R8),intent(inout) :: warmMaxInc(nMax) ! NEW
real(R8),intent(inout) :: windMaxInc(nMax) ! NEW
real(R8),intent(inout) :: qSolInc(nMax) ! NEW
real(R8),intent(inout) :: windInc(nMax) ! NEW
real(R8),intent(inout) :: nInc(nMax) ! NEW
real(R8),intent(out) :: tBulk (nMax) ! NEW
real(R8),intent(out) :: tSkin (nMax) ! NEW
real(R8),intent(out) :: tSkin_day (nMax) ! NEW
real(R8),intent(out) :: tSkin_night (nMax) ! NEW
real(R8),intent(out) :: cSkin (nMax) ! NEW
real(R8),intent(out) :: cSkin_night (nMax) ! NEW
integer(IN),intent(in) :: secs ! NEW elsapsed seconds in day (GMT)
integer(IN),intent(in) :: dt ! NEW
logical ,intent(in) :: cold_start ! cold start flag
real(R8),intent(in) ,optional :: missval ! masked value
!--- output arguments -------------------------------
real(R8),intent(out) :: sen (nMax) ! heat flux: sensible (W/m^2)
real(R8),intent(out) :: lat (nMax) ! heat flux: latent (W/m^2)
real(R8),intent(out) :: lwup (nMax) ! heat flux: lw upward (W/m^2)
real(R8),intent(out) :: evap (nMax) ! water flux: evap ((kg/s)/m^2)
real(R8),intent(out) :: taux (nMax) ! surface stress, zonal (N)
real(R8),intent(out) :: tauy (nMax) ! surface stress, maridional (N)
real(R8),intent(out) :: tref (nMax) ! diag: 2m ref height T (K)
real(R8),intent(out) :: qref (nMax) ! diag: 2m ref humidity (kg/kg)
real(R8),intent(out) :: duu10n(nMax) ! diag: 10m wind speed squared (m/s)^2
real(R8),intent(out),optional :: ustar_sv(nMax) ! diag: ustar
real(R8),intent(out),optional :: re_sv (nMax) ! diag: sqrt of exchange coefficient (water)
real(R8),intent(out),optional :: ssq_sv (nMax) ! diag: sea surface humidity (kg/kg)
! !EOP
!--- local constants --------------------------------
real(R8),parameter :: umin = 0.5_R8 ! minimum wind speed (m/s)
real(R8),parameter :: zref = 10.0_R8 ! reference height (m)
real(R8),parameter :: ztref = 2.0_R8 ! reference height for air T (m)
integer(IN),parameter :: iMax = 3
real(R8),parameter :: lambdaC = 6.0_R8
real(R8),parameter :: lambdaL = 0.0_R8
real(R8),parameter :: doLMax = 1.0_R8
real(R8),parameter :: pwr = 0.2_R8
real(R8),parameter :: Rizero = 1.0_R8
real(R8),parameter :: NUzero = 40.0e-4_R8
real(R8),parameter :: Prandtl = 1.0_R8
real(R8),parameter :: kappa0 = 0.2e-4_R8
real(R8),parameter :: F0 = 0.5_R8
real(R8),parameter :: F1 = 0.15_R8
real(R8),parameter :: R1 = 10.0_R8
real(R8),parameter :: Ricr = 0.30_R8
real(R8),parameter :: tiny = 1.0e-12_R8
real(R8),parameter :: tiny2 = 1.0e-6_R8
real(R8),parameter :: pi = SHR_CONST_PI
!--- local variables --------------------------------
integer(IN) :: n ! vector loop index
integer(IN) :: i ! iteration loop index
integer(IN) :: lsecs ! local seconds elapsed
integer(IN) :: lonsecs ! incrememnt due to lon offset
real(R8) :: vmag ! surface wind magnitude (m/s)
real(R8) :: thvbot ! virtual temperature (K)
real(R8) :: ssq ! sea surface humidity (kg/kg)
real(R8) :: delt ! potential T difference (K)
real(R8) :: delq ! humidity difference (kg/kg)
real(R8) :: stable ! stability factor
real(R8) :: rdn ! sqrt of neutral exchange coeff (momentum)
real(R8) :: rhn ! sqrt of neutral exchange coeff (heat)
real(R8) :: ren ! sqrt of neutral exchange coeff (water)
real(R8) :: rd ! sqrt of exchange coefficient (momentum)
real(R8) :: rh ! sqrt of exchange coefficient (heat)
real(R8) :: re ! sqrt of exchange coefficient (water)
real(R8) :: ustar ! ustar
real(R8) :: qstar ! qstar
real(R8) :: tstar ! tstar
real(R8) :: hol ! H (at zbot) over L
real(R8) :: xsq ! ?
real(R8) :: xqq ! ?
real(R8) :: psimh ! stability function at zbot (momentum)
real(R8) :: psixh ! stability function at zbot (heat and water)
real(R8) :: psix2 ! stability function at ztref reference height
real(R8) :: alz ! ln(zbot/zref)
real(R8) :: al2 ! ln(zref/ztref)
real(R8) :: u10n ! 10m neutral wind
real(R8) :: tau ! stress at zbot
real(R8) :: cp ! specific heat of moist air
real(R8) :: bn ! exchange coef funct for interpolation
real(R8) :: bh ! exchange coef funct for interpolation
real(R8) :: fac ! vertical interpolation factor
real(R8) :: DTiter !
real(R8) :: DSiter !
real(R8) :: DViter !
real(R8) :: Dcool !
real(R8) :: Qdel ! net cool skin heating
real(R8) :: Hd ! net heating above -z=d
real(R8) :: Hb ! net kinematic heating above -z = delta
real(R8) :: lambdaV !
real(R8) :: Fd ! net fresh water forcing above -z=d
real(R8) :: ustarw ! surface wind forcing of layer above -z=d
real(R8) :: Qsol ! solar heat flux (W/m2)
real(R8) :: Qnsol ! non-solar heat flux (W/m2)
real(R8) :: fsine !
real(R8) :: SSS ! sea surface salinity
real(R8) :: alphaT !
real(R8) :: betaS !
real(R8) :: doL ! ocean forcing stablity parameter
real(R8) :: Rid ! Richardson number at depth d
real(R8) :: Ribulk ! Bulk Richardson number at depth d
real(R8) :: FofRi ! Richardon number dependent diffusivity
real(R8) :: Smult ! multiplicative term based on regime
real(R8) :: Sfact ! multiplicative term based on regime
real(R8) :: Kdiff ! diffusive term based on regime
real(R8) :: Kvisc ! viscosity term based on regime
real(R8) :: hsign !
real(R8) :: rhocn !
real(R8) :: rcpocn !
real(R8) :: Nreset ! value for multiplicative reset factor
real(R8) :: resec ! reset offset value in seconds
logical :: lmidnight
logical :: ltwopm
logical :: ltwoam
logical :: lnoon
logical :: lfullday
integer :: nsum
integer :: ier
real(R8) :: pexp ! eqn 19
real(R8) :: AMP ! eqn 18
real(R8) :: dif3
real(R8) :: phid
real(R8) :: spval
!--- local functions --------------------------------
real(R8) :: qsat ! function: the saturation humididty of air (kg/m^3)
real(R8) :: cdn ! function: neutral drag coeff at 10m
real(R8) :: psimhu ! function: unstable part of psimh
real(R8) :: psixhu ! function: unstable part of psimx
real(R8) :: Umps ! dummy arg ~ wind velocity (m/s)
real(R8) :: Tk ! dummy arg ~ temperature (K)
real(R8) :: xd ! dummy arg ~ ?
real(R8) :: molvisc ! molecular viscosity
real(R8) :: molPr ! molecular Prandtl number
qsat(Tk) = 640380.0_R8 / exp(5107.4_R8/Tk)
cdn(Umps) = 0.0027_R8 / Umps + 0.000142_R8 + 0.0000764_R8 * Umps
psimhu(xd) = log((1.0_R8+xd*(2.0_R8+xd))*(1.0_R8+xd*xd)/8.0_R8) - 2.0_R8*atan(xd) + 1.571_R8
psixhu(xd) = 2.0_R8 * log((1.0_R8 + xd*xd)/2.0_R8)
molvisc(Tk) = 1.623e-6_R8 * exp((-1.0_R8*(Tk-273.15_R8))/45.2_R8)
molPr(Tk) = 11.64_R8 * exp((-1.0_R8*(Tk-273.15_R8))/40.7_R8)
!--- formats ----------------------------------------
character(*),parameter :: subName = '(shr_flux_atmOcn_diurnal) '
character(*),parameter :: F00 = "('(shr_flux_atmOcn_diurnal) ',4a)"
!-------------------------------------------------------------------------------
! PURPOSE:
! computes atm/ocn surface fluxes
!
! NOTES:
! o all fluxes are positive downward
! o net heat flux = net sw + lw up + lw down + sen + lat
! o here, tstar = <WT>/U*, and qstar = <WQ>/U*.
! o wind speeds should all be above a minimum speed (eg. 1.0 m/s)
!
! ASSUMPTIONS:
! o Neutral 10m drag coeff: cdn = .0027/U10 + .000142 + .0000764 U10
! o Neutral 10m stanton number: ctn = .0327 sqrt(cdn), unstable
! ctn = .0180 sqrt(cdn), stable
! o Neutral 10m dalton number: cen = .0346 sqrt(cdn)
! o The saturation humidity of air at T(K): qsat(T) (kg/m^3)
!-------------------------------------------------------------------------------
if (debug > 0 .and. s_loglev > 0) write(s_logunit,F00) "enter"
! this is especially for flux_diurnal calculations
if (.not. flux_diurnal) then
write(s_logunit,F00) "ERROR: flux_diurnal must be true"
call shr_sys_abort(subName//"flux diurnal must be true")
endif
spval = shr_const_spval
al2 = log(zref/ztref)
if (flux_diurnal) then
! equations 18 and 19
AMP = 1.0_R8/F0-1.0_R8
pexp = log( (1.0_R8/F1-F0) / (1.0_R8-F0) ) / log(R1)
if (.not. ocn_prognostic) then
! Set swpen and ocean salinity from following analytic expressions
swpen(:) = 0.67_R8*(exp((-1._R8*shr_const_zsrflyr)/1.0_R8)) + &
0.33_R8*exp((-1._R8*shr_const_zsrflyr)/17.0_R8)
ocnsal(:) = shr_const_ocn_ref_sal/1000.0_R8
else
! use swpen and ocnsal from input argument
endif
if (cold_start) then
! if (s_loglev > 0) then
write(s_logunit,F00) "Initialize diurnal cycle fields"
! end if
warm (:) = 0.0_R8
salt (:) = 0.0_R8
speed (:) = 0.0_R8
regime (:) = 0.0_R8
qSolAvg (:) = 0.0_R8
windAvg (:) = 0.0_R8
warmMax (:) = 0.0_R8
windMax (:) = 0.0_R8
warmMaxInc (:) = 0.0_R8
windMaxInc (:) = 0.0_R8
qSolInc (:) = 0.0_R8
windInc (:) = 0.0_R8
nInc (:) = 0.0_R8
tSkin_day (:) = ts(:)
tSkin_night(:) = ts(:)
cSkin_night(:) = 0.0_R8
endif
end if
DO n=1,nMax
if (mask(n) /= 0) then
!--- compute some initial and useful flux quantities ---
vmag = max(umin, sqrt( (ubot(n)-us(n))**2 + (vbot(n)-vs(n))**2) )
alz = log(zbot(n)/zref)
hol = 0.0
psimh = 0.0
psixh = 0.0
rdn = sqrt(cdn(vmag))
if (flux_diurnal) then
tBulk(n) = ts(n)+warm(n) ! first guess for tBulk from read in ts,warm
tSkin(n) = tBulk(n)
Qsol = swdn(n) + swup(n)
SSS = 1000.0_R8*ocnsal(n)+salt(n)
lambdaV = lambdaC
alphaT = 0.000297_R8*(1.0_R8+0.0256_R8*(ts(n)-298.15_R8)+0.003_R8*(SSS - 35.0_R8))
betaS = 0.000756_R8*(1.0_R8-0.0016_R8*(ts(n)-298.15_R8))
rhocn = 1023.342_R8*(1.0_R8-0.000297_R8*(ts(n)-298.15_R8)+0.000756_R8 * (SSS - 35.0_R8))
rcpocn = rhocn * 3990.0_R8*(1.0_R8-0.0012_R8*(SSS - 35.0_R8))
Rid = shr_const_g * (alphaT*warm(n) - betaS*salt(n)) *pwr*shr_const_zsrflyr / &
( pwr*MAX(tiny,speed(n)) )**2
Ribulk = 0.0
!----------------------------------------------------------
! convert elapsed time from GMT to local &
! check elapsed time. reset warm if near lsecs = reset_sec
!----------------------------------------------------------
Nreset = 1.0_R8
resec = Nreset*dt
lonsecs = ceiling(long(n)/360.0_R8*86400.0)
lsecs = mod(secs + lonsecs,86400)
lmidnight = (lsecs >= 0 .and. lsecs < dt) ! 0 = midnight
ltwopm = (lsecs >= 48600 .and. lsecs < 48600+dt) ! 48600 = 1:30pm
ltwoam = (lsecs >= 5400 .and. lsecs < 5400 +dt) ! 5400 = 1:30am
lnoon = (lsecs >= 43200 .and. lsecs < 43200+dt) ! 43200 = noon
lfullday = (lsecs > 86400-dt .and. lsecs <= 86400)
nsum = nint(nInc(n))
if ( lmidnight ) then
Regime(n) = 1.0_R8 ! RESET DIURNAL
warm(n) = 0.0_R8
salt(n) = 0.0_R8
speed(n) = 0.0_R8
endif
else ! flux_diurnal
tBulk(n) = ts(n)
tSkin(n) = tBulk(n)
end if
thvbot = thbot(n) * (1.0_R8 + shr_const_zvir * qbot(n)) ! virtual temp (K)
ssq = 0.98_R8 * qsat(tBulk(n)) / rbot(n) ! sea surf hum (kg/kg)
delt = thbot(n) - tBulk(n) ! pot temp diff (K)
delq = qbot(n) - ssq ! spec hum dif (kg/kg)
cp = shr_const_cpdair*(1.0_R8 + shr_const_cpvir*ssq)
stable = 0.5_R8 + sign(0.5_R8 , delt)
!--- shift wind speed using old coefficient and stability function
rd = rdn / (1.0_R8 + rdn/shr_const_karman*(alz-psimh))
u10n = vmag * rd / rdn
!--- initial neutral transfer coeffs at 10m
rdn = sqrt(cdn(u10n))
rhn = (1.0_R8-stable) * 0.0327_R8 + stable * 0.018_R8
ren = 0.0346_R8
!--- initial ustar, tstar, qstar ---
ustar = rdn * vmag
tstar = rhn * delt
qstar = ren * delq
! --- iterate ---
DO i = 1, iMax ! iteration loop
!------------------------------------------------------------
! iterate to converge on FLUXES Z/L, ustar, tstar and qstar
! and on Rid in the DIURNAL CYCLE
!------------------------------------------------------------
if (flux_diurnal) then
Smult = 0.0_R8
Sfact = 0.0_R8
Kdiff = 0.0_R8
Kvisc = 0.0_R8
dif3 = 0.0_R8
ustarw = ustar*sqrt(rbot(n)/rhocn)
Qnsol = lwdn(n) - shr_const_stebol*(tSkin(n))**4 + &
rbot(n)*ustar*(cp*tstar + shr_const_latvap*qstar)
Hd = (Qnsol + Qsol*(1.0_R8-swpen(n)) ) / rcpocn
Fd = (prec(n) + rbot(n)*ustar*qstar ) * SSS / rhocn
!--- COOL SKIN EFFECT ---
Dcool = lambdaV*molvisc(tBulk(n)) / ustarw
Qdel = Qnsol + Qsol * &
(0.137_R8 + 11.0_R8*Dcool - 6.6e-5/Dcool *(1.0_R8 - exp((-1.0_R8*Dcool)/8.0e-4)))
Hb = (Qdel/rcpocn)+(Fd*betaS/alphaT)
Hb = min(Hb , 0.0_R8)
lambdaV = lambdaC*(1.0_R8 + ( (0.0_R8-Hb)*16.0_R8*molvisc(tBulk(n))* &
shr_const_g*alphaT*molPr(tBulk(n))**2/ustarw**4)**0.75)**(-1/3)
cSkin(n) = MIN(0.0_R8, lambdaV * molPr(tBulk(n)) * Qdel / ustarw / rcpocn )
!--- REGIME ---
doL = shr_const_zsrflyr*shr_const_karman*shr_const_g* &
(alphaT*Hd + betaS*Fd ) / ustarw**3
Rid = MAX(0.0_R8,Rid)
Smult = dt * (pwr+1.0_R8) / (shr_const_zsrflyr*pwr)
Sfact = dt * (pwr+1.0_R8) / (shr_const_zsrflyr)**2
FofRi = 1.0_R8/(1.0_R8 + AMP*(Rid/Rizero)**pexp)
if ( (doL.gt.0.0_R8) .and. (Qsol.gt.0.0) ) then
phid = MIN(1.0_R8 + 5.0_R8 * doL, 5.0_R8 + doL)
FofRi = 1.0_R8/(1.0_R8 + AMP*(Rid/Rizero)**pexp)
dif3 = (kappa0 + NUzero *FofRi)
if ((doL.le.lambdaL).and.(NINT(regime(n)).le.2)) then
regime(n) = 2.0_R8
Kdiff = shr_const_karman * ustarw * shr_const_zsrflyr / phid
Kvisc = Kdiff * (1.0_R8 - doL/lambdaL)**2 + &
dif3 * (doL/lambdaL)**2 * (3.0_R8 - 2.0_R8 * doL/lambdaL)
Kdiff = Kvisc
else
regime(n) = 3.0_R8
Kdiff = kappa0 + NUzero * FofRi
Kvisc = Prandtl* kappa0 + NUzero * FofRi
endif
else
if (regime(n).eq.1.0_R8) then
Smult = 0.0_R8
else
if (Ribulk .gt. Ricr) then
regime(n) = 3.0_R8
Kdiff = kappa0 + NUzero * FofRi
Kvisc = Prandtl* kappa0 + NUzero * FofRi
else
regime(n) = 4.0_R8
Kdiff = shr_const_karman*ustarw*shr_const_zsrflyr *(1.0_R8-7.0_R8*doL)**(1/3)
Kvisc = Kdiff
endif
endif
endif
!--- IMPLICIT INTEGRATION ---
DTiter = (warm(n) +(Smult*Hd)) /(1.+ Sfact*Kdiff)
DSiter = (salt(n) -(Smult*Fd)) /(1.+ Sfact*Kdiff)
DViter = (speed(n) +(Smult*ustarw*ustarw)) /(1.+ Sfact*Kvisc)
DTiter = MAX( 0.0_R8, DTiter)
DViter = MAX( 0.0_R8, DViter)
Rid =(shr_const_g*(alphaT*DTiter-betaS*DSiter)*pwr*shr_const_zsrflyr) / &
(pwr*MAX(tiny,DViter))**2
Ribulk = Rid * pwr
Ribulk = 0.0_R8
tBulk(n) = ts(n) + DTiter
tSkin(n) = tBulk(n) + cskin(n)
!--need to update ssq,delt,delq as function of tBulk ----
ssq = 0.98_R8 * qsat(tBulk(n)) / rbot(n) ! sea surf hum (kg/kg)
delt = thbot(n) - tBulk(n) ! pot temp diff (K)
delq = qbot(n) - ssq ! spec hum dif (kg/kg)
else ! not flux_diurnal
!--- if control case, regime should be 0
regime(n) = 0.0_R8
Smult = 0.0_R8
Kdiff = 0.0_R8
Kvisc = 0.0_R8
warm(n) = 0.0_R8
salt(n) = 0.0_R8
speed(n) = 0.0_R8
cSkin(n) = 0.0_R8
endif
!--- UPDATE FLUX ITERATION ---
!--- compute stability & evaluate all stability functions ---
hol = shr_const_karman*shr_const_g*zbot(n)* &
(tstar/thbot(n)+qstar/(1.0_R8/shr_const_zvir+qbot(n)))/ustar**2
hol = sign( min(abs(hol),10.0_R8), hol )
stable = 0.5_R8 + sign(0.5_R8 , hol)
xsq = max(sqrt(abs(1.0_R8 - 16.0_R8*hol)) , 1.0_R8)
xqq = sqrt(xsq)
psimh = -5.0_R8*hol*stable + (1.0_R8-stable)*psimhu(xqq)
psixh = -5.0_R8*hol*stable + (1.0_R8-stable)*psixhu(xqq)
!--- shift wind speed using old coefficient and stability function ---
rd = rdn / (1.0_R8 + rdn/shr_const_karman*(alz-psimh))
u10n = vmag * rd / rdn
!--- update neutral transfer coeffs at 10m
rdn = sqrt(cdn(u10n))
rhn = (1.0_R8-stable) * 0.0327_R8 + stable * 0.018_R8
ren = 0.0346_R8
!--- shift all coeffs to measurement height and stability ---
rd = rdn / (1.0_R8 + rdn/shr_const_karman*(alz-psimh))
rh = rhn / (1.0_R8 + rhn/shr_const_karman*(alz-psixh))
re = ren / (1.0_R8 + ren/shr_const_karman*(alz-psixh))
ustar = rd * vmag
tstar = rh * delt
qstar = re * delq
ENDDO ! end iteration loop
!--- COMPUTE FLUXES TO ATMOSPHERE AND OCEAN ---
tau = rbot(n) * ustar * ustar
!--- momentum flux ---
taux(n) = tau * (ubot(n)-us(n)) / vmag
tauy(n) = tau * (vbot(n)-vs(n)) / vmag
!--- heat flux ---
sen (n) = cp * tau * tstar / ustar
lat (n) = shr_const_latvap * tau * qstar / ustar
lwup(n) = -shr_const_stebol * Tskin(n)**4
!--- water flux ---
evap(n) = lat(n)/shr_const_latvap
!------------------------------------------------------------
! compute diagnostics: 2m ref T & Q, 10m wind speed squared
!------------------------------------------------------------
hol = hol*ztref/zbot(n)
xsq = max( 1.0_R8, sqrt(abs(1.0_R8-16.0_R8*hol)) )
xqq = sqrt(xsq)
psix2 = -5.0_R8*hol*stable + (1.0_R8-stable)*psixhu(xqq)
fac = (rh/shr_const_karman) * (alz + al2 - psixh + psix2 )
tref(n) = thbot(n) - delt*fac
tref(n) = tref(n) - 0.01_R8*ztref ! pot temp to temp correction
fac = (re/shr_const_karman) * (alz + al2 - psixh + psix2 )
qref(n) = qbot(n) - delq*fac
duu10n(n) = u10n*u10n ! 10m wind speed squared
if (flux_diurnal) then
!------------------------------------------------------------
! update new prognostic variables
!------------------------------------------------------------
warm (n) = DTiter
salt (n) = DSiter
speed (n) = DViter
if (ltwopm) then
tSkin_day(n) = tSkin(n)
warmmax(n) = max(DTiter,0.0_R8)
endif
if (ltwoam) then
tSkin_night(n) = tSkin(n)
cSkin_night(n) = cSkin(n)
endif
if ((lmidnight).and.(lfullday)) then
qSolAvg(n) = qSolInc(n)/real(nsum+1,R8)
windAvg(n) = windInc(n)/real(nsum+1,R8)
! warmMax(n) = max(DTiter,warmMaxInc(n))
windMax(n) = max(u10n,windMaxInc(n))
nsum = 0
qSolInc(n) = Qsol
windInc(n) = u10n
! warmMaxInc(n) = 0.0_R8
windMaxInc(n) = 0.0_R8
! tSkin_night(n) = tSkin(n)
! cSkin_night(n) = cSkin(n)
else
if ((lmidnight).and.(.not.(lfullday))) then
nsum = 0
qSolInc(n) = Qsol