build.gradle

group 'dev.conreality.sdk.android'
version rootProject.file('VERSION').text.trim()

buildscript {
  repositories {
    google()
    jcenter()
  }

  dependencies {
    // See: https://developer.android.com/studio/releases/gradle-plugin
    classpath 'com.android.tools.build:gradle:3.3.2'
  }
}

rootProject.allprojects {
  repositories {
    google()
    jcenter()
  }
}

apply plugin: 'com.android.library'

android {
  compileSdkVersion 28 // Android 9.0 (Pie)

  defaultConfig {
    minSdkVersion 21 // Android 5.0 (Lollipop)
    testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
  }

  compileOptions {
    sourceCompatibility JavaVersion.VERSION_1_8
    targetCompatibility JavaVersion.VERSION_1_8
  }

  lintOptions {
    disable 'InvalidPackage'
  }
}

dependencies {
  // See: https://developer.android.com/jetpack/androidx/releases/core
  implementation 'androidx.core:core:1.0.2'

  // See: https://developer.android.com/jetpack/androidx/releases/annotation
  implementation 'androidx.annotation:annotation:1.1.0'

  // See: https://developer.android.com/jetpack/androidx/releases/lifecycle
  def lifecycle_version = '2.0.0'
  implementation "androidx.lifecycle:lifecycle-runtime:$lifecycle_version"
  implementation "androidx.lifecycle:lifecycle-common-java8:$lifecycle_version"

  // See: https://github.com/JakeWharton/ThreeTenABP/releases
  compileOnly 'com.jakewharton.threetenabp:threetenabp:1.2.1'

  // See: https://github.com/ReactiveX/RxJava/releases
  compileOnly 'io.reactivex.rxjava2:rxjava:2.2.11'
  compileOnly 'io.reactivex.rxjava2:rxandroid:2.1.1'

  // See: https://developers.google.com/android/guides/setup
  implementation 'com.google.android.gms:play-services-nearby:17.0.0'

  // See: https://github.com/AltBeacon/android-beacon-library/releases
  implementation 'org.altbeacon:android-beacon-library:2.16.2'

  // See: https://github.com/polarofficial/polar-ble-sdk/releases
  compileOnly fileTree(dir: 'libs', include: 'polar-ble-sdk.aar') // requires rxandroid, rxjava2
}