boundary dof

[edljk]

Is there a way to get the global numbering of all degrees of freedom associated to a faceset?
Thanks

[lijas]

Here is some code that I use to extract dofs on faces. It is not really optimised, but hopefully it is good enough for your purpuse.
We dont have "dof-extraction" functionallity in Ferrite atm, but me and @fredrikekre have discussed to maybe add some dof-utilities that should be able to do this.

Out of curiosity, why do you need to extract the dofs on a faces?

grid = generate_grid(Hexahedron, (1,1,1))

dh = DofHandler(grid)
push!(dh, :u, 3)
close!(dh)

function dofs_on_face(dh::DofHandler, faceid::FaceIndex)

    cellid, lfaceidx = faceid
    nfields = length(dh.field_names)

    local_face_dofs = Int[]
    for ifield in 1:nfields
        field_name = dh.field_names[ifield]
        offset = Ferrite.field_offset(dh, field_name)
        field_dim = Ferrite.getfielddim(dh, field_name)
        field_ip = dh.field_interpolations[ifield]
        face = Ferrite.faces(field_ip)[lfaceidx]
        
        for fdof in face, d in 1:field_dim
            push!(local_face_dofs, (fdof-1)*field_dim + d + offset)
        end
    end
    
    _celldofs = zeros(Int, ndofs_per_cell(dh, cellid))
    celldofs!(_celldofs, dh, cellid)
    
    return _celldofs[local_face_dofs] 

end

function dofs_on_faceset(dh::DofHandler, faceset)
    globaldofs = Int[]
    for faceid in faceset
        facedofs = dofs_on_face(dh, faceid)
        append!(globaldofs, facedofs)
    end
    unique!(globaldofs)
    sort!(globaldofs)
end

dofs_on_faceset(dh, getfaceset(grid, "right"))

[edljk]

Thank you so much!
I was far from being able to produce a solution by myself..
I am using the boundary dof to define specific periodicity of domains.
I know there has been a huge work in Ferrite on periodicity to make it as flexible as possible but I didn't find the time to have a look yet..

[lijas]

Yeah, the PeriodicDirichlet is pretty flexible now so you should give it a :D

[fredrikekre]

Another, perhaps more intuitive, way is to create a boundary condition on the face, and extract the dofs which became constrained:

julia> using Ferrite

julia> grid = generate_grid(Hexahedron, (1,1,1));

julia> dh = DofHandler(grid);

julia> push!(dh, :u, 3);

julia> close!(dh);

julia> ch = ConstraintHandler(dh);

julia> add!(ch, Dirichlet(:u, getfaceset(grid, "right"), (x, t) -> 0*x));

julia> close!(ch);

julia> ch.prescribed_dofs
12-element Vector{Int64}:
  4
  5
  6
  7
  8
  9
 16
 17
 18
 19
 20
 21

Obviously this isn't great either though. The periodic stuff isn't so complicated to use, so I would encourage you to have a look at it. If that doesn't solve your problem I am of course also curious about what your periodicity looks like :)