build.gradle

plugins {
    id 'java-library'
    id 'maven-publish'
}

group 'org.citydb'
version '1.1.6'
description 'Fork of the inactive swingx-ws library'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(11)
    }
    withJavadocJar()
    withSourcesJar()
}

repositories {
    maven {
        url 'https://3dcitydb.org/maven'
    }
    mavenCentral()
}

dependencies {
    implementation 'org.citydb:swingx-all:1.6.10'
    implementation 'commons-httpclient:commons-httpclient:3.1'
    implementation 'com.sun.xml.ws:jaxws-ri:2.3.7'
    implementation 'net.sf.json-lib:json-lib:0.9'
    implementation 'jtidy:jtidy:4aug2000r7-dev'
    implementation 'rome:rome:1.0'
    implementation 'org.json:json:20231013'
    compileOnly 'org.kohsuke.metainf-services:metainf-services:1.8'
    annotationProcessor 'org.kohsuke.metainf-services:metainf-services:1.8'
}

javadoc {
    failOnError = false
    options.addStringOption('Xdoclint:none', '-quiet')
}

jar {
    from(sourceSets.main.allSource) {
        include '**/*'
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }
    manifest {
        attributes('Implementation-Title': project.name,
                'Implementation-Version': project.version
        )
    }
    into('META-INF') {
        from 'LICENSE'
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            pom {
                name = project.name
                description = project.description
                url = 'https://github.com/3dcitydb'
                licenses {
                    license {
                        name = 'GNU Lesser General Public License (LGPL), Version 2.1'
                        url = 'http://www.fsf.org/licensing/licenses/lgpl.txt'
                        distribution = 'repo'
                    }
                }
                developers {
                    developer {
                        id = 'clausnagel'
                        name = 'Claus Nagel'
                        email = 'claus.nagel@gmail.com'
                        roles = ['architect', 'developer']
                        timezone = '+1'
                    }
                }
                scm {
                    url = 'https://github.com/3dcitydb/swingx-ws'
                    connection = 'scm:git:https://github.com/3dcitydb/swingx-ws.git'
                }
            }
        }
    }
    repositories {
        maven {
            url project.hasProperty('gitLab_maven_url') ? project.property('gitLab_maven_url') : System.getenv('GITLAB_MAVEN_URL')
            name 'gitlab-maven'
            credentials(HttpHeaderCredentials) {
                name = 'Private-Token'
                value = project.hasProperty('gitLab_private_token') ? project.property('gitLab_private_token') : System.getenv('GITLAB_PRIVATE_TOKEN')
            }
            authentication {
                header(HttpHeaderAuthentication)
            }
        }
    }
}